#*
    Considerações:
	1- Biomassa X é composta por 2 componentes
		O componente com atividade catalitica consiste em acido nucleicos e proteinas -> R
		componente inerte P.
    2- Nitrogenio, N é o substrato limitante q afeta a cinética de crescimento.
  -----------------------------  *#
Model Biop_NE_mod5t

	PARAMETERS

   
	Kss	as Real(Brief="Constante de saturação do modelo de Monod para sacarose",Unit='kg/m^3');  
	Ksn as Real(Brief="Constante de saturação do modelo de Monod para nitrogênio",Unit='kg/m^3');
	mim	as Real(Brief="taxa de crescimento máximo específico",Unit='1/s');
	alfa	as Real;  
	gama	as Real(Unit='1/s'); 
	K1		as Real(Unit='kg/kg');#(g PHB / g biomassa) -> constante de formação de produto associado ao crescimento de biomassa
	K2		as Real(Unit='1/s');#(g PHB / g biomassa*h) -> constante de formação de produto não associado ao crescimento de biomassa
	Yn		as Real(Brief="1/rendimento de biomassa baseado no nitrogenio",Unit='kg/kg');#(g biomassa/g nitrogenio  )
	kd		as Real(Unit='1/s');
	#kc		as Real(Unit='1/s');
 
	VARIABLES
	X	as Real(Unit='kg/m^3');
	R	as Real(Unit='kg/m^3');
	P	as Real(Unit='kg/m^3');
	S	as Real(Unit='kg/m^3');
	N	as Real(Unit='kg/m^3');
	PHB as Real;
	mi  as Real(Unit='1/s');
	
	EQUATIONS

	"Produção de Biomassa total"
		X = R + P;

	"Produção de Biomassa residual"
	
	diff(R) = mi * R - kd * R;
	
	"Produção de Biopolímero"
		diff(P) = (K1*mi+ K2)*R;
	
	"Consumo de Nitrogenio"
		diff(N) = -(mi/Yn)*R;
	
	if (S > 0 * 'kg/m^3') then
	"Consumo de Açúcar"	
		diff(S) = -(alfa*mi + gama)*R;

	"Taxa de crescimento específica  Monod 2 substratos"
		mi = mim * (S/(S + Kss))*(N/(N + Ksn));

	else
		diff(S) = 0 * 'kg/m^3/s';
	"Taxa de crescimento específica  Monod 2 substratos"
		mi = 0/'s';
	end
	
	#alfa =(1/Yrs1 + K1/Yps1), onde Yrs1 é o rendimento de biomassa baseado na frutose (g biomassa/g frutose), 
	#gama = (ms1 + K2/Yps1) ,onde ms1 é o coeficiente de manutenção da biomassa baseado na frutose (g frutose/g biomassa*h)

	"Percentual de acumulo"
	PHB * X = P * 100;
end

FlowSheet Biop_NE_process5t as Biop_NE_mod5t
	SET
	Kss = 0.1928 * 'kg/m^3';  
	Ksn = 0.0447 * 'kg/m^3';
	mim = 0.7979 * '1/s';
	alfa =2.0606;  
	gama = 0.0849 * '1/s';
	K1 = 0.4053 * 'kg/kg';
	K2 = -0.0079 * '1/s';
	Yn = 10.6314;
	kd = 0.0073 * '1/s';
	#kc = 0.01 * '1/s';

	#SPECIFY
	
	
	INITIAL
	R = 0.017 * 'kg/m^3';
	P = 0.007 * 'kg/m^3';
	S = 17.519 * 'kg/m^3';
	N = 0.425 * 'kg/m^3'; # x 0,212 conversão de sulfato de amonio para N

	
	OPTIONS
	
	TimeStep = 0.1;
	TimeEnd	 = 24;
	TimeUnit = 's';
#	DAESolver(File="dassl");   
end

Estimation Biop_NE_Estt5 as Biop_NE_process5t
	ESTIMATE
	# PARAMETER  START    LOWER     UPPER     UNIT


	Kss			0.2009		0.004	7		'kg/m^3';  
	Ksn			0.0446		0.005	1		'kg/m^3';
	mim			0.7979	    0.1		0.8		'1/s';
	alfa		2.0293		1		5			;  
	gama		0.08502		0.05		5		'1/s';
	K1			0.4059		0.1		3		'kg/kg';
	K2			-0.00795	-1		3		'1/s';
	Yn			10.62		0.1		18			 ;
	kd 			0.007		0.0005	1		'1/s';
	#k3			0.0131		0.0001	1		'1/s';
	#K2			0.00527		0.001	3		'1/s';
	
	#*Kss		1.5679		0.005		7		'kg/m^3';  
	Kss			0.0487		0.004	7		'kg/m^3';  
	Ksn			0.049		0.005	1		'kg/m^3';
	mim			0.799	    0.1		0.8		'1/s';
	alfa		2.0458		1		5			;  
	gama		0.086		0.05		5		'1/s';
	K1			0.404		0.1		3		'kg/kg';
	K2			0.0049		0.001	3		'1/s';
	Yn			10.69		0.5		18			 ;
	kd 			0.0078		0.001	1		'1/s';*#
	#k3			0.01274		0.0001	1		'1/s';
	
	EXPERIMENTS
	# DATA FILE    WEIGTH
	"Bio.dat"      1;
	
	OPTIONS
	Statistics(
		Fits=true,
		Parameters=false,
		Predictions=false
	);
	
	NLPSolver(
		MaxIterations = 1000,
		File = "complex"
		#File = "ipopt_emso"
	);
	
end