#*-------------------------------------------------------------------
* EMSO Model Library (EML) Copyright (C) 2004 - 2007 ALSOC.
*
* This LIBRARY is free software; you can distribute it and/or modify
* it under the therms of the ALSOC FREE LICENSE as available at
* http://www.enq.ufrgs.br/alsoc.
*
* EMSO Copyright (C) 2004 - 2007 ALSOC, original code
* from http://www.rps.eng.br Copyright (C) 2002-2004.
* All rights reserved.
*
* EMSO is distributed under the therms of the ALSOC LICENSE as
* available at http://www.enq.ufrgs.br/alsoc.
*
*--------------------------------------------------------------------
* Sample Rankine cicle.
*--------------------------------------------------------------------
* Author: Argimiro R. Secchi
* $Id: sample_rankine.mso 195 2007-03-07 20:30:12Z arge $
*-------------------------------------------------------------------*#

using "water_steam/power_plant";

# Simple Rankine cycle
FlowSheet Rankine

    PARAMETERS
    propterm as Plugin(Brief="Steam tables", Type="water", File="propterm");

    DEVICES
	Turb	as Turbina;
	Cond	as Condensador;
	Bomba1	as Bomba;
	GV		as Gerador_Vapor_Simples;
	GE		as Gerador_Eletrico;

	CONNECTIONS
	GV.Fout      to  Turb.Fin;
	Turb.Fout    to  Cond.Fin;
	Cond.Fout    to  Bomba1.Fin;
	Bomba1.Fout  to  GV.Fin;

	VARIABLES
	EF_CIC as Eficiencia;

	EQUATIONS
	"Potencia do Gerador Eletrico"
	GE.POT_GE = GE.EF_GE * Turb.POT_TURB;

	"Eficiencia do Ciclo"
	EF_CIC * GV.Q_GV = GE.POT_GE - Bomba1.POT_BMB;

	SET
	Bomba1.v_esp = 1.01e-3* 'm^3/kg';
	GE.EF_GE = 0.97;

	SPECIFY
#	EF_CIC = 0.275;

	GV.Fout.P = 11.3 *'MPa';
	GV.Fout.T = (530 + 273.15)*'K';
#	GV.Fout.F = 100 * 'kg/s';
	GV.EF_GV = 0.8;
#	GV.Q_GV = 230 * 'MJ/s';

	Turb.POT_TURB = 63*'MW';
	Turb.EF_T = 0.8;
	Turb.Fout.P = 0.007*'MPa';

#	Cond.Fout.T = (34 + 273.15) * 'K';
#	Cond.Q_COND = 125 * 'MJ/s';
	Cond.G_S = 5.0*'K';

#	Bomba1.Fout.F = 60 * 'kg/s';
	Bomba1.EF_B = 0.7;
#	Bomba1.POT_BMB = 0.9 * 'MW';

	OPTIONS
	Dynamic = false;
end

# Simple Rankine cycle with extraction
FlowSheet Rankine_s
	DEVICES
	TAP1	as Turbina_sangra;
	TAP2	as Turbina;
	COND	as Condensador_2alim;
	BBP		as Bomba;
	RAP2	as Condensador;
	TR_AP2	as Trocador;
	GV		as Gerador_Vapor;
	GE		as Gerador_Eletrico;
	F_RA	as Corrente;

    PARAMETERS
    propterm as Plugin(Brief="Steam tables", Type="water", File="propterm");

	CONNECTIONS
	F_RA		to	GV.Fin_ra;
	GV.Fout_sa  to  TAP1.Fin;
	TAP1.Fout   to  TAP2.Fin;
	TAP2.Fout   to  COND.Fin1;
	TAP1.Fouts  to  RAP2.Fin;
	RAP2.Fout   to  COND.Fin2;
	COND.Fout   to  BBP.Fin;
	BBP.Fout    to  TR_AP2.Fin;
	TR_AP2.Fout to  GV.Fin_a;

	VARIABLES
	EF_CIC as Eficiencia;
	POT_TURB as Potencia;

	EQUATIONS
	F_RA.T = GV.Fout_ra.T-180*'K';
	F_RA.P = GV.Fout_ra.P+1*'MPa';
	[F_RA.S,F_RA.H] = propterm.propPTv(F_RA.P,F_RA.T);

#	GV.Fin_a.P = GV.Fout_sa.P;

	"Trocadores de Calor"
	RAP2.Q_COND = TR_AP2.Q;

	"Eficiencias das Turbinas"
	TAP1.EF_T = TAP2.EF_T;

	"Potencias das Turbinas"
	POT_TURB = TAP1.POT_TURB + TAP2.POT_TURB;

	"Potencia do Gerador Eletrico"
	GE.POT_GE = GE.EF_GE * POT_TURB;

	"Eficiencia do Ciclo"
	EF_CIC * GV.Q_GV = GE.POT_GE - BBP.POT_BMB;

	SET
	BBP.v_esp = 1.01e-3*'m^3/kg';
	GE.EF_GE = 0.97;

	SPECIFY
#	EF_CIC = 0.275;

	GV.Fin_a.F = (357/3.6)*'kg/s';
#	GV.Fin_a.P = 134 * 0.101325*'MPa';
#	GV.Fin_a.T = (197 + 273.15)*'K';
	GV.Feco.P = 130 * 0.101325*'MPa';
	GV.Feco.T = (314 + 273.15)*'K';
	GV.Fvap.P = 126 * 0.101325*'MPa';
	GV.Fvap.T = (400 + 273.15)*'K';
	GV.Fout_sa.P = 121 * 0.101325*'MPa';
	GV.Fout_sa.T = (525 + 273.15)*'K';
	GV.Fin_ra.F = (344/3.6)*'kg/s';
	GV.Fout_ra.P = 28 * 0.101325*'MPa';
	GV.Fout_ra.T = (526 + 273.15)*'K';
	GV.EF_GV = 0.8;
#	GV.Q_GV = 400*'MJ/s';

#	TAP1.POT_TURB = 43*'MW';
#	TAP1.EF_T = 0.8;
	TAP1.Fout.P = 2*'MPa';
	TAP1.y = 0.035;
#	TAP2.POT_TURB = 23*'MW';
	TAP2.EF_T = 0.8;
	TAP2.Fout.P = 0.2*'MPa';
#	TAP2.Fout.T = 315*'K';

#	COND.Fout.T = (34 + 273.15)*'K';
#	COND.Q_COND = 125*'MJ/s';
	COND.G_S = 5.0*'K';

	BBP.EF_B = 0.95;
#	BBP.POT_BMB = 2 * 0.8*'MW'; #duas bombas
	BBP.Fout.P = 146 * 0.101325*'MPa';

	RAP2.G_S = 1*'K';

#	TR_AP2.Fout.P = 134 * 0.101325*'MPa';
	TR_AP2.DP = 20 * 0.101325*'MPa';

	OPTIONS
#	GuessFile = "Rankine_s";
	Dynamic = false;
end