#*-------------------------------------------------------------------
* EMSO Model Library (EML) Copyright (C) 2004 - 2007 ALSOC.
*
* This LIBRARY is free software; you can distribute it and/or modify
* it under the therms of the ALSOC FREE LICENSE as available at
* http://www.enq.ufrgs.br/alsoc.
*
* EMSO Copyright (C) 2004 - 2007 ALSOC, original code
* from http://www.rps.eng.br Copyright (C) 2002-2004.
* All rights reserved.
*
* EMSO is distributed under the therms of the ALSOC LICENSE as
* available at http://www.enq.ufrgs.br/alsoc.
*
*--------------------------------------------------------------------
* Some Hock and Schittkowski test problems
*--------------------------------------------------------------------
* Author: Edson Cordeiro do Valle, Rafael de Pelegrini Soares		  
* $Id$
*--------------------------------------------------------------------*#
	Optimization hs71
	VARIABLES
	x1 as Real(Default=2, Lower=1, Upper=5);
	x2 as Real(Default=5, Lower=1, Upper=5);
	x3 as Real(Default=5, Lower=1, Upper=5);
	x4 as Real(Default=1, Lower=1, Upper=5);

	MINIMIZE
	x1*x4*(x1+x2+x3) + x3;
	
	EQUATIONS
	x1*x2*x3*x4 > 25;
	
	x1*x1 + x2*x2 + x3*x3 + x4*x4 = 40;
	
	OPTIONS
	NLPSolver(File = "ipopt_emso"
			  #File = "complex"
	          #File = "optpp_emso"
			  );
	Dynamic = false;
end

Optimization hs75
	VARIABLES
	x1 as Real(Default=1.0e-6, Lower=0, Upper=1200);
	x2 as Real(Default=1.0e-6, Lower=0, Upper=1200);
	x3 as Real(Default=1.0e-6, Lower=-0.48, Upper=0.48);
	x4 as Real(Default=1.0e-6, Lower=-0.48, Upper=0.48);

	MINIMIZE
	3*x1+1.0e-6*x1^3+2*x2+(2/3)*1.0e-6*x2^3;
	
	EQUATIONS
	x4 - x3 + 0.48 > 0;
	x3 - x4 + 0.48 > 0;

    1000*sin((-x3-0.25)*'rad')+1000*sin((-x4-0.25)*'rad')+894.8-x1 = 0;
	
	1000*sin((x3-0.25)*'rad')+1000*sin((x3-x4-0.25)*'rad')+894.8-x2 = 0;
	
	1000*sin((x4-0.25)*'rad')+1000*sin((x4-x3-0.25)*'rad')+1294.8 = 0;
	
	
	OPTIONS
	Dynamic = false;
	NLPSolveNLA = false;
#*
	NLPSolver(	File = "optpp_emso",
				MeritFun = "VanShanno",
				SecondOrderDerivative= "BFGS",
				SecondOrderDerivative= "finitediferences",
				SearchStrategy = "TrustRegion",
				TRSize = 0.3636,
				Objtol = 1e-8,
				constrtol = 1e-4, 
				Minstep = 1e-10,
				Maxstep= 1e10,
				Gradtol = 1e-4);	
*#

NLPSolver(File = "ipopt_emso",
		  	  RelativeAccuracy = 1e-6, 
	          hessian_approximation = "exact",
			  finite_difference_perturbation = 1.0e-10,
			  Derivative_Test="second-order");

end

Optimization bn65
	VARIABLES
	x1 as Real(Default=1, Lower=-4.5, Upper=4.5);
	x2 as Real(Default=5, Lower=-4.5, Upper=4.5);
	x3 as Real(Default=5, Lower=-5, Upper=5);

	MINIMIZE
	(x1-x2)^2 + (1/9)*(x1+x2-10)^2 + (x3-5)^2;
	
	EQUATIONS
	x1^2 + x2^2 + x3^2 < 48;
	
	OPTIONS
	Dynamic = false;
	NLPSolveNLA = false;
	NLPSolver(File = "ipopt_emso",
			  Objtol = 1e-6);
	
#	NLPSolver(File = "optpp_emso",
#			  RelativeAccuracy = 1e-6,
#			SecondOrderDerivative= "BFGS");

end