#*-------------------------------------------------------------------
* EMSO Model Library (EML) Copyright (C) 2004 - 2007 ALSOC.
*
* This LIBRARY is free software; you can distribute it and/or modify
* it under the therms of the ALSOC FREE LICENSE as available at
* http://www.enq.ufrgs.br/alsoc.
*
* EMSO Copyright (C) 2004 - 2007 ALSOC, original code
* from http://www.rps.eng.br Copyright (C) 2002-2004.
* All rights reserved.
*
* EMSO is distributed under the therms of the ALSOC LICENSE as
* available at http://www.enq.ufrgs.br/alsoc.
*
*--------------------------------------------------------------------
* Sample file for model pfr
*
*
* Adiabatic Production of Acetic Anhydride with a PFR
*
* Based on Example 8-6 of Elements of Chemical Reaction Engineering
* Second Edition H. Scott Fogler
*
*
*--------------------------------------------------------------------
* 
* This sample file needs VRTherm (www.vrtech.com.br) to run.
*
*----------------------------------------------------------------------
* Author: Rafael de P. Soares
*         Paula B. Staudt
* $Id: sample_pfr.mso 585 2008-07-28 23:31:29Z bicca $
*--------------------------------------------------------------------*#

using "reactors/pfr";

FlowSheet PFR_AceticAnhydride
	
PARAMETERS

	PP   		as Plugin (Brief="Physical Properties",
		Type = "PP",
		Components = ["acetone", "acetic anhydride", "methane" ],
		LiquidModel = "PR",
		VapourModel = "PR"
	);
	NComp 	as Integer;

DEVICES

	s1   	as source;
	Reac as pfr;

SET
	NComp = PP.NumberOfComponents;
	
	s1.ValidPhases = "Vapour-Liquid";
	s1.CompositionBasis = "Molar";
	
	Reac.NDisc 	= 10;
	Reac.Across 	= 0.7 * 'in^2';
	Reac.L 			= 2.28 * 'm';
	Reac.NReac 	= 1;

	# Reaction 1: A -> B + C
	Reac.stoic(:,1) = [-1, 1, 1];
	
EQUATIONS

for z in [1:Reac.NDisc] do
	
"Reaction Rate = k*C(1)"
	Reac.r(1,z)  = exp(34.34 - (34222 * 'K') / Reac.str(z).T)*'1/s' * Reac.C(1,z);

"Heat of reaction"
	Reac.Hr(1,z) = -80.77 * 'kJ/mol';

"Pressure Drop (no pressure drop)"
	Reac.str(z+1).P = Reac.str(z).P;

end

SPECIFY
	s1.F = 138/1000 * 'kmol/h';
	s1.T = 1035 * 'K';
	s1.P = 1.6  * 'atm';
	s1.Composition = [1, 0, 0];

	Reac.q     = 0     * 'J/s';
	
CONNECTIONS

	s1.Outlet  to  Reac.Inlet;
	
INITIAL

for z in [2:Reac.NDisc+1] do
	
	Reac.str(z).T = Reac.Inlet.T;
	Reac.str(z).z(1:NComp-1) = Reac.Inlet.z(1:NComp-1);

end
	
OPTIONS
	# This model can be solved in both steady or dynamic
	Dynamic 	= true;
	TimeStep 	= 0.05;
	TimeEnd 	= 3;
	#Dynamic = false;
	#DAESolver = "dassl";
end