#*-------------------------------------------------------------------
* EMSO Model Library (EML) Copyright (C) 2004 - 2007 ALSOC.
*
* This LIBRARY is free software; you can distribute it and/or modify
* it under the therms of the ALSOC FREE LICENSE as available at
* http://www.enq.ufrgs.br/alsoc.
*
* EMSO Copyright (C) 2004 - 2007 ALSOC, original code
* from http://www.rps.eng.br Copyright (C) 2002-2004.
* All rights reserved.
*
* EMSO is distributed under the therms of the ALSOC LICENSE as
* available at http://www.enq.ufrgs.br/alsoc.
*
*-------------------------------------------------------------------
* Model of costs for a reboiler
*-------------------------------------------------------------------- 
*
*	Streams:
*		* a liquid inlet stream
*		* a liquid outlet stream
*		* a vapour outlet stream
*		* a feed stream
*
*	Assumptions:
*		* perfect mixing of both phases
*		* thermodynamics equilibrium
*		* no liquid entrainment in the vapour stream
*
*	Specify:
*		* the Feed stream
*		* the Liquid inlet stream
*		* the outlet flows: OutletV.F and OutletL.F
*
*	Initial:
*		* the reboiler temperature (OutletL.T)
*		* the reboiler liquid level (Ll)
*		* (NoComps - 1) OutletL (OR OutletV) compositions
*
*	- This Model is valid if 14m^2 < Across < 1100 m^2
*
*----------------------------------------------------------------------
* Author: Núbia do Carmo Ferreira
* $Id: reboiler.mso 210 2007-03-15 12:52:28Z arge $
*--------------------------------------------------------------------*#

using "stage_separators/reboiler";

Model reboiler_cost as reboiler
	ATTRIBUTES
	Pallete 	= true;
	Icon 		= "icon/Reboiler";

	PARAMETERS
	Material as Switcher (Valid = ["Stainless steel 316", "Stainless steel 304", "Stainless steel 347", "Nickel 200", "Monel 400", "Inconel 600", "Incoloy 825", "Titanium", "Hastelloy"], 
			Default = "Stainless steel 316");
	Cost(8,3) as Real;
	
	VARIABLES
	Ce as currency 	(Brief="Capital Cost");
	Cb as currency	(Brief="Basic Cost");
	Fd as positive	(Brief="Cost Factor based on the type of the heat exchanger");
	Fp as positive	(Brief="Cost Factor based on the project pressure");
	Fm as positive	(Brief="Cost Factor based on the construction material");
	P  as pressure 	(Brief="Average pressure");

	EQUATIONS
	"Average pressure"
	P = 0.5*(InletL.P + OutletL.P);
	
	"Capital Cost"
	Ce = Cb*Fd*Fp*Fm;

	"Basic Cost"
	Cb = 'US$'*exp(Cost(1,1) + Cost(1,2)*ln(Across/'m^2') + Cost(1,3)*(ln(Across/'m^2'))^2);

	"Cost Factor based on the type of the heat exchanger"
	Fd = exp(Cost(3,1) + Cost(3,2)*ln(Across/'m^2') + Cost(3,3)*ln(Across/'m^2'));

	if P <= 700 * 'kPa' then
		"Cost Factor based on the project pressure" # verificar
		Fp = Cost(5,1) + Cost(5,2)*ln(Across/'m^2');
	else if 700 * 'kPa' < P and P < 2100 * 'kPa' then
		Fp = Cost(5,1) + Cost(5,2)*ln(Across/'m^2');
	else if 2100 * 'kPa' < P and P < 4200 * 'kPa' then
		Fp = Cost(6,1) + Cost(6,2)*ln(Across/'m^2');
	else if 4200 * 'kPa' < P and P < 6200 * 'kPa' then
		Fp = Cost(7,1) + Cost(7,2)*ln(Across/'m^2');
	else
		Fp = Cost(7,1) + Cost(7,2)*ln(Across/'m^2'); # verificar
	end
	end
	end
	end

	"Cost Factor based on the construction material"
	Fm = Cost(8,1) + Cost(8,2)*ln(Across/'m^2');
	
end