#*-------------------------------------------------------------------
* EMSO Model Library (EML) Copyright (C) 2004 - 2007 ALSOC.
*
* This LIBRARY is free software; you can distribute it and/or modify
* it under the therms of the ALSOC FREE LICENSE as available at
* http://www.enq.ufrgs.br/alsoc.
*
* EMSO Copyright (C) 2004 - 2007 ALSOC, original code
* from http://www.rps.eng.br Copyright (C) 2002-2004.
* All rights reserved.
*
* EMSO is distributed under the therms of the ALSOC LICENSE as
* available at http://www.enq.ufrgs.br/alsoc.
*
*----------------------------------------------------------------------
* Author: Rafael de Pelegrini Soares
* $Id: sample_cstr_simple.mso 176 2007-03-04 04:56:54Z arge $
*---------------------------------------------------------------------*#

using "reactors/cstr";

FlowSheet CSTR

	PARAMETERS
	Fin as flow_vol;
	Fout as flow_vol;
	CA0 as conc_mol;
	CB0 as conc_mol;
	FA0 as flow_mol;
	FB0 as flow_mol;
	# Troca térmica
	Tw as temperature;
	U as heat_trans_coeff;
	A as area;
	# Reação
	k0 as frequency;
	Ea as energy_mol (Brief = "Energia de Ativação");
	R  as entr_mol;
	
	VARIABLES
	q as heat_rate;
	HR as energy_mol;
	T as temperature;
	k as frequency;
	CA as conc_mol;
	CB as conc_mol;
	V as volume;
	rA as reaction_mol;
	rB as reaction_mol;
	Cps as cp_mol; # (Unit='cal/mol/K');
	T0 as temperature;
	
	EQUATIONS
	
	"Troca térmica"
	q=U*A*(T-Tw); #j/s
	
	"Constante de Reação"
	k=k0*exp(Ea/R*(1/(436.15*'K') - 1/T));
	
	"Taxas de Reação"
	rA=-k*CA; # (mol/m^3/h)  >> reação de primeira ordem <<
	rB=-rA;
	
	"Calor de Reação"
	HR=-(80*250)*'cal/mol';
	
	"Cp da mistura"
	Cps=(0.5*250)*3*'J/mol/K';
	
	"Balanço de Energia"
	diff(T)=((U*A*(Tw-T)-FA0*Cps*(T-T0)+HR*rA*V)/(CA0*V*Cps));
	
	"Bal. Material Global"
	diff(V)=Fin-Fout;
	
	"Bal. Material A"
	diff(V*CA)=(FA0-Fout*CA+V*rA);
	
	"Bal. Material B"
	diff(V*CB)=(FB0-Fout*CB+V*rB);
	
	"Temperatura da corrente de alimentação"
	T0= (40 + 273.15 + time*200/1000/'s') * 'K';
	
	SET
	Fin = 0.125997903*'m^3/h';
	Fout = 0.125997903*'m^3/h';
	CA0=9.3652352*'mol/m^3';
	CB0=0*'mol/m^3';
	FA0 = Fin*CA0;
	FB0 = Fin*CB0;
	Tw = (140+273)*'K';
	k0=0.8*'1/h'; #constante para T=436.15 K
	Ea=28960*'cal/mol';
	R=1.98*'cal/mol/K';
	U = 0 *'cal/m^2/K/s';#isolado
	A = 1*'m^2'; 
	
	INITIAL
	T = (140 + 273) * 'K';
	V = 0.9*6*'m^3';
	CA = 2*'mol/m^3';
	CB = 6*'mol/m^3';
	
	OPTIONS
	TimeStep = 10;
	TimeEnd = 1200;
end