#*---------------------------------------------------------------------
* This file is property of the author and cannot be used, copyed
* or modified without permission.
*
* Copyright (C) 2002-2004  the author
*----------------------------------------------------------------------
* Author: Paula Bettio Staudt
*         Rafael de Pelegrini Soares
* $Id: sample_batch.mso 1 2006-06-20 17:33:53Z rafael $
*----------------------------------------------------------------------
*
* Sample file for a isotermic batch reactor.
*
*-------------------------------------------------------------------*#

using "batch";

FlowSheet SampleBatch
	PARAMETERS
	NoComps as Integer(Brief="Number of components");

	DEVICES
	feed as stream;
	reac as batch_isotermic;
	
	CONNECTIONS
	feed to reac.Inlet;
	
	PARAMETERS
	k1 as Real(Unit="(l/mol)^3.5/min", Default=18.7);
	k2 as Real(Unit="l/mol/min", Default=0.58);
	k3 as Real(Unit="(l/mol)^2/min", Default=0.09);
	k4 as Real(Unit="(l/mol)^1.5/min", Default=0.42);
	Ks as inv_conc_mol(Default=115.83);
	K  as Real(Default=34.4);
	kla as flow_vol(Default=3.3);
	H as inv_conc_mol(Default=737);
	pCO2;
	
	VARIABLES
	C6 as conc_mol(Brief="Special component concentration");

	SET
	NoComps = 5;
	reac.NoReacs = 5;
	pCO2 = 0.9;
	
	reac.stoic(1,:) = [-2,   1,  -1, -1,  0  ];
	reac.stoic(2,:) = [-0.5, 0,  0,  -1, -0.5];
	reac.stoic(3,:) = [1,   -1,  1,   0,   0 ];
	reac.stoic(4,:) = [0,   -1,  1,  -2,   0 ];
	reac.stoic(5,:) = [0,    1, -1,   0,   1 ];

	EQUATIONS
	"Inlet Flow"
	feed.F = kla*(pCO2/H-reac.C(2));
	
	"Reaction rates"
	reac.r(1)=k1   * reac.C(1)^4 * sqrt(reac.C(2));
	reac.r(2)=k2   * reac.C(3)   * reac.C(4);
	reac.r(3)=k2/K * reac.C(1)   * reac.C(5);
	reac.r(4)=k3   * reac.C(1)   * reac.C(4)^2;
	reac.r(5)=k4   * C6^2   * sqrt(reac.C(2));
	
	"C6 Equilibrium"
	C6  = Ks * reac.C(1) * reac.C(4);
	
	SPECIFY
	"Feed conditions"
	feed.T = 300*"K";
	feed.P = 1*"atm";
	feed.h = 0*"J/mol";
	feed.v = 0;
	feed.z = [0,1,0,0,0];

	"Reactor volume"
	reac.Vr = 1 * "l";
	
	INITIAL
	"Initial concentration"
	reac.C=[0.444, 0.00122, 0, 0.007, 0] * "mol/l";

	OPTIONS
	outputLevel = "high";
	time = [0:100:180*60];
end