#*-------------------------------------------------------------------
* EMSO Model Library (EML) Copyright (C) 2004 - 2007 ALSOC.
*
* This LIBRARY is free software; you can distribute it and/or modify
* it under the therms of the ALSOC FREE LICENSE as available at
* http://www.enq.ufrgs.br/alsoc.
*
* EMSO Copyright (C) 2004 - 2007 ALSOC, original code
* from http://www.rps.eng.br Copyright (C) 2002-2004.
* All rights reserved.
*
* EMSO is distributed under the therms of the ALSOC LICENSE as
* available at http://www.enq.ufrgs.br/alsoc.
*
*--------------------------------------------------------------------
* Author: Gerson Balbueno Bicca 
* $Id: DoublePipe.mso 110 2007-01-12 18:44:02Z bicca $
*------------------------------------------------------------------*#

using "HEX_Engine";
#+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++#
# 	Basic Models for Double Pipe Heat Exchangers
#+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++#

Model DoublePipe_Basic
	
PARAMETERS
ext PP 	    	as CalcObject	(Brief="External Physical Properties");
ext NComp   	as Integer   	(Brief="Number of Components");
	M(NComp)  	as molweight 	(Brief="Component Mol Weight");
	
VARIABLES

in  Inlet	    	as Inlet_Main_Stream; 	# Hot and Cold Inlets
out Outlet      	as Outlet_Main_Stream;	# Hot and Cold Outlets
	Properties  	as Main_Properties;		# Hot and Cold Properties
	Details     	as Details_Main;
	Inner 			as Main_DoublePipe;
	Outer 			as Main_DoublePipe;
	Resistances 	as Main_Resistances;

SET

	M  = PP.MolecularWeight();

EQUATIONS

"Hot Stream Average Temperature"
	Properties.Hot.Average.T = 0.5*Inlet.Hot.T + 0.5*Outlet.Hot.T;
	
"Cold Stream Average Temperature"
	Properties.Cold.Average.T = 0.5*Inlet.Cold.T + 0.5*Outlet.Cold.T;
	
"Hot Stream Average Pressure"
	Properties.Hot.Average.P = 0.5*Inlet.Hot.P+0.5*Outlet.Hot.P;
	
"Cold Stream Average Pressure"
	Properties.Cold.Average.P = 0.5*Inlet.Cold.P+0.5*Outlet.Cold.P;

"Cold Stream Wall Temperature"
	Properties.Cold.Wall.Twall =   0.5*Properties.Hot.Average.T + 0.5*Properties.Cold.Average.T;

"Hot Stream Wall Temperature"
	Properties.Hot.Wall.Twall =   0.5*Properties.Hot.Average.T + 0.5*Properties.Cold.Average.T;

"Hot Stream Average Molecular Weight"
	Properties.Hot.Average.Mw = sum(M*Inlet.Hot.z);

"Cold Stream Average Molecular Weight"
	Properties.Cold.Average.Mw = sum(M*Inlet.Cold.z);

if Inlet.Cold.v equal 0
	then	
"Heat Capacity Cold Stream"
	Properties.Cold.Average.Cp 		= 	PP.LiquidCp(Properties.Cold.Average.T,Properties.Cold.Average.P,Inlet.Cold.z);
	Properties.Cold.Inlet.Cp 		= 	PP.LiquidCp(Inlet.Cold.T,Inlet.Cold.P,Inlet.Cold.z);
	Properties.Cold.Outlet.Cp 		= 	PP.LiquidCp(Outlet.Cold.T,Outlet.Cold.P,Outlet.Cold.z);

"Mass Density Cold Stream"
	Properties.Cold.Average.rho 	= 	PP.LiquidDensity(Properties.Cold.Average.T,Properties.Cold.Average.P,Inlet.Cold.z);
	Properties.Cold.Inlet.rho 		= 	PP.LiquidDensity(Inlet.Cold.T,Inlet.Cold.P,Inlet.Cold.z);
	Properties.Cold.Outlet.rho 		= 	PP.LiquidDensity(Outlet.Cold.T,Outlet.Cold.P,Outlet.Cold.z);

"Viscosity Cold Stream"
	Properties.Cold.Average.Mu 		= 	PP.LiquidViscosity(Properties.Cold.Average.T,Properties.Cold.Average.P,Inlet.Cold.z);
	Properties.Cold.Inlet.Mu 		= 	PP.LiquidViscosity(Inlet.Cold.T,Inlet.Cold.P,Inlet.Cold.z);
	Properties.Cold.Outlet.Mu 		= 	PP.LiquidViscosity(Outlet.Cold.T,Outlet.Cold.P,Outlet.Cold.z);

"Conductivity Cold Stream"
	Properties.Cold.Average.K	 	= 	PP.LiquidThermalConductivity(Properties.Cold.Average.T,Properties.Cold.Average.P,Inlet.Cold.z);
	Properties.Cold.Inlet.K 		= 	PP.LiquidThermalConductivity(Inlet.Cold.T,Inlet.Cold.P,Inlet.Cold.z);
	Properties.Cold.Outlet.K 		= 	PP.LiquidThermalConductivity(Outlet.Cold.T,Outlet.Cold.P,Outlet.Cold.z);

"Heat Capacity Cold Stream"
	Properties.Cold.Wall.Cp 		= 	PP.LiquidCp(Properties.Cold.Wall.Twall,Properties.Cold.Average.P,Inlet.Cold.z);
	
"Viscosity Cold Stream"
	Properties.Cold.Wall.Mu 		= 	PP.LiquidViscosity(Properties.Cold.Wall.Twall,Properties.Cold.Average.P,Inlet.Cold.z);

"Conductivity Cold Stream"
	Properties.Cold.Wall.K 			= 	PP.LiquidThermalConductivity(Properties.Cold.Wall.Twall,Properties.Cold.Average.P,Inlet.Cold.z);


	else

"Heat Capacity Cold Stream"
	Properties.Cold.Average.Cp 	=	PP.VapourCp(Properties.Cold.Average.T,Properties.Cold.Average.P,Inlet.Cold.z);
	Properties.Cold.Inlet.Cp 	=	PP.VapourCp(Inlet.Cold.T,Inlet.Cold.P,Inlet.Cold.z);
	Properties.Cold.Outlet.Cp 	=	PP.VapourCp(Outlet.Cold.T,Outlet.Cold.P,Outlet.Cold.z);

"Mass Density Cold Stream"
	Properties.Cold.Average.rho 	=	PP.VapourDensity(Properties.Cold.Average.T,Properties.Cold.Average.P,Inlet.Cold.z);
	Properties.Cold.Inlet.rho 		=	PP.VapourDensity(Inlet.Cold.T,Inlet.Cold.P,Inlet.Cold.z);
	Properties.Cold.Outlet.rho 		=	PP.VapourDensity(Outlet.Cold.T,Outlet.Cold.P,Outlet.Cold.z);

"Viscosity Cold Stream"
	Properties.Cold.Average.Mu 		=	PP.VapourViscosity(Properties.Cold.Average.T,Properties.Cold.Average.P,Inlet.Cold.z);
	Properties.Cold.Inlet.Mu 		=	PP.VapourViscosity(Inlet.Cold.T,Inlet.Cold.P,Inlet.Cold.z);
	Properties.Cold.Outlet.Mu 		=	PP.VapourViscosity(Outlet.Cold.T,Outlet.Cold.P,Outlet.Cold.z);

"Conductivity Cold Stream"
	Properties.Cold.Average.K 		= 	PP.VapourThermalConductivity(Properties.Cold.Average.T,Properties.Cold.Average.P,Inlet.Cold.z);
	Properties.Cold.Inlet.K 		= 	PP.VapourThermalConductivity(Inlet.Cold.T,Inlet.Cold.P,Inlet.Cold.z);
	Properties.Cold.Outlet.K 		= 	PP.VapourThermalConductivity(Outlet.Cold.T,Outlet.Cold.P,Outlet.Cold.z);
	
"Heat Capacity Cold Stream"
	Properties.Cold.Wall.Cp 		=	PP.VapourCp(Properties.Cold.Wall.Twall,Properties.Cold.Average.P,Inlet.Cold.z);


"Viscosity Cold Stream"
	Properties.Cold.Wall.Mu 		=	PP.VapourViscosity(Properties.Cold.Wall.Twall,Properties.Cold.Average.P,Inlet.Cold.z);

"Conductivity Cold Stream"
	Properties.Cold.Wall.K 			= 	PP.VapourThermalConductivity(Properties.Cold.Wall.Twall,Properties.Cold.Average.P,Inlet.Cold.z);
	
	
	
end

if Inlet.Hot.v equal 0

	then

"Heat Capacity Hot Stream"
	Properties.Hot.Average.Cp 	=		PP.LiquidCp(Properties.Hot.Average.T,Properties.Hot.Average.P,Inlet.Hot.z);
	Properties.Hot.Inlet.Cp 	=		PP.LiquidCp(Inlet.Hot.T,Inlet.Hot.P,Inlet.Hot.z);
	Properties.Hot.Outlet.Cp 	=		PP.LiquidCp(Outlet.Hot.T,Outlet.Hot.P,Outlet.Hot.z);

"Mass Density Hot Stream"
	Properties.Hot.Average.rho 	=		PP.LiquidDensity(Properties.Hot.Average.T,Properties.Hot.Average.P,Inlet.Hot.z);
	Properties.Hot.Inlet.rho 	=		PP.LiquidDensity(Inlet.Hot.T,Inlet.Hot.P,Inlet.Hot.z);
	Properties.Hot.Outlet.rho 	=		PP.LiquidDensity(Outlet.Hot.T,Outlet.Hot.P,Outlet.Hot.z);

"Viscosity Hot Stream"
	Properties.Hot.Average.Mu 	=		PP.LiquidViscosity(Properties.Hot.Average.T,Properties.Hot.Average.P,Inlet.Hot.z);	
	Properties.Hot.Inlet.Mu 	=		PP.LiquidViscosity(Inlet.Hot.T,Inlet.Hot.P,Inlet.Hot.z);	
	Properties.Hot.Outlet.Mu 	=		PP.LiquidViscosity(Outlet.Hot.T,Outlet.Hot.P,Outlet.Hot.z);	

"Conductivity Hot Stream"
	Properties.Hot.Average.K 	=		PP.LiquidThermalConductivity(Properties.Hot.Average.T,Properties.Hot.Average.P,Inlet.Hot.z);	
	Properties.Hot.Inlet.K 		=		PP.LiquidThermalConductivity(Inlet.Hot.T,Inlet.Hot.P,Inlet.Hot.z);	
	Properties.Hot.Outlet.K 	=		PP.LiquidThermalConductivity(Outlet.Hot.T,Outlet.Hot.P,Outlet.Hot.z);	

"Heat Capacity Hot Stream"
	Properties.Hot.Wall.Cp 		=		PP.LiquidCp(Properties.Hot.Wall.Twall,Properties.Hot.Average.P,Inlet.Hot.z);

"Viscosity Hot Stream"
	Properties.Hot.Wall.Mu 		=		PP.LiquidViscosity(Properties.Hot.Wall.Twall,Properties.Hot.Average.P,Inlet.Hot.z);	

"Conductivity Hot Stream"
	Properties.Hot.Wall.K 		=		PP.LiquidThermalConductivity(Properties.Hot.Wall.Twall,Properties.Hot.Average.P,Inlet.Hot.z);	
	

	else

"Heat Capacity Hot Stream"
	Properties.Hot.Average.Cp 	=		PP.VapourCp(Properties.Hot.Average.T,Properties.Hot.Average.P,Inlet.Hot.z);
	Properties.Hot.Inlet.Cp 	=		PP.VapourCp(Inlet.Hot.T,Inlet.Hot.P,Inlet.Hot.z);
	Properties.Hot.Outlet.Cp 	=		PP.VapourCp(Outlet.Hot.T,Outlet.Hot.P,Outlet.Hot.z);

"Mass Density Hot Stream"
	Properties.Hot.Average.rho 	=		PP.VapourDensity(Properties.Hot.Average.T,Properties.Hot.Average.P,Inlet.Hot.z);
	Properties.Hot.Inlet.rho 	=		PP.VapourDensity(Inlet.Hot.T,Inlet.Hot.P,Inlet.Hot.z);
	Properties.Hot.Outlet.rho 	=		PP.VapourDensity(Outlet.Hot.T,Outlet.Hot.P,Outlet.Hot.z);

"Viscosity Hot Stream"
	Properties.Hot.Average.Mu 	=		PP.VapourViscosity(Properties.Hot.Average.T,Properties.Hot.Average.P,Inlet.Hot.z);
	Properties.Hot.Inlet.Mu 	=		PP.VapourViscosity(Inlet.Hot.T,Inlet.Hot.P,Inlet.Hot.z);
	Properties.Hot.Outlet.Mu 	=		PP.VapourViscosity(Outlet.Hot.T,Outlet.Hot.P,Outlet.Hot.z);

"Conductivity Hot Stream"
	Properties.Hot.Average.K 	=		PP.VapourThermalConductivity(Properties.Hot.Average.T,Properties.Hot.Average.P,Inlet.Hot.z);	
	Properties.Hot.Inlet.K 		=		PP.VapourThermalConductivity(Inlet.Hot.T,Inlet.Hot.P,Inlet.Hot.z);	
	Properties.Hot.Outlet.K 	=		PP.VapourThermalConductivity(Outlet.Hot.T,Outlet.Hot.P,Outlet.Hot.z);	

"Heat Capacity Hot Stream"
	Properties.Hot.Wall.Cp 		=		PP.VapourCp(Properties.Hot.Wall.Twall,Properties.Hot.Average.P,Inlet.Hot.z);

"Viscosity Hot Stream"
	Properties.Hot.Wall.Mu 		=		PP.VapourViscosity(Properties.Hot.Wall.Twall,Properties.Hot.Average.P,Inlet.Hot.z);

"Conductivity Hot Stream"
	Properties.Hot.Wall.K 		=		PP.VapourThermalConductivity(Properties.Hot.Wall.Twall,Properties.Hot.Average.P,Inlet.Hot.z);	


end

#+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++#
# 	Thermal Details
#+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++#
"Hot Stream Heat Capacity"
	Details.Ch =Inlet.Hot.F*Properties.Hot.Average.Cp; 
	
"Cold Stream Heat Capacity"
	Details.Cc =Inlet.Cold.F*Properties.Cold.Average.Cp;

"Minimum Heat Capacity"
	Details.Cmin  = min([Details.Ch,Details.Cc]);

"Maximum Heat Capacity"
	Details.Cmax  = max([Details.Ch,Details.Cc]);

"Heat Capacity Ratio"	
	Details.Cr*Details.Cmax   = Details.Cmin;
	
#--------------------------------------------------------------------
# 	Energy Balance
#--------------------------------------------------------------------

"Energy Balance Hot Stream"
	Details.Q = Inlet.Hot.F*(Inlet.Hot.h-Outlet.Hot.h);

"Energy Balance Cold Stream"
	Details.Q = Inlet.Cold.F*(Outlet.Cold.h - Inlet.Cold.h);

#--------------------------------------------------------------------
# 	Material Balance
#--------------------------------------------------------------------

"Flow Mass Inlet Cold Stream"
	Properties.Cold.Inlet.Fw	=  sum(M*Inlet.Cold.z)*Inlet.Cold.F;

"Flow Mass Outlet Cold Stream"
	Properties.Cold.Outlet.Fw	=  sum(M*Outlet.Cold.z)*Outlet.Cold.F;

"Flow Mass Inlet Hot Stream"
	Properties.Hot.Inlet.Fw		=  sum(M*Inlet.Hot.z)*Inlet.Hot.F;

"Flow Mass Outlet Hot Stream"	
	Properties.Hot.Outlet.Fw	=  sum(M*Outlet.Hot.z)*Outlet.Hot.F;

"Molar Balance Hot Stream"
	Inlet.Hot.F  = Outlet.Hot.F;
	
"Molar Balance Cold Stream"
	Inlet.Cold.F = Outlet.Cold.F;

#+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++#
# 	Constraints
#+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++#
"Hot Stream Molar Fraction Constraint"
	Outlet.Hot.z=Inlet.Hot.z;
	
"Cold Stream Molar Fraction Constraint"
	Outlet.Cold.z=Inlet.Cold.z;
	
"No Phase Change In Cold Stream"
	Inlet.Cold.v=Outlet.Cold.v;

"No Phase Change In Hot Stream"
	Inlet.Hot.v=Outlet.Hot.v;
	
if Inner.PressureDrop.Re < 2300

	then
"Inner Side Friction Factor - laminar Flow"
	Inner.PressureDrop.fi*Inner.PressureDrop.Re = 16;

	else 
"Inner Side Friction Factor - Turbulent Flow"
	(Inner.PressureDrop.fi-0.0035)*(Inner.PressureDrop.Re^0.42) = 0.264;

end	


if Outer.PressureDrop.Re < 2300

	then
"Inner Side Friction Factor - laminar Flow"
	Outer.PressureDrop.fi*Outer.PressureDrop.Re = 16;

	else 
"Inner Side Friction Factor - Turbulent Flow"
	(Outer.PressureDrop.fi - 0.0035)*(Outer.PressureDrop.Re^0.42) = 0.264;

end

end

Model DoublePipe 					as DoublePipe_Basic
	
PARAMETERS

	HE	    	as CalcObject	(Brief="STHE Calculations",File="heatex");
	Pi			as constant 	(Brief="Pi Number",Default=3.14159265);
	Hside 	    as Integer 		(Brief="Fluid Alocation Flag-Default:Outer",Lower=0,Upper=1);
	Side		as Integer		(Brief="Flow Direction",Lower=0,Upper=1);
	DoInner  	as length		(Brief="Outside Diameter of Inner Pipe",Lower=1e-6);
	DiInner		as length		(Brief="Inside Diameter of Inner Pipe",Lower=1e-10);
	DiOuter		as length		(Brief="Inside Diameter of Outer pipe",Lower=1e-10);
	Lpipe		as length		(Brief="Effective Tube Length",Lower=0.1);
	Kwall		as conductivity (Brief="Tube Wall Material Thermal Conductivity",Default=1.0);
	
SET
	Pi  	= 3.14159265;
	Hside	= HE.FluidAlocation();
	Side 	= HE.FlowDir();

#"Inner Pipe Cross Sectional Area for Flow"
	Inner.HeatTransfer.As=Pi*DiInner*DiInner/4;
	
#"Outer Pipe Cross Sectional Area for Flow"
	Outer.HeatTransfer.As=Pi*(DiOuter*DiOuter-DoInner*DoInner)/4;
	
#"Inner Pipe Hydraulic Diameter for Heat Transfer"
	Inner.HeatTransfer.Dh=DiInner;
	
#"Outer Pipe Hydraulic Diameter for Heat Transfer"
	Outer.HeatTransfer.Dh=(DiOuter*DiOuter-DoInner*DoInner)/DoInner;

#"Inner Pipe Hydraulic Diameter for Pressure Drop"
	Inner.PressureDrop.Dh=DiInner;
	
#"Outer Pipe Hydraulic Diameter for Pressure Drop"
	Outer.PressureDrop.Dh=DiOuter-DoInner;

EQUATIONS

"Exchange Surface Area"
	Details.A=Pi*DoInner*Lpipe;

if Hside equal 1
	
	then
	
"Pressure Drop Hot Stream"
	Outlet.Hot.P  = Inlet.Hot.P - Outer.PressureDrop.Pdrop;

"Pressure Drop Cold Stream"
	Outlet.Cold.P  = Inlet.Cold.P - Inner.PressureDrop.Pdrop;
	
"Outer Pipe Film Coefficient"
	Outer.HeatTransfer.hcoeff= HE.PipeFilmCoeff(Outer.HeatTransfer.Re,Outer.HeatTransfer.PR,Properties.Hot.Average.K,Outer.HeatTransfer.Dh,Lpipe)*Outer.HeatTransfer.Phi;

"Inner Pipe Film Coefficient"
	Inner.HeatTransfer.hcoeff= HE.PipeFilmCoeff(Inner.HeatTransfer.Re,Inner.HeatTransfer.PR,Properties.Cold.Average.K,DiInner,Lpipe)*Inner.HeatTransfer.Phi;

"Outer Pipe Pressure Drop"
	Outer.PressureDrop.Pdrop = (2*Outer.PressureDrop.fi*Lpipe*Properties.Hot.Average.rho*Outer.HeatTransfer.Vmean^2)/(Outer.PressureDrop.Dh*Outer.HeatTransfer.Phi);
	
"Inner Pipe Pressure Drop"
	Inner.PressureDrop.Pdrop = (2*Inner.PressureDrop.fi*Lpipe*Properties.Cold.Average.rho*Inner.HeatTransfer.Vmean^2)/(DiInner*Inner.HeatTransfer.Phi);

"Outer Pipe Phi correction"
	Outer.HeatTransfer.Phi = HE.PhiCorrection(Properties.Hot.Average.Mu,Properties.Hot.Wall.Mu);
	
"Inner Pipe Phi correction"
	Inner.HeatTransfer.Phi  = HE.PhiCorrection(Properties.Cold.Average.Mu,Properties.Cold.Wall.Mu);

"Outer Pipe Prandtl Number"
	Outer.HeatTransfer.PR = ((Properties.Hot.Average.Cp/Properties.Hot.Average.Mw)*Properties.Hot.Average.Mu)/Properties.Hot.Average.K;

"Inner Pipe Prandtl Number"
	Inner.HeatTransfer.PR = ((Properties.Cold.Average.Cp/Properties.Cold.Average.Mw)*Properties.Cold.Average.Mu)/Properties.Cold.Average.K;

"Outer Pipe Reynolds Number for Heat Transfer"
	Outer.HeatTransfer.Re =	(Properties.Hot.Average.rho*Outer.HeatTransfer.Vmean*Outer.HeatTransfer.Dh)/Properties.Hot.Average.Mu;

"Outer Pipe Reynolds Number for Pressure Drop"
	Outer.PressureDrop.Re =	(Properties.Hot.Average.rho*Outer.HeatTransfer.Vmean*Outer.PressureDrop.Dh)/Properties.Hot.Average.Mu;

"Inner Pipe Reynolds Number for Heat Transfer"
	Inner.HeatTransfer.Re =	(Properties.Cold.Average.rho*Inner.HeatTransfer.Vmean*Inner.HeatTransfer.Dh)/Properties.Cold.Average.Mu;

"Inner Pipe Reynolds Number for Pressure Drop"
	Inner.PressureDrop.Re =	Inner.HeatTransfer.Re;

"Outer Pipe Velocity"
	Outer.HeatTransfer.Vmean*(Outer.HeatTransfer.As*Properties.Hot.Average.rho)  = Properties.Hot.Inlet.Fw;

"Inner Pipe Velocity"
	Inner.HeatTransfer.Vmean*(Inner.HeatTransfer.As*Properties.Cold.Average.rho)  = Properties.Cold.Inlet.Fw;

	else
	
"Pressure Drop Hot Stream"
	Outlet.Hot.P  = Inlet.Hot.P - Inner.PressureDrop.Pdrop;

"Pressure Drop Cold Stream"
	Outlet.Cold.P  = Inlet.Cold.P - Outer.PressureDrop.Pdrop;
	
"Inner Pipe Film Coefficient"
	Inner.HeatTransfer.hcoeff= HE.PipeFilmCoeff(Inner.HeatTransfer.Re,Inner.HeatTransfer.PR,Properties.Hot.Average.K,DiInner,Lpipe)*Inner.HeatTransfer.Phi;

"Outer Pipe Film Coefficient"
	Outer.HeatTransfer.hcoeff= HE.PipeFilmCoeff(Outer.HeatTransfer.Re,Outer.HeatTransfer.PR,Properties.Cold.Average.K,Outer.HeatTransfer.Dh,Lpipe)*Outer.HeatTransfer.Phi;

"Outer Pipe Pressure Drop"
	Outer.PressureDrop.Pdrop = (2*Outer.PressureDrop.fi*Lpipe*Properties.Cold.Average.rho*Outer.HeatTransfer.Vmean^2)/(Outer.PressureDrop.Dh*Outer.HeatTransfer.Phi);
	
"Inner Pipe Pressure Drop"
	Inner.PressureDrop.Pdrop 	= (2*Inner.PressureDrop.fi*Lpipe*Properties.Hot.Average.rho*Inner.HeatTransfer.Vmean^2)/(DiInner*Inner.HeatTransfer.Phi);

"Outer Pipe Phi correction"
	Outer.HeatTransfer.Phi 		= HE.PhiCorrection(Properties.Cold.Average.Mu,Properties.Cold.Wall.Mu);
	
"Inner Pipe Phi correction"
	Inner.HeatTransfer.Phi  	= HE.PhiCorrection(Properties.Hot.Average.Mu,Properties.Hot.Wall.Mu);
	
"Outer Pipe Prandtl Number"
	Outer.HeatTransfer.PR 		= ((Properties.Cold.Average.Cp/Properties.Cold.Average.Mw)*Properties.Cold.Average.Mu)/Properties.Cold.Average.K;

"Inner Pipe Prandtl Number"
	Inner.HeatTransfer.PR 		= ((Properties.Hot.Average.Cp/Properties.Hot.Average.Mw)*Properties.Hot.Average.Mu)/Properties.Hot.Average.K;

"Outer Pipe Reynolds Number for Heat Transfer"
	Outer.HeatTransfer.Re 		= (Properties.Cold.Average.rho*Outer.HeatTransfer.Vmean*Outer.HeatTransfer.Dh)/Properties.Cold.Average.Mu;

"Outer Pipe Reynolds Number for Pressure Drop"
	Outer.PressureDrop.Re 		= (Properties.Cold.Average.rho*Outer.HeatTransfer.Vmean*Outer.PressureDrop.Dh)/Properties.Cold.Average.Mu;

"Inner Pipe Reynolds Number for Pressure Drop"
	Inner.PressureDrop.Re 		= Inner.HeatTransfer.Re;

"Inner Pipe Reynolds Number for Heat Transfer"
	Inner.HeatTransfer.Re 		= (Properties.Hot.Average.rho*Inner.HeatTransfer.Vmean*Inner.HeatTransfer.Dh)/Properties.Hot.Average.Mu;

"Outer Pipe Velocity"
	Outer.HeatTransfer.Vmean*(Outer.HeatTransfer.As*Properties.Cold.Average.rho)= Properties.Cold.Inlet.Fw;
	
"Inner Pipe Velocity"
	Inner.HeatTransfer.Vmean*(Inner.HeatTransfer.As*Properties.Hot.Average.rho)	= Properties.Hot.Inlet.Fw;

end

"Inner Pipe Resistance"	
	Resistances.Rtube*(Inner.HeatTransfer.hcoeff*DiInner) = DoInner;
	
"Wall Resistance"
	Resistances.Rwall*(2*Kwall) = DoInner*ln(DoInner/DiInner);

"Outer Pipe Resistance"
	Resistances.Rshell*(Outer.HeatTransfer.hcoeff)=1;

"Overall Heat Transfer Coefficient Clean"
	Details.Uc*(Resistances.Rtube+Resistances.Rwall+Resistances.Rshell)=1;

"Overall Heat Transfer Coefficient Dirty"
	Details.Ud*(Resistances.Rfi*(DoInner/DiInner) + Resistances.Rfo + Resistances.Rtube + Resistances.Rwall + Resistances.Rshell)=1;
	
end

Model DoublePipe_Basic_NTU	 		as DoublePipe
#+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++#
# 	Basic Model Double Pipe Heat Exchanger - NTU Method
#+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++#
VARIABLES

Eft	  as positive (Brief="Effectiveness",Default=0.5,Lower=1e-12);

EQUATIONS	

"Energy Balance"
	Details.Q	= Eft*Details.Cmin*(Inlet.Hot.T-Inlet.Cold.T);	


end

Model DoublePipe_Basic_LMTD	 		as DoublePipe
#+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++#
# 	Basic Model for Double Pipe Heat Exchanger- LMTD Method
#+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++#
VARIABLES

DT0     as temp_delta	(Brief="Temperature Difference at Inlet",Lower=1);
DTL		as temp_delta	(Brief="Temperature Difference at Outlet",Lower=1);
LMTD	as temp_delta	(Brief="Logarithmic Mean Temperature Difference",Lower=1);

EQUATIONS
#+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++#
# 			Log Mean Temperature Difference
#+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++#

if abs(DT0 - DTL) > 0.05*max(abs([DT0,DTL])) 
	
	then
"Log Mean Temperature Difference"
	LMTD*ln(DT0/DTL) = (DT0-DTL);

	else
	
if DT0*DTL equal 0
	
	then
"Log Mean Temperature Difference"
	LMTD = 0.5*(DT0+DTL);

	else
"Log Mean Temperature Difference"
	LMTD = 0.5*(DT0+DTL)*(1-(DT0-DTL)^2/(DT0*DTL)*(1+(DT0-DTL)^2/(DT0*DTL)/2)/12);
	
end
	
end

"Exchange Surface Area"
	Details.Q = Details.Ud*Pi*DoInner*Lpipe*LMTD;

end

Model DoublePipe_LMTD  				as DoublePipe_Basic_LMTD

EQUATIONS

if Side equal 0

	then
"Temperature Difference at Inlet - Cocurrent Flow"
	DT0 = Inlet.Hot.T - Inlet.Cold.T;

"Temperature Difference at Outlet - Cocurrent Flow"
	DTL = Outlet.Hot.T - Outlet.Cold.T;

	else
"Temperature Difference at Inlet - Counter Flow"
	DT0 = Inlet.Hot.T - Outlet.Cold.T;

"Temperature Difference at Outlet - Counter Flow"
	DTL = Outlet.Hot.T - Inlet.Cold.T;
end
	
end

Model DoublePipe_NTU  				as DoublePipe_Basic_NTU

EQUATIONS

if Details.Cr equal 0 
	
	then 	
"Effectiveness"
	Eft = 1-exp(-Details.NTU);
	
	else

if Side equal 0

then
"Effectiveness in Cocurrent Flow"
	Eft*(1+Details.Cr) = (1-exp(-Details.NTU*(1+Details.Cr)));
	
	else

if Details.Cr equal 1
	
	then
"Effectiveness in Counter Flow"
	Eft*(1+Details.NTU) = Details.NTU;
	
	else
"Effectiveness in Counter Flow"
	Eft*(1-Details.Cr*exp(-Details.NTU*(1-Details.Cr))) = (1-exp(-Details.NTU*(1-Details.Cr)));
	
end

end


end

end

Model Multitubular_Basic
	
PARAMETERS

	Npipe 		as Integer 		(Brief="N Pipe in Series",Default=2);
ext PP 			as CalcObject	(Brief="External Physical Properties");
	HE	    	as CalcObject	(Brief="STHE Calculations",File="heatex");
	Pi			as constant 	(Brief="Pi Number",Default=3.14159265);
	Hside 	    as Integer 		(Brief="Fluid Alocation Flag-Default:Outer",Lower=0,Upper=1);
	DoInner  	as length		(Brief="Outside Diameter of Inner Pipe",Lower=1e-6);
	DiInner		as length		(Brief="Inside Diameter of Inner Pipe",Lower=1e-10);
	DiOuter		as length		(Brief="Inside Diameter of Outer pipe",Lower=1e-10);
	Lpipe		as length		(Brief="Effective Tube Length",Lower=0.1);
	Kwall		as conductivity (Brief="Tube Wall Material Thermal Conductivity",Default=1.0);

VARIABLES

Unity(Npipe)  as DoublePipe_Basic;

SET
	Pi  	= 3.14159265;
	Hside	= HE.FluidAlocation();
	
#"Inner Pipe Cross Sectional Area for Flow"
	Unity.Inner.HeatTransfer.As=Pi*DiInner*DiInner/4;
	
#"Outer Pipe Cross Sectional Area for Flow"
	Unity.Outer.HeatTransfer.As=Pi*(DiOuter*DiOuter-DoInner*DoInner)/4;
	
#"Inner Pipe Hydraulic Diameter for Heat Transfer"
	Unity.Inner.HeatTransfer.Dh=DiInner;
	
#"Outer Pipe Hydraulic Diameter for Heat Transfer"
	Unity.Outer.HeatTransfer.Dh=(DiOuter*DiOuter-DoInner*DoInner)/DoInner;

#"Inner Pipe Hydraulic Diameter for Pressure Drop"
	Unity.Inner.PressureDrop.Dh=DiInner;
	
#"Outer Pipe Hydraulic Diameter for Pressure Drop"
	Unity.Outer.PressureDrop.Dh=DiOuter-DoInner;

EQUATIONS

for i in [1:Npipe]

"Overall Heat Transfer Coefficient Clean"
	Unity(i).Details.Uc*(Unity(i).Resistances.Rtube+Unity(i).Resistances.Rwall+Unity(i).Resistances.Rshell)=1;

"Overall Heat Transfer Coefficient Dirty"
	Unity(i).Details.Ud*(Unity(i).Resistances.Rfi*(DoInner/DiInner) + Unity(i).Resistances.Rfo + Unity(i).Resistances.Rtube + Unity(i).Resistances.Rwall + Unity(i).Resistances.Rshell)=1;

"Exchange Surface Area"
	Unity(i).Details.A=Pi*DoInner*Lpipe;
	
if Hside equal 1
	
	then
	
"Pressure Drop Hot Stream"
	Unity(i).Outlet.Hot.P  = Unity(i).Inlet.Hot.P - Unity(i).Outer.PressureDrop.Pdrop;

"Pressure Drop Cold Stream"
	Unity(i).Outlet.Cold.P  = Unity(i).Inlet.Cold.P - Unity(i).Inner.PressureDrop.Pdrop;
	
"Outer Pipe Film Coefficient"
	Unity(i).Outer.HeatTransfer.hcoeff= HE.PipeFilmCoeff(Unity(i).Outer.HeatTransfer.Re,Unity(i).Outer.HeatTransfer.PR,Unity(i).Properties.Hot.Average.K,Unity(i).Outer.HeatTransfer.Dh,Lpipe)*Unity(i).Outer.HeatTransfer.Phi;

"Inner Pipe Film Coefficient"
	Unity(i).Inner.HeatTransfer.hcoeff= HE.PipeFilmCoeff(Unity(i).Inner.HeatTransfer.Re,Unity(i).Inner.HeatTransfer.PR,Unity(i).Properties.Cold.Average.K,DiInner,Lpipe)*Unity(i).Inner.HeatTransfer.Phi;

"Outer Pipe Pressure Drop"
	Unity(i).Outer.PressureDrop.Pdrop = (2*Unity(i).Outer.PressureDrop.fi*Lpipe*Unity(i).Properties.Hot.Average.rho*Unity(i).Outer.HeatTransfer.Vmean^2)/(Unity(i).Outer.PressureDrop.Dh*Unity(i).Outer.HeatTransfer.Phi);
	
"Inner Pipe Pressure Drop"
	Unity(i).Inner.PressureDrop.Pdrop = (2*Unity(i).Inner.PressureDrop.fi*Lpipe*Unity(i).Properties.Cold.Average.rho*Unity(i).Inner.HeatTransfer.Vmean^2)/(DiInner*Unity(i).Inner.HeatTransfer.Phi);

"Outer Pipe Phi correction"
	Unity(i).Outer.HeatTransfer.Phi = HE.PhiCorrection(Unity(i).Properties.Hot.Average.Mu,Unity(i).Properties.Hot.Wall.Mu);
	
"Inner Pipe Phi correction"
	Unity(i).Inner.HeatTransfer.Phi  = HE.PhiCorrection(Unity(i).Properties.Cold.Average.Mu,Unity(i).Properties.Cold.Wall.Mu);

"Outer Pipe Prandtl Number"
	Unity(i).Outer.HeatTransfer.PR = ((Unity(i).Properties.Hot.Average.Cp/Unity(i).Properties.Hot.Average.Mw)*Unity(i).Properties.Hot.Average.Mu)/Unity(i).Properties.Hot.Average.K;

"Inner Pipe Prandtl Number"
	Unity(i).Inner.HeatTransfer.PR = ((Unity(i).Properties.Cold.Average.Cp/Unity(i).Properties.Cold.Average.Mw)*Unity(i).Properties.Cold.Average.Mu)/Unity(i).Properties.Cold.Average.K;

"Outer Pipe Reynolds Number for Heat Transfer"
	Unity(i).Outer.HeatTransfer.Re =	(Unity(i).Properties.Hot.Average.rho*Unity(i).Outer.HeatTransfer.Vmean*Unity(i).Outer.HeatTransfer.Dh)/Unity(i).Properties.Hot.Average.Mu;

"Outer Pipe Reynolds Number for Pressure Drop"
	Unity(i).Outer.PressureDrop.Re =	(Unity(i).Properties.Hot.Average.rho*Unity(i).Outer.HeatTransfer.Vmean*Unity(i).Outer.PressureDrop.Dh)/Unity(i).Properties.Hot.Average.Mu;

"Inner Pipe Reynolds Number for Heat Transfer"
	Unity(i).Inner.HeatTransfer.Re =	(Unity(i).Properties.Cold.Average.rho*Unity(i).Inner.HeatTransfer.Vmean*Unity(i).Inner.HeatTransfer.Dh)/Unity(i).Properties.Cold.Average.Mu;

"Inner Pipe Reynolds Number for Pressure Drop"
	Unity(i).Inner.PressureDrop.Re =	Unity(i).Inner.HeatTransfer.Re;

"Outer Pipe Velocity"
	Unity(i).Outer.HeatTransfer.Vmean  = Unity(i).Properties.Hot.Inlet.Fw/(Unity(i).Outer.HeatTransfer.As*Unity(i).Properties.Hot.Average.rho);

"Inner Pipe Velocity"
	Unity(i).Inner.HeatTransfer.Vmean  = Unity(i).Properties.Cold.Inlet.Fw/(Unity(i).Inner.HeatTransfer.As*Unity(i).Properties.Cold.Average.rho);

	else
	
"Pressure Drop Hot Stream"
	Unity(i).Outlet.Hot.P  = Unity(i).Inlet.Hot.P - Unity(i).Inner.PressureDrop.Pdrop;

"Pressure Drop Cold Stream"
	Unity(i).Outlet.Cold.P  = Unity(i).Inlet.Cold.P - Unity(i).Outer.PressureDrop.Pdrop;
	
"Inner Pipe Film Coefficient"
	Unity(i).Inner.HeatTransfer.hcoeff= HE.PipeFilmCoeff(Unity(i).Inner.HeatTransfer.Re,Unity(i).Inner.HeatTransfer.PR,Unity(i).Properties.Hot.Average.K,DiInner,Lpipe)*Unity(i).Inner.HeatTransfer.Phi;

"Outer Pipe Film Coefficient"
	Unity(i).Outer.HeatTransfer.hcoeff= HE.PipeFilmCoeff(Unity(i).Outer.HeatTransfer.Re,Unity(i).Outer.HeatTransfer.PR,Unity(i).Properties.Cold.Average.K,Unity(i).Outer.HeatTransfer.Dh,Lpipe)*Unity(i).Outer.HeatTransfer.Phi;
	
"Outer Pipe Pressure Drop"
	Unity(i).Outer.PressureDrop.Pdrop = (2*Unity(i).Outer.PressureDrop.fi*Lpipe*Unity(i).Properties.Cold.Average.rho*Unity(i).Outer.HeatTransfer.Vmean^2)/(Unity(i).Outer.PressureDrop.Dh*Unity(i).Outer.HeatTransfer.Phi);
	
"Inner Pipe Pressure Drop"
	Unity(i).Inner.PressureDrop.Pdrop 	= (2*Unity(i).Inner.PressureDrop.fi*Lpipe*Unity(i).Properties.Hot.Average.rho*Unity(i).Inner.HeatTransfer.Vmean^2)/(DiInner*Unity(i).Inner.HeatTransfer.Phi);

"Outer Pipe Phi correction"
	Unity(i).Outer.HeatTransfer.Phi 	= HE.PhiCorrection(Unity(i).Properties.Cold.Average.Mu,Unity(i).Properties.Cold.Wall.Mu);
	
"Inner Pipe Phi correction"
	Unity(i).Inner.HeatTransfer.Phi  	= HE.PhiCorrection(Unity(i).Properties.Hot.Average.Mu,Unity(i).Properties.Hot.Wall.Mu);
	
"Outer Pipe Prandtl Number"
	Unity(i).Outer.HeatTransfer.PR 		= ((Unity(i).Properties.Cold.Average.Cp/Unity(i).Properties.Cold.Average.Mw)*Unity(i).Properties.Cold.Average.Mu)/Unity(i).Properties.Cold.Average.K;

"Inner Pipe Prandtl Number"
	Unity(i).Inner.HeatTransfer.PR 		= ((Unity(i).Properties.Hot.Average.Cp/Unity(i).Properties.Hot.Average.Mw)*Unity(i).Properties.Hot.Average.Mu)/Unity(i).Properties.Hot.Average.K;

"Outer Pipe Reynolds Number for Heat Transfer"
	Unity(i).Outer.HeatTransfer.Re 		= (Unity(i).Properties.Cold.Average.rho*Unity(i).Outer.HeatTransfer.Vmean*Unity(i).Outer.HeatTransfer.Dh)/Unity(i).Properties.Cold.Average.Mu;

"Outer Pipe Reynolds Number for Pressure Drop"
	Unity(i).Outer.PressureDrop.Re 		= (Unity(i).Properties.Cold.Average.rho*Unity(i).Outer.HeatTransfer.Vmean*Unity(i).Outer.PressureDrop.Dh)/Unity(i).Properties.Cold.Average.Mu;

"Inner Pipe Reynolds Number for Pressure Drop"
	Unity(i).Inner.PressureDrop.Re 		= Unity(i).Inner.HeatTransfer.Re;

"Inner Pipe Reynolds Number for Heat Transfer"
	Unity(i).Inner.HeatTransfer.Re 		= (Unity(i).Properties.Hot.Average.rho*Unity(i).Inner.HeatTransfer.Vmean*Unity(i).Inner.HeatTransfer.Dh)/Unity(i).Properties.Hot.Average.Mu;

"Outer Pipe Velocity"
	Unity(i).Outer.HeatTransfer.Vmean  	= Unity(i).Properties.Cold.Inlet.Fw/(Unity(i).Outer.HeatTransfer.As*Unity(i).Properties.Cold.Average.rho);

"Inner Pipe Velocity"
	Unity(i).Inner.HeatTransfer.Vmean  	= Unity(i).Properties.Hot.Inlet.Fw/(Unity(i).Inner.HeatTransfer.As*Unity(i).Properties.Hot.Average.rho);

end

"Inner Pipe Resistance"	
	Unity(i).Resistances.Rtube*(Unity(i).Inner.HeatTransfer.hcoeff*DiInner) = DoInner;
	
"Wall Resistance"
	Unity(i).Resistances.Rwall=DoInner*ln(DoInner/DiInner)/(2*Kwall);

"Outer Pipe Resistance"
	Unity(i).Resistances.Rshell*(Unity(i).Outer.HeatTransfer.hcoeff)=1;
	
end


end

Model Multitubular_Basic_LMTD	 	as Multitubular_Basic
#+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++#
# 	Basic Model for Double Pipe Heat Exchanger- LMTD Method
#+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++#
VARIABLES

DT0(Npipe)     	as temp_delta	(Brief="Temperature Difference at Inlet",Lower=1);
DTL(Npipe)		as temp_delta	(Brief="Temperature Difference at Outlet",Lower=1);
LMTD(Npipe)		as temp_delta	(Brief="Logarithmic Mean Temperature Difference",Lower=1);

EQUATIONS
#+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++#
# 			Log Mean Temperature Difference
#+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++#
for i in [1:Npipe]
	
if abs(DT0(i) - DTL(i)) > 0.05*max(abs([DT0(i),DTL(i)])) 
	
	then
"Log Mean Temperature Difference"
	LMTD(i)= (DT0(i)-DTL(i))/ln(DT0(i)/DTL(i));

	else
	
if DT0(i)*DTL(i) equal 0
	
	then
"Log Mean Temperature Difference"
	LMTD(i) = 0.5*(DT0(i)+DTL(i));
	
	else
"Log Mean Temperature Difference"
	LMTD(i) = 0.5*(DT0(i)+DTL(i))*(1-(DT0(i)-DTL(i))^2/(DT0(i)*DTL(i))*(1+(DT0(i)-DTL(i))^2/(DT0(i)*DTL(i))/2)/12);
	
end
	
end

"Exchange Surface Area"
	Unity(i).Details.Q = Unity(i).Details.Ud*Unity(i).Details.A*LMTD(i);

end

end

Model Multitubular_Counter_NTU 		as Multitubular_Basic

VARIABLES

Eft(Npipe)	  as positive (Brief="Effectiveness",Default=0.05,Lower=1e-8);

CONNECTIONS

Unity([1:Npipe-1]).Outlet.Hot  	to Unity([2:Npipe]).Inlet.Hot;
Unity([2:Npipe]).Outlet.Cold 	to Unity([1:Npipe-1]).Inlet.Cold;

EQUATIONS

for i in [1:Npipe]

if Unity(i).Details.Cr equal 0 
	
	then 	
"Effectiveness"
	Eft(i) = 1-exp(-Unity(i).Details.NTU);
	
	else

if Unity(i).Details.Cr equal 1
	
	then
"Effectiveness in Counter Flow"
	Eft(i) = Unity(i).Details.NTU/(1+Unity(i).Details.NTU);
	
	else
"Effectiveness in Counter Flow"
	Eft(i)*(1-Unity(i).Details.Cr*exp(-Unity(i).Details.NTU*(1-Unity(i).Details.Cr))) = (1-exp(-Unity(i).Details.NTU*(1-Unity(i).Details.Cr)));
	
end


end

"Energy Balance"
	Unity(i).Details.Q	= Eft(i)*Unity(i).Details.Cmin*(Unity(i).Inlet.Hot.T-Unity(i).Inlet.Cold.T);
	
end

end

Model Multitubular_Cocurrent_NTU 	as Multitubular_Basic

VARIABLES

Eft(Npipe)	  as positive (Brief="Effectiveness",Default=0.05,Lower=1e-8);

CONNECTIONS

Unity([1:Npipe-1]).Outlet.Hot  	to Unity([2:Npipe]).Inlet.Hot;
Unity([1:Npipe-1]).Outlet.Cold 	to Unity([2:Npipe]).Inlet.Cold;

EQUATIONS

for i in [1:Npipe]

if Unity(i).Details.Cr equal 0 
	
	then 	
"Effectiveness"
	Eft(i) = 1-exp(-Unity(i).Details.NTU);
	
	else
"Effectiveness in Cocurrent Flow"
	Eft(i) = (1-exp(-Unity(i).Details.NTU*(1+Unity(i).Details.Cr)))/(1+Unity(i).Details.Cr);

end

"Energy Balance"
	Unity(i).Details.Q	= Eft(i)*Unity(i).Details.Cmin*(Unity(i).Inlet.Hot.T-Unity(i).Inlet.Cold.T);
	
end

end

Model Multitubular_Counter_LMTD  	as Multitubular_Basic_LMTD

CONNECTIONS

Unity([1:Npipe-1]).Outlet.Hot  	to Unity([2:Npipe]).Inlet.Hot;
Unity([2:Npipe]).Outlet.Cold 	to Unity([1:Npipe-1]).Inlet.Cold;

EQUATIONS
for i in [1:Npipe]
	
"Temperature Difference at Inlet - Counter Flow"
	DT0(i) = Unity(i).Inlet.Hot.T - Unity(i).Outlet.Cold.T;

"Temperature Difference at Outlet - Counter Flow"
	DTL(i) = Unity(i).Outlet.Hot.T - Unity(i).Inlet.Cold.T;
	
end

end

Model Multitubular_Cocurrent_LMTD  	as Multitubular_Basic_LMTD

CONNECTIONS

Unity([1:Npipe-1]).Outlet.Hot  	to Unity([2:Npipe]).Inlet.Hot;
Unity([1:Npipe-1]).Outlet.Cold 	to Unity([2:Npipe]).Inlet.Cold;

EQUATIONS

for i in [1:Npipe]
	
"Temperature Difference at Inlet - Cocurrent Flow"
	DT0(i) = Unity(i).Inlet.Hot.T - Unity(i).Inlet.Cold.T;

"Temperature Difference at Outlet - Cocurrent Flow"
	DTL(i) = Unity(i).Outlet.Hot.T - Unity(i).Outlet.Cold.T;
	
end

end