#*-------------------------------------------------------------------
* EMSO Model Library (EML) Copyright (C) 2004 - 2007 ALSOC.
*
* This LIBRARY is free software; you can distribute it and/or modify
* it under the therms of the ALSOC FREE LICENSE as available at
* http://www.enq.ufrgs.br/alsoc.
*
* EMSO Copyright (C) 2004 - 2007 ALSOC, original code
* from http://www.rps.eng.br Copyright (C) 2002-2004.
* All rights reserved.
*
* EMSO is distributed under the therms of the ALSOC LICENSE as
* available at http://www.enq.ufrgs.br/alsoc.
*--------------------------------------------------------------------
* Author: Gerson Balbueno Bicca 
* $Id: PHE.mso 250 2007-04-27 16:32:02Z bicca $
*------------------------------------------------------------------*#
using "HEX_Engine";

Model PHE

 ATTRIBUTES
	Icon 		= "icon/phe";
	Pallete 	= true;
	Brief 		= "Shortcut model  for plate and Frame heat exchanger.";
	Info 		=
	"
	Model of a gasketed plate heat exchanger.
	The heat transfer and pressure loss calculations are based on Kumar [1] work.
	The following assumptions are considered in order to derive the mathematical model [2]:
	
	A.1 : Steady-State operation;
	A.2 : No phase changes;
	A.3 : No heat loss to the surroundings.
	A.4 : Uniform distribution of flow through the channels of a pass.

	References:
    
	[1] E.A.D. Saunders, Heat Exchangers: Selection, Design and
    Construction, Longman, Harlow, 1988.
    
	[2] J.A.W. Gut, J.M. Pinto, Modeling of plate heat exchangers
    with generalized configurations, Int. J. Heat Mass Transfer
    46 (14) (2003) 2571\2585.
	";

 PARAMETERS

outer PP 	    	as Plugin		(Brief="External Physical Properties", Type="PP");
outer NComp   		as Integer   	(Brief="Number of Chemical Components");
	Pi				as constant 	(Brief="Pi Number",Default=3.14159265);
	Kp1(15)			as constant 	(Brief="First constant in Kumar calculation for Pressure Drop");
	Kp2(15)			as constant 	(Brief="Second constant in Kumar calculation for Pressure Drop");
	Kc1(14)			as constant 	(Brief="First constant in Kumar calculation for Heat Transfer");
	Kc2(14)			as constant 	(Brief="Second constant Kumar calculation for Heat Transfer");
	M(NComp)  		as molweight 	(Brief="Component Mol Weight");
	
	ChevronAngle 	as Switcher		(Brief="Chevron Corrugation Inclination Angle in Degrees ",Valid=["30","45","50","60","65"],Default="30");
	Method 			as Switcher		(Brief="Method of Thermal Calculation",Valid=["NTU","LMTD"],Default="NTU");
	SideOne 		as Switcher		(Brief="Fluid Alocation in the Side I - (The odd channels)",Valid=["hot","cold"],Default="hot");
	Nchannels		as Integer 		(Brief="Total Number of Channels in The Whole Heat Exchanger");
	Nplates			as Integer 		(Brief="Total Number of Plates in The Whole Heat Exchanger",Default=25);
	NpassHot		as Integer 		(Brief="Number of Passes for Hot Side");
	NpassCold		as Integer 		(Brief="Number of Passes for Cold Side");
	Dports  		as length		(Brief="Ports Diameter",Lower=1e-6);
	Atotal  		as area			(Brief="Total Effective  Area",Lower=1e-6);
	Aports  		as area			(Brief="Port Opening  Area of Plate",Lower=1e-6);
	Achannel  		as area			(Brief="Cross-Sectional Area for Channel Flow",Lower=1e-6);
	Dh  			as length		(Brief="Equivalent Diameter of Channel",Lower=1e-6);
	Depth  			as length		(Brief="Corrugation Depth",Lower=1e-6);
	PhiFactor		as Real			(Brief="Enlargement Factor",Lower=1e-6);
	Lp				as length		(Brief="Plate Vertical Distance between Port Centers",Lower=0.1);
	Lpack			as length		(Brief="Compact Plate Pack Length",Lower=0.1);
	Lv				as length		(Brief="Vertical Ports Distance",Lower=0.1);
	Lh				as length		(Brief="Plate Horizontal Distance between Port Centers",Lower=0.1);
	Lw				as length		(Brief="Plate Width",Lower=0.1);
	pitch			as length		(Brief="Plate Pitch",Lower=0.1);
	pt				as length		(Brief="Plate Thickness",Lower=0.1);
	Kwall			as conductivity (Brief="Plate Thermal Conductivity",Default=1.0);
	Rfh				as positive		(Brief="Hot Side Fouling Resistance",Unit='m^2*K/kW',Default=1e-6,Lower=0);
	Rfc				as positive		(Brief="Cold Side Fouling Resistance",Unit='m^2*K/kW',Default=1e-6,Lower=0);

 VARIABLES

in  InletHot	    as stream 		(Brief="Inlet Hot Stream", PosX=0, PosY=0.7156);	
in  InletCold	    as stream 		(Brief="Inlet Cold Stream", PosX=1, PosY=0.7156);
out OutletHot    	as streamPH 	(Brief="Outlet Hot Stream", PosX=0, PosY=0.2793);
out OutletCold    	as streamPH 	(Brief="Outlet Cold Stream", PosX=1, PosY=0.2793);

	HotSide  		as Main_PHE		(Brief="Plate Heat Exchanger Hot Side");
	ColdSide  		as Main_PHE		(Brief="Plate Heat Exchanger Cold Side");
	Thermal 		as Thermal_PHE	(Brief="Thermal Results");

 SET

#"First constant for Kumar's calculating Pressure Drop"
	Kp1 = [50,19.40,2.990,47,18.290,1.441,34,11.250,0.772,24,3.240,0.760,24,2.80,0.639];

#"Second constant for Kumar's calculating Pressure Drop"
	Kp2 = [1,0.589,0.183,1,0.652,0.206,1,0.631,0.161,1,0.457,0.215,1,0.451,0.213];

#"First constant for Kumar's calculating Heat Transfer"
	Kc1 = [0.718,0.348,0.718,0.400,0.300,0.630,0.291,0.130,0.562,0.306,0.108,0.562,0.331,0.087];

#"Second constant for Kumar's calculating Heat Transfer"
	Kc2 = [0.349,0.663,0.349,0.598,0.663,0.333,0.591,0.732,0.326,0.529,0.703,0.326,0.503,0.718];
	
#"Component Molecular Weight"
	M  = PP.MolecularWeight();
	
#"Pi Number"
	Pi  	= 3.14159265;
	
#"Plate Vertical Distance between Port Centers"
	Lp = Lv - Dports;
	
#"Corrugation Depth"
	Depth=pitch-pt;
	
#"Plate Horizontal Distance between Port Centers"
	Lh=Lw-Dports;
	
#"Hydraulic Diameter"
	Dh=2*Depth/PhiFactor;

#"Ports Area"
	Aports=Pi*Dports*Dports/4;
	
#"Channel Area"
	Achannel=Depth*Lw;
	
#"Pack Length"
	Lpack=Depth*(Nplates-1)+Nplates*pt;
	
#"Total Number of  Channels"
	Nchannels = Nplates -1;
	
#"Exchange Surface Area"
	Atotal =(Nplates-2)*Lw*Lp*PhiFactor;
	
 EQUATIONS

"Hot	Stream Average Temperature"
	HotSide.Properties.Average.T = 0.5*InletHot.T + 0.5*OutletHot.T;

"Cold Stream Average Temperature"
	ColdSide.Properties.Average.T = 0.5*InletCold.T + 0.5*OutletCold.T;
	
"Hot Stream Average Pressure"
	HotSide.Properties.Average.P = 0.5*InletHot.P+0.5*OutletHot.P;
	
"Cold Stream Average Pressure"
	ColdSide.Properties.Average.P = 0.5*InletCold.P+0.5*OutletCold.P;

"Cold Stream Wall Temperature"
	ColdSide.Properties.Wall.Twall =   0.5*HotSide.Properties.Average.T + 0.5*ColdSide.Properties.Average.T;

"Hot Stream Wall Temperature"
	HotSide.Properties.Wall.Twall =   0.5*HotSide.Properties.Average.T + 0.5*ColdSide.Properties.Average.T;

"Hot Stream Average Molecular Weight"
	HotSide.Properties.Average.Mw = sum(M*InletHot.z);

"Cold Stream Average Molecular Weight"
	ColdSide.Properties.Average.Mw = sum(M*InletCold.z);

 if InletCold.v equal 0
	
	then	

"Average Heat Capacity Cold Stream"
	ColdSide.Properties.Average.Cp 		= 	PP.LiquidCp(ColdSide.Properties.Average.T,ColdSide.Properties.Average.P,InletCold.z);

"Inlet Heat Capacity Cold Stream"
	ColdSide.Properties.Inlet.Cp 			= 	PP.LiquidCp(InletCold.T,InletCold.P,InletCold.z);

"Outlet	Heat Capacity Cold Stream"
	ColdSide.Properties.Outlet.Cp 		= 	PP.LiquidCp(OutletCold.T,OutletCold.P,OutletCold.z);

"Average Mass Density Cold Stream"
	ColdSide.Properties.Average.rho 	= 	PP.LiquidDensity(ColdSide.Properties.Average.T,ColdSide.Properties.Average.P,InletCold.z);

"Inlet Mass Density Cold Stream"
	ColdSide.Properties.Inlet.rho 		= 	PP.LiquidDensity(InletCold.T,InletCold.P,InletCold.z);

"Outlet Mass Density Cold Stream"
	ColdSide.Properties.Outlet.rho 	= 	PP.LiquidDensity(OutletCold.T,OutletCold.P,OutletCold.z);

"Average Viscosity Cold Stream"
	ColdSide.Properties.Average.Mu 	= 	PP.LiquidViscosity(ColdSide.Properties.Average.T,ColdSide.Properties.Average.P,InletCold.z);

"Inlet	Viscosity Cold Stream"
	ColdSide.Properties.Inlet.Mu 		= 	PP.LiquidViscosity(InletCold.T,InletCold.P,InletCold.z);

"Outlet	Viscosity Cold Stream"
	ColdSide.Properties.Outlet.Mu 	= 	PP.LiquidViscosity(OutletCold.T,OutletCold.P,OutletCold.z);

"Average	Conductivity Cold Stream"
	ColdSide.Properties.Average.K	 	= 	PP.LiquidThermalConductivity(ColdSide.Properties.Average.T,ColdSide.Properties.Average.P,InletCold.z);

"Inlet	Conductivity Cold Stream"
	ColdSide.Properties.Inlet.K 		= 	PP.LiquidThermalConductivity(InletCold.T,InletCold.P,InletCold.z);

"Outlet	Conductivity Cold Stream"
	ColdSide.Properties.Outlet.K 		= 	PP.LiquidThermalConductivity(OutletCold.T,OutletCold.P,OutletCold.z);

"Viscosity Cold Stream at wall temperature"
	ColdSide.Properties.Wall.Mu 		= 	PP.LiquidViscosity(ColdSide.Properties.Wall.Twall,ColdSide.Properties.Average.P,InletCold.z);

	else

"Average Heat Capacity ColdStream"
	ColdSide.Properties.Average.Cp 	=	PP.VapourCp(ColdSide.Properties.Average.T,ColdSide.Properties.Average.P,InletCold.z);

"Inlet Heat Capacity Cold Stream"
	ColdSide.Properties.Inlet.Cp 		=	PP.VapourCp(InletCold.T,InletCold.P,InletCold.z);

"Outlet Heat Capacity Cold Stream"
	ColdSide.Properties.Outlet.Cp 	=	PP.VapourCp(OutletCold.T,OutletCold.P,OutletCold.z);

"Average Mass Density Cold Stream"
	ColdSide.Properties.Average.rho 	=	PP.VapourDensity(ColdSide.Properties.Average.T,ColdSide.Properties.Average.P,InletCold.z);

"Inlet Mass Density Cold Stream"
	ColdSide.Properties.Inlet.rho 		=	PP.VapourDensity(InletCold.T,InletCold.P,InletCold.z);
	
"Outlet Mass Density Cold Stream"
	ColdSide.Properties.Outlet.rho 	=	PP.VapourDensity(OutletCold.T,OutletCold.P,OutletCold.z);

"Average Viscosity Cold Stream"
	ColdSide.Properties.Average.Mu 	=	PP.VapourViscosity(ColdSide.Properties.Average.T,ColdSide.Properties.Average.P,InletCold.z);

"Inlet Viscosity Cold Stream"
	ColdSide.Properties.Inlet.Mu 		=	PP.VapourViscosity(InletCold.T,InletCold.P,InletCold.z);

"Outlet Viscosity Cold Stream"
	ColdSide.Properties.Outlet.Mu 	=	PP.VapourViscosity(OutletCold.T,OutletCold.P,OutletCold.z);

"Average Conductivity Cold Stream"
	ColdSide.Properties.Average.K 		= 	PP.VapourThermalConductivity(ColdSide.Properties.Average.T,ColdSide.Properties.Average.P,InletCold.z);

"Inlet Conductivity Cold Stream"
	ColdSide.Properties.Inlet.K 		= 	PP.VapourThermalConductivity(InletCold.T,InletCold.P,InletCold.z);

"Outlet Conductivity Cold Stream"
	ColdSide.Properties.Outlet.K 		= 	PP.VapourThermalConductivity(OutletCold.T,OutletCold.P,OutletCold.z);
	
"Viscosity Cold Stream at wall temperature"
	ColdSide.Properties.Wall.Mu 		=	PP.VapourViscosity(ColdSide.Properties.Wall.Twall,ColdSide.Properties.Average.P,InletCold.z);

 end

 if InletHot.v equal 0

	then

"Average Heat Capacity Hot Stream"
	HotSide.Properties.Average.Cp 	=		PP.LiquidCp(HotSide.Properties.Average.T,HotSide.Properties.Average.P,InletHot.z);

"Inlet Heat Capacity Hot Stream"
	HotSide.Properties.Inlet.Cp 		=		PP.LiquidCp(InletHot.T,InletHot.P,InletHot.z);

"Outlet Heat Capacity Hot Stream"
	HotSide.Properties.Outlet.Cp 	=		PP.LiquidCp(OutletHot.T,OutletHot.P,OutletHot.z);

"Average Mass Density Hot Stream"
	HotSide.Properties.Average.rho =		PP.LiquidDensity(HotSide.Properties.Average.T,HotSide.Properties.Average.P,InletHot.z);

"Inlet Mass Density Hot Stream"
	HotSide.Properties.Inlet.rho 		=		PP.LiquidDensity(InletHot.T,InletHot.P,InletHot.z);

"Outlet Mass Density Hot Stream"
	HotSide.Properties.Outlet.rho 	=		PP.LiquidDensity(OutletHot.T,OutletHot.P,OutletHot.z);

"Average Viscosity Hot Stream"
	HotSide.Properties.Average.Mu 	=		PP.LiquidViscosity(HotSide.Properties.Average.T,HotSide.Properties.Average.P,InletHot.z);	

"Inlet Viscosity Hot Stream"
	HotSide.Properties.Inlet.Mu 	=		PP.LiquidViscosity(InletHot.T,InletHot.P,InletHot.z);	

"Outlet Viscosity Hot Stream"
	HotSide.Properties.Outlet.Mu 	=		PP.LiquidViscosity(OutletHot.T,OutletHot.P,OutletHot.z);	

"Average Conductivity Hot Stream"
	HotSide.Properties.Average.K 	=		PP.LiquidThermalConductivity(HotSide.Properties.Average.T,HotSide.Properties.Average.P,InletHot.z);	

"Inlet Conductivity Hot Stream"
	HotSide.Properties.Inlet.K 		=		PP.LiquidThermalConductivity(InletHot.T,InletHot.P,InletHot.z);	

"Outlet Conductivity Hot Stream"
	HotSide.Properties.Outlet.K 	=		PP.LiquidThermalConductivity(OutletHot.T,OutletHot.P,OutletHot.z);	

"Viscosity Hot Stream at wall temperature"
	HotSide.Properties.Wall.Mu 		=		PP.LiquidViscosity(HotSide.Properties.Wall.Twall,HotSide.Properties.Average.P,InletHot.z);	


	else

"Average Heat Capacity Hot Stream"
	HotSide.Properties.Average.Cp 	=		PP.VapourCp(HotSide.Properties.Average.T,HotSide.Properties.Average.P,InletHot.z);

"Inlet Heat Capacity Hot Stream"
	HotSide.Properties.Inlet.Cp 		=		PP.VapourCp(InletHot.T,InletHot.P,InletHot.z);

"Outlet Heat Capacity Hot Stream"
	HotSide.Properties.Outlet.Cp 	=		PP.VapourCp(OutletHot.T,OutletHot.P,OutletHot.z);

"Average Mass Density Hot Stream"
	HotSide.Properties.Average.rho =		PP.VapourDensity(HotSide.Properties.Average.T,HotSide.Properties.Average.P,InletHot.z);

"Inlet Mass Density Hot Stream"
	HotSide.Properties.Inlet.rho 		=		PP.VapourDensity(InletHot.T,InletHot.P,InletHot.z);
	
"Outlet Mass Density Hot Stream"
	HotSide.Properties.Outlet.rho 	=		PP.VapourDensity(OutletHot.T,OutletHot.P,OutletHot.z);

"Average Viscosity Hot Stream"
	HotSide.Properties.Average.Mu 	=		PP.VapourViscosity(HotSide.Properties.Average.T,HotSide.Properties.Average.P,InletHot.z);

"Inlet Viscosity Hot Stream"
	HotSide.Properties.Inlet.Mu 	=		PP.VapourViscosity(InletHot.T,InletHot.P,InletHot.z);

"Outlet Viscosity Hot Stream"
	HotSide.Properties.Outlet.Mu 	=		PP.VapourViscosity(OutletHot.T,OutletHot.P,OutletHot.z);

"Average Conductivity Hot Stream"
	HotSide.Properties.Average.K 	=		PP.VapourThermalConductivity(HotSide.Properties.Average.T,HotSide.Properties.Average.P,InletHot.z);	

"Inlet Conductivity Hot Stream"
	HotSide.Properties.Inlet.K 		=		PP.VapourThermalConductivity(InletHot.T,InletHot.P,InletHot.z);	

"Outlet Conductivity Hot Stream"
	HotSide.Properties.Outlet.K 	=		PP.VapourThermalConductivity(OutletHot.T,OutletHot.P,OutletHot.z);	

"Viscosity Hot Stream at wall temperature"
	HotSide.Properties.Wall.Mu 		=		PP.VapourViscosity(HotSide.Properties.Wall.Twall,HotSide.Properties.Average.P,InletHot.z);

 end

"Energy Balance Hot Stream"
	Thermal.Q = InletHot.F*(InletHot.h-OutletHot.h);

"Energy Balance Cold Stream"
	Thermal.Q = InletCold.F*(OutletCold.h - InletCold.h);

"Flow Mass Inlet Cold Stream"
	ColdSide.Properties.Inlet.Fw	=  sum(M*InletCold.z)*InletCold.F;

"Flow Mass Outlet Cold Stream"
	ColdSide.Properties.Outlet.Fw	=  sum(M*OutletCold.z)*OutletCold.F;

"Flow Mass Inlet Hot Stream"
	HotSide.Properties.Inlet.Fw		=  sum(M*InletHot.z)*InletHot.F;

"Flow Mass Outlet Hot Stream"	
	HotSide.Properties.Outlet.Fw	=  sum(M*OutletHot.z)*OutletHot.F;

"Molar Balance Hot Stream"
	OutletHot.F = InletHot.F;
	
"Molar Balance Cold Stream"
	OutletCold.F = InletCold.F;

"Hot Stream Molar Fraction Constraint"
	OutletHot.z=InletHot.z;
	
"Cold Stream Molar Fraction Constraint"
	OutletCold.z=InletCold.z;

 switch SideOne
	
	case "cold":
	
"Total Number of  Passages Cold Side"
	ColdSide.PressureDrop.Npassage = (2*Nchannels+1+(-1)^(Nchannels+1))/(4*NpassCold);

"Total Number of  Passages Hot Side"
	HotSide.PressureDrop.Npassage = (2*Nchannels-1+(-1)^(Nchannels))/(4*NpassHot);
	
	case "hot":
	
"Total Number of  Passages Cold Side"
	HotSide.PressureDrop.Npassage = (2*Nchannels+1+(-1)^(Nchannels+1))/(4*NpassHot);

"Total Number of  Passages Hot Side"
	ColdSide.PressureDrop.Npassage = (2*Nchannels-1+(-1)^(Nchannels))/(4*NpassCold);

 end

"Hot Stream Mass Flux in the Channel"
	HotSide.HeatTransfer.Gchannel=HotSide.Properties.Inlet.Fw/(HotSide.PressureDrop.Npassage*Achannel);

"Hot Stream Mass Flux in the Ports"
	HotSide.HeatTransfer.Gports=HotSide.Properties.Inlet.Fw/Aports;

"Cold Stream Mass Flux in the Ports"
	ColdSide.HeatTransfer.Gports=ColdSide.Properties.Inlet.Fw/Aports;

"Cold Stream Mass Flux in the Channel"
	ColdSide.HeatTransfer.Gchannel=ColdSide.Properties.Inlet.Fw/(ColdSide.PressureDrop.Npassage*Achannel);

"Hot Stream Pressure Drop in Ports"
	HotSide.PressureDrop.DPports =1.5*NpassHot*HotSide.HeatTransfer.Gports^2/(2*HotSide.Properties.Average.rho);

"Cold Stream Pressure Drop in Ports"
	ColdSide.PressureDrop.DPports =1.5*NpassCold*ColdSide.HeatTransfer.Gports^2/(2*ColdSide.Properties.Average.rho);

"Hot Stream Pressure Drop in Channels"
	HotSide.PressureDrop.DPchannel =2*HotSide.PressureDrop.fi*NpassHot*Lv*HotSide.HeatTransfer.Gchannel^2/(HotSide.Properties.Average.rho*Dh*HotSide.HeatTransfer.Phi^0.17);

"Cold Stream Pressure Drop in Channels"
	ColdSide.PressureDrop.DPchannel =2*ColdSide.PressureDrop.fi*NpassCold*Lv*ColdSide.HeatTransfer.Gchannel^2/(ColdSide.Properties.Average.rho*Dh*ColdSide.HeatTransfer.Phi^0.17);

"Hot Stream Total Pressure Drop"
	HotSide.PressureDrop.Pdrop =HotSide.PressureDrop.DPchannel+HotSide.PressureDrop.DPports;

"Cold Stream Total Pressure Drop"
	ColdSide.PressureDrop.Pdrop =ColdSide.PressureDrop.DPchannel+ColdSide.PressureDrop.DPports;

 switch ChevronAngle #Pressure Drop Friction Factor According to kumar's (1984)
	
	case "30": #	ChevronAngle <= 30
	
	if 	HotSide.HeatTransfer.Re < 10
		then
				HotSide.PressureDrop.fi 		= Kp1(1)/HotSide.HeatTransfer.Re^Kp2(1);
				ColdSide.PressureDrop.fi  	=	Kp1(1)/ColdSide.HeatTransfer.Re^Kp2(1);
		else
				if 	HotSide.HeatTransfer.Re < 100 
					then
							HotSide.PressureDrop.fi 		= Kp1(2)/HotSide.HeatTransfer.Re^Kp2(2);
							ColdSide.PressureDrop.fi  	=	Kp1(2)/ColdSide.HeatTransfer.Re^Kp2(2);
					else
							HotSide.PressureDrop.fi 		= Kp1(3)/HotSide.HeatTransfer.Re^Kp2(3);
							ColdSide.PressureDrop.fi  	=	Kp1(3)/ColdSide.HeatTransfer.Re^Kp2(3);
				end
			
	end	

	case "45":
	
	if 	HotSide.HeatTransfer.Re < 15
		then
				HotSide.PressureDrop.fi 		= Kp1(4)/HotSide.HeatTransfer.Re^Kp2(4);
				ColdSide.PressureDrop.fi  	=	Kp1(4)/ColdSide.HeatTransfer.Re^Kp2(4);
		else
				if 	HotSide.HeatTransfer.Re < 300 
					then
							HotSide.PressureDrop.fi 		= Kp1(5)/HotSide.HeatTransfer.Re^Kp2(5);
							ColdSide.PressureDrop.fi  	=	Kp1(5)/ColdSide.HeatTransfer.Re^Kp2(5);
					else
							HotSide.PressureDrop.fi 		= Kp1(6)/HotSide.HeatTransfer.Re^Kp2(6);
							ColdSide.PressureDrop.fi  	=	Kp1(6)/ColdSide.HeatTransfer.Re^Kp2(6);
				end
			
	end	

	case "50":
	
	if 	HotSide.HeatTransfer.Re < 20
		then
				HotSide.PressureDrop.fi 		= Kp1(7)/HotSide.HeatTransfer.Re^Kp2(7);
				ColdSide.PressureDrop.fi  	=	Kp1(7)/ColdSide.HeatTransfer.Re^Kp2(7);
		else
				if 	HotSide.HeatTransfer.Re < 300 
					then
							HotSide.PressureDrop.fi 		= Kp1(8)/HotSide.HeatTransfer.Re^Kp2(8);
							ColdSide.PressureDrop.fi  	=	Kp1(8)/ColdSide.HeatTransfer.Re^Kp2(8);
					else
							HotSide.PressureDrop.fi 		= Kp1(9)/HotSide.HeatTransfer.Re^Kp2(9);
							ColdSide.PressureDrop.fi  	=	Kp1(9)/ColdSide.HeatTransfer.Re^Kp2(9);
				end
			
	end
	
	case "60":
	
	if 	HotSide.HeatTransfer.Re < 40
		then
				HotSide.PressureDrop.fi 		= Kp1(10)/HotSide.HeatTransfer.Re^Kp2(10);
				ColdSide.PressureDrop.fi  	=	Kp1(10)/ColdSide.HeatTransfer.Re^Kp2(10);
		else
				if 	HotSide.HeatTransfer.Re < 400 
					then
							HotSide.PressureDrop.fi 		= Kp1(11)/HotSide.HeatTransfer.Re^Kp2(11);
							ColdSide.PressureDrop.fi  	=	Kp1(11)/ColdSide.HeatTransfer.Re^Kp2(11);
					else
							HotSide.PressureDrop.fi 		= Kp1(12)/HotSide.HeatTransfer.Re^Kp2(12);
							ColdSide.PressureDrop.fi  	=	Kp1(12)/ColdSide.HeatTransfer.Re^Kp2(12);
				end
			
	end
	
	case "65": #	ChevronAngle >= 65
	
	if 	HotSide.HeatTransfer.Re < 50
		then
				HotSide.PressureDrop.fi 		= Kp1(13)/HotSide.HeatTransfer.Re^Kp2(13);
				ColdSide.PressureDrop.fi  	=	Kp1(13)/ColdSide.HeatTransfer.Re^Kp2(13);
		else
				if 	HotSide.HeatTransfer.Re < 500 
					then
							HotSide.PressureDrop.fi 		= Kp1(14)/HotSide.HeatTransfer.Re^Kp2(14);
							ColdSide.PressureDrop.fi  	=	Kp1(14)/ColdSide.HeatTransfer.Re^Kp2(14);
					else
							HotSide.PressureDrop.fi 		= Kp1(15)/HotSide.HeatTransfer.Re^Kp2(15);
							ColdSide.PressureDrop.fi  	=	Kp1(15)/ColdSide.HeatTransfer.Re^Kp2(15);
				end
			
	end

 end

 switch ChevronAngle # Heat Transfer Coefficient According to kumar's (1984)

	case "30": #	ChevronAngle <= 30
	
	if 	HotSide.HeatTransfer.Re < 10
		then
				HotSide.HeatTransfer.hcoeff=(HotSide.Properties.Average.K*HotSide.HeatTransfer.PR^(1/3)*HotSide.HeatTransfer.Phi^0.17*Kc1(1)*HotSide.HeatTransfer.Re^Kc2(1))/Dh;
				ColdSide.HeatTransfer.hcoeff =(ColdSide.Properties.Average.K*ColdSide.HeatTransfer.PR^(1/3)*ColdSide.HeatTransfer.Phi^0.17*Kc1(1)*ColdSide.HeatTransfer.Re^Kc2(1))/Dh;
		else
				HotSide.HeatTransfer.hcoeff=(HotSide.Properties.Average.K*HotSide.HeatTransfer.PR^(1/3)*HotSide.HeatTransfer.Phi^0.17*Kc1(2)*HotSide.HeatTransfer.Re^Kc2(2))/Dh;
				ColdSide.HeatTransfer.hcoeff =(ColdSide.Properties.Average.K*ColdSide.HeatTransfer.PR^(1/3)*ColdSide.HeatTransfer.Phi^0.17*Kc1(2)*ColdSide.HeatTransfer.Re^Kc2(2))/Dh;
	end	
	
	case "45":
	
	if 	HotSide.HeatTransfer.Re < 10
		then
				HotSide.HeatTransfer.hcoeff=(HotSide.Properties.Average.K*HotSide.HeatTransfer.PR^(1/3)*HotSide.HeatTransfer.Phi^0.17*Kc1(3)*HotSide.HeatTransfer.Re^Kc2(3))/Dh;
				ColdSide.HeatTransfer.hcoeff =(ColdSide.Properties.Average.K*ColdSide.HeatTransfer.PR^(1/3)*ColdSide.HeatTransfer.Phi^0.17*Kc1(3)*ColdSide.HeatTransfer.Re^Kc2(3))/Dh;
		else
				if 	HotSide.HeatTransfer.Re < 100
					then
							HotSide.HeatTransfer.hcoeff=(HotSide.Properties.Average.K*HotSide.HeatTransfer.PR^(1/3)*HotSide.HeatTransfer.Phi^0.17*Kc1(4)*HotSide.HeatTransfer.Re^Kc2(4))/Dh;
							ColdSide.HeatTransfer.hcoeff =(ColdSide.Properties.Average.K*ColdSide.HeatTransfer.PR^(1/3)*ColdSide.HeatTransfer.Phi^0.17*Kc1(4)*ColdSide.HeatTransfer.Re^Kc2(4))/Dh;
					else
							HotSide.HeatTransfer.hcoeff=(HotSide.Properties.Average.K*HotSide.HeatTransfer.PR^(1/3)*HotSide.HeatTransfer.Phi^0.17*Kc1(5)*HotSide.HeatTransfer.Re^Kc2(5))/Dh;
							ColdSide.HeatTransfer.hcoeff =(ColdSide.Properties.Average.K*ColdSide.HeatTransfer.PR^(1/3)*ColdSide.HeatTransfer.Phi^0.17*Kc1(5)*ColdSide.HeatTransfer.Re^Kc2(5))/Dh;
				end
	end

	case "50":
	
	if 	HotSide.HeatTransfer.Re < 20
		then
				HotSide.HeatTransfer.hcoeff=(HotSide.Properties.Average.K*HotSide.HeatTransfer.PR^(1/3)*HotSide.HeatTransfer.Phi^0.17*Kc1(6)*HotSide.HeatTransfer.Re^Kc2(6))/Dh;
				ColdSide.HeatTransfer.hcoeff =(ColdSide.Properties.Average.K*ColdSide.HeatTransfer.PR^(1/3)*ColdSide.HeatTransfer.Phi^0.17*Kc1(6)*ColdSide.HeatTransfer.Re^Kc2(6))/Dh;
		else
				if 	HotSide.HeatTransfer.Re < 300
					then
							HotSide.HeatTransfer.hcoeff=(HotSide.Properties.Average.K*HotSide.HeatTransfer.PR^(1/3)*HotSide.HeatTransfer.Phi^0.17*Kc1(7)*HotSide.HeatTransfer.Re^Kc2(7))/Dh;
							ColdSide.HeatTransfer.hcoeff =(ColdSide.Properties.Average.K*ColdSide.HeatTransfer.PR^(1/3)*ColdSide.HeatTransfer.Phi^0.17*Kc1(7)*ColdSide.HeatTransfer.Re^Kc2(7))/Dh;
					else
							HotSide.HeatTransfer.hcoeff=(HotSide.Properties.Average.K*HotSide.HeatTransfer.PR^(1/3)*HotSide.HeatTransfer.Phi^0.17*Kc1(8)*HotSide.HeatTransfer.Re^Kc2(8))/Dh;
							ColdSide.HeatTransfer.hcoeff =(ColdSide.Properties.Average.K*ColdSide.HeatTransfer.PR^(1/3)*ColdSide.HeatTransfer.Phi^0.17*Kc1(8)*ColdSide.HeatTransfer.Re^Kc2(8))/Dh;
				end
	end

	case "60":
	
	if 	HotSide.HeatTransfer.Re < 20
		then
				HotSide.HeatTransfer.hcoeff=(HotSide.Properties.Average.K*HotSide.HeatTransfer.PR^(1/3)*HotSide.HeatTransfer.Phi^0.17*Kc1(9)*HotSide.HeatTransfer.Re^Kc2(9))/Dh;
				ColdSide.HeatTransfer.hcoeff =(ColdSide.Properties.Average.K*ColdSide.HeatTransfer.PR^(1/3)*ColdSide.HeatTransfer.Phi^0.17*Kc1(9)*ColdSide.HeatTransfer.Re^Kc2(9))/Dh;
		else
				if 	HotSide.HeatTransfer.Re < 400
					then
							HotSide.HeatTransfer.hcoeff=(HotSide.Properties.Average.K*HotSide.HeatTransfer.PR^(1/3)*HotSide.HeatTransfer.Phi^0.17*Kc1(10)*HotSide.HeatTransfer.Re^Kc2(10))/Dh;
							ColdSide.HeatTransfer.hcoeff =(ColdSide.Properties.Average.K*ColdSide.HeatTransfer.PR^(1/3)*ColdSide.HeatTransfer.Phi^0.17*Kc1(10)*ColdSide.HeatTransfer.Re^Kc2(10))/Dh;
					else
							HotSide.HeatTransfer.hcoeff=(HotSide.Properties.Average.K*HotSide.HeatTransfer.PR^(1/3)*HotSide.HeatTransfer.Phi^0.17*Kc1(11)*HotSide.HeatTransfer.Re^Kc2(11))/Dh;
							ColdSide.HeatTransfer.hcoeff =(ColdSide.Properties.Average.K*ColdSide.HeatTransfer.PR^(1/3)*ColdSide.HeatTransfer.Phi^0.17*Kc1(11)*ColdSide.HeatTransfer.Re^Kc2(11))/Dh;
				end
	end
	
	case "65": #	ChevronAngle >= 65
	
	if 	HotSide.HeatTransfer.Re < 20
		then
				HotSide.HeatTransfer.hcoeff=(HotSide.Properties.Average.K*HotSide.HeatTransfer.PR^(1/3)*HotSide.HeatTransfer.Phi^0.17*Kc1(12)*HotSide.HeatTransfer.Re^Kc2(12))/Dh;
				ColdSide.HeatTransfer.hcoeff =(ColdSide.Properties.Average.K*ColdSide.HeatTransfer.PR^(1/3)*ColdSide.HeatTransfer.Phi^0.17*Kc1(12)*ColdSide.HeatTransfer.Re^Kc2(12))/Dh;
		else
				if 	HotSide.HeatTransfer.Re < 500
					then
							HotSide.HeatTransfer.hcoeff=(HotSide.Properties.Average.K*HotSide.HeatTransfer.PR^(1/3)*HotSide.HeatTransfer.Phi^0.17*Kc1(13)*HotSide.HeatTransfer.Re^Kc2(13))/Dh;
							ColdSide.HeatTransfer.hcoeff =(ColdSide.Properties.Average.K*ColdSide.HeatTransfer.PR^(1/3)*ColdSide.HeatTransfer.Phi^0.17*Kc1(13)*ColdSide.HeatTransfer.Re^Kc2(13))/Dh;
					else
							HotSide.HeatTransfer.hcoeff=(HotSide.Properties.Average.K*HotSide.HeatTransfer.PR^(1/3)*HotSide.HeatTransfer.Phi^0.17*Kc1(14)*HotSide.HeatTransfer.Re^Kc2(14))/Dh;
							ColdSide.HeatTransfer.hcoeff =(ColdSide.Properties.Average.K*ColdSide.HeatTransfer.PR^(1/3)*ColdSide.HeatTransfer.Phi^0.17*Kc1(14)*ColdSide.HeatTransfer.Re^Kc2(14))/Dh;
				end
	end

 end

"Hot Stream Velocity in Channels"
	HotSide.PressureDrop.Vchannel =HotSide.HeatTransfer.Gchannel/HotSide.Properties.Average.rho;

"Cold Stream Velocity in Channels"
	ColdSide.PressureDrop.Vchannel =ColdSide.HeatTransfer.Gchannel/ColdSide.Properties.Average.rho;

"Hot Stream Velocity in Ports"
	HotSide.PressureDrop.Vports =HotSide.Properties.Inlet.Fw/(Aports*HotSide.Properties.Inlet.rho);

"Cold Stream Velocity in Ports"
	ColdSide.PressureDrop.Vports =ColdSide.Properties.Inlet.Fw/(Aports*ColdSide.Properties.Inlet.rho);

"Hot Stream Reynolds Number"
	HotSide.HeatTransfer.Re =Dh*HotSide.HeatTransfer.Gchannel/HotSide.Properties.Average.Mu;

"Cold Stream Reynolds Number"
	ColdSide.HeatTransfer.Re =Dh*ColdSide.HeatTransfer.Gchannel/ColdSide.Properties.Average.Mu;

"Hot Stream Prandtl Number"
	HotSide.HeatTransfer.PR= ((HotSide.Properties.Average.Cp/HotSide.Properties.Average.Mw)*HotSide.Properties.Average.Mu)/HotSide.Properties.Average.K;

"Cold Stream Prandtl Number"
	ColdSide.HeatTransfer.PR = ((ColdSide.Properties.Average.Cp/ColdSide.Properties.Average.Mw)*ColdSide.Properties.Average.Mu)/ColdSide.Properties.Average.K;

"Hot Stream Viscosity Correction"
	HotSide.HeatTransfer.Phi= HotSide.Properties.Average.Mu/HotSide.Properties.Wall.Mu;

"Cold Stream Viscosity Correction"
	ColdSide.HeatTransfer.Phi= ColdSide.Properties.Average.Mu/ColdSide.Properties.Wall.Mu;

"Hot Stream Outlet Pressure"
	OutletHot.P  = InletHot.P - HotSide.PressureDrop.Pdrop;
	
"Cold Stream Outlet Pressure"
	OutletCold.P  = InletCold.P - ColdSide.PressureDrop.Pdrop;
	
"Overall Heat Transfer Coefficient Clean"
	Thermal.Uc/HotSide.HeatTransfer.hcoeff +Thermal.Uc*pt/Kwall+Thermal.Uc/ColdSide.HeatTransfer.hcoeff=1;

"Overall Heat Transfer Coefficient Dirty"
	Thermal.Ud*(1/HotSide.HeatTransfer.hcoeff +pt/Kwall+1/ColdSide.HeatTransfer.hcoeff + Rfc + Rfh)=1;

 switch Method
	
	case "LMTD":
	
"Duty"
	Thermal.Q = Thermal.Ud*Atotal*Thermal.LMTD*Thermal.Fc;
	
	case "NTU":

"Duty"
	Thermal.Q = Thermal.Eft*Thermal.Cmin*(InletHot.T-InletCold.T);

 end

"Temperature Difference at Inlet - Counter Flow"
	Thermal.DT0 = InletHot.T - OutletCold.T;

"Temperature Difference at Outlet - Counter Flow"
	Thermal.DTL = OutletHot.T - InletCold.T;

"Heat Capacity Ratio"
	Thermal.Cr =Thermal.Cmin/Thermal.Cmax;

"Minimum Heat Capacity"
	Thermal.Cmin  = min([HotSide.HeatTransfer.WCp,ColdSide.HeatTransfer.WCp]);

"Maximum Heat Capacity"
	Thermal.Cmax  = max([HotSide.HeatTransfer.WCp,ColdSide.HeatTransfer.WCp]);

"Hot Stream Heat Capacity"
	HotSide.HeatTransfer.WCp  = InletHot.F*HotSide.Properties.Average.Cp;

"Cold Stream Heat Capacity"
	ColdSide.HeatTransfer.WCp = InletCold.F*ColdSide.Properties.Average.Cp;

"Number of Units Transference for the Whole Heat Exchanger"
	Thermal.NTU = max([HotSide.HeatTransfer.NTU,ColdSide.HeatTransfer.NTU]);

"Number of Units Transference for Hot Side"
	HotSide.HeatTransfer.NTU*HotSide.HeatTransfer.WCp = Thermal.Ud*Atotal;

"Number of Units Transference for Cold Side"
	ColdSide.HeatTransfer.NTU*ColdSide.HeatTransfer.WCp = Thermal.Ud*Atotal;

 if Thermal.Cr equal 1 # To be Fixed: Effectiveness in true counter flow !
	
	then
"Effectiveness in Counter Flow"
	Thermal.Eft = Thermal.NTU/(1+Thermal.NTU);
	
"LMTD Correction Factor"
	Thermal.Fc =Thermal.Eft/(1-Thermal.Eft)/Thermal.NTU;
	
	else
"Effectiveness in Counter Flow"
	Thermal.Eft = (1-exp(-Thermal.NTU*(1-Thermal.Cr)))/(1-Thermal.Cr*exp(-Thermal.NTU*(1-Thermal.Cr)));
	
"LMTD Correction Factor"
	Thermal.Fc =(ln(abs(1-Thermal.Eft*Thermal.Cr))-ln(abs(1-Thermal.Eft)))/(Thermal.NTU*(1-Thermal.Cr));
	
 end
end