#*-------------------------------------------------------------------
* EMSO Model Library (EML) Copyright (C) 2004 - 2007 ALSOC.
*
* This LIBRARY is free software; you can distribute it and/or modify
* it under the therms of the ALSOC FREE LICENSE as available at
* http://www.enq.ufrgs.br/alsoc.
*
* EMSO Copyright (C) 2004 - 2007 ALSOC, original code
* from http://www.rps.eng.br Copyright (C) 2002-2004.
* All rights reserved.
*
* EMSO is distributed under the therms of the ALSOC LICENSE as
* available at http://www.enq.ufrgs.br/alsoc.
*
*---------------------------------------------------------------------
* Hidrodesalkylation of mesitylene
*----------------------------------------------------------------------
* Solved problem from Fogler (1999)
* Problem number: 6-6
* Page: 273 (Brazilian version, 2002)
*----------------------------------------------------------------------
*
*   Description:
*		Sample to calculate of the molar concentration as functions of
*	the resident time in a PFR with a fixed bed. There is the reaction
*	of hidrodesalkylation of mesitylene:
*			mesitylene + H2 -> m-xylene + CH4
*			m-xylene   + H2 -> toluene  + CH4
*	
*   Assumptions:
*		* change time in residence time
*       * steady-state
*       * isotermic and isobaric system
*       * gaseous phase
*
*	Specify:
*		* the inlet stream
*		* the kinetic parameters
*		* the parameters of reactor
*
*----------------------------------------------------------------------
* Author: Christiano D. W. Guerra and Rodolfo Rodrigues
* $Id: hidrodesalkeletion.mso 188 2007-03-07 16:53:12Z rodolfo $
*--------------------------------------------------------------------*#

using "types";


#*---------------------------------------------------------------------
* Example 6-6: in a PFR
*--------------------------------------------------------------------*#

FlowSheet pfr
	PARAMETERS
	NComp 		as Integer		(Brief="Number of components", Default=1);
	NReac 		as Integer		(Brief="Number of reactions");
	stoic(NComp,NReac) as Real 	(Brief="Stoichiometric coefficients");
	k(NReac) 	as Real 		(Brief="Specific velocity reaction", Unit='(ft^3/lbmol)^.5/h');
	P			as pressure 	(Brief="Pressure of reactor");
	T			as temperature	(Brief="Temperature of reactor");
	R			as Real			(Brief="Universal gas constant", Unit='atm*ft^3/degR/lbmol', Default=0.73);
	yo(NComp)	as fraction 	(Brief="Input molar fraction");
	vo			as flow_vol 	(Brief="Input volumetric flow");
	
	VARIABLES
	F(NComp) 	as flow_mol 	(Brief="Molar flow", DisplayUnit='lbmol/h');
	C(NComp) 	as conc_mol 	(Brief="Molar concentration", Lower=0, DisplayUnit='lbmol/ft^3');
	Co(NComp) 	as conc_mol 	(Brief="Input molar concentration", Lower=0, DisplayUnit='lbmol/ft^3');
	
	r(NComp,NReac) as reaction_mol (Brief="Relative rate of reaction", DisplayUnit='lbmol/h/ft^3');
	rate(NComp)	as reaction_mol	(Brief="Overall rate of reaction", DisplayUnit='lbmol/h/ft^3');
	tau			as time_h		(Brief="Residence time", DisplayUnit='h');
	V			as volume		(Brief="Reactor volume", DisplayUnit='ft^3');

	EQUATIONS
	"Change time in tau"
	tau = time;
	
	"Molar balance"
	diff(C) = rate;
	
	"Molar flow"
	F = vo*C;
	
	"Inlet molar concentration"
	Co = yo*P/R/T;
	
	"Residence time"
	tau = V/vo;

	"Relative rate of reaction 1"
	r(:,1) = stoic(:,1)*k(1)*C(1)*sqrt(C(2));
	
	"Relative rate of reaction 2"
	r(:,2) = stoic(:,2)*k(2)*C(3)*sqrt(C(2));
	
	"Overall rate of reaction"
	rate = sumt(r);
	
	SET
	NComp = 5; 	# 1: mesitylene, 2: hydrogen, 3: m-xylene, 
				# 4: methane and 5: toluene
	
	NReac = 2;	# 1: M + H -> X + Me,
				# 2: X + H -> T + Me
	
	stoic(:,1) = [-1.0, -1.0,  1.0, 1.0, 0.0]; # M + H -> X + Me
	stoic(:,2) = [ 0.0, -1.0, -1.0, 1.0, 1.0]; # X + H -> T + Me
	
	vo= 476*'ft^3/h';
	T = 1500*'degR';
	P = 35*'atm';
	yo= [1/3, 2/3, 0.0, 0.0, 0.0];
	k = [55.2, 30.2]*'(ft^3/lbmol)^.5/h';
	
	INITIAL
	"Molar concentration"
	C = Co;
	
	OPTIONS
	TimeStep = 0.01;
	TimeEnd = 0.5;
	TimeUnit = 'h';
end