Changeset 930 for branches/gui/eml

Timestamp:

Apr 23, 2011, 8:08:41 PM (12 years ago)

Author:

Rafael de Pelegrini Soares

Message:

Added a condenser model with a built-in "reflux" variable.

File:

• branches/gui/eml/stage_separators/condenser.mso (modified) (1 diff)

branches/gui/eml/stage_separators/condenser.mso

@@ -427 +427 @@
 
 
+Model condenser2
+
+ATTRIBUTES
+        Pallete         = true;
+        Icon            = "icon/Condenser"; 
+        Brief           = "Model of a  dynamic condenser with control.";
+        Info            =
+"== ASSUMPTIONS ==
+* perfect mixing of both phases;
+* thermodynamics equilibrium.
+        
+== SPECIFY ==
+* the InletVapour stream;
+* the outlet flows: Product.F and Reflux.F;
+* the InletQ (the model requires an energy stream, also you can use a controller for setting the heat duty using the heat_flow model).
+
+== OPTIONAL ==
+* the condenser model has three control ports
+** TI OutletLiquid Temperature Indicator;
+** PI OutletLiquid Pressure Indicator;
+** LI Level Indicator of Condenser;
+
+== INITIAL CONDITIONS ==
+* Initial_Temperature :  the condenser temperature (OutletLiquid.T);
+* Levelpercent_Initial : the condenser liquid level in percent (LI);
+* Initial_Composition : (NoComps) OutletLiquid compositions.
+";      
+        
+PARAMETERS
+        outer PP                as Plugin       (Brief = "External Physical Properties", Type="PP");
+        outer NComp     as Integer (Brief="Number of Components");
+        
+        Mw(NComp)       as molweight    (Brief = "Component Mol Weight",Hidden=true);
+        low_flow        as flow_mol     (Brief = "Low Flow",Default = 1E-6, Hidden=true);
+        zero_flow       as flow_mol     (Brief = "No Flow",Default = 0, Hidden=true);
+
+        CondenserType   as Switcher     (Brief="Condenser type", Valid = ["partial", "total"], Default = "partial");
+        VapourFlow              as Switcher     (Brief="Vapour Flow", Valid = ["on", "off"], Default = "on",Hidden=true);
+
+        Kfactor as positive (Brief="K factor for pressure drop", Lower = 1E-8, Default = 1E-3);
+        
+        Levelpercent_Initial            as positive     (Brief="Initial liquid height in Percent", Default = 0.70);
+        Initial_Temperature                     as temperature  (Brief="Initial Temperature of Condenser");
+        Initial_Composition(NComp)      as positive     (Brief="Initial Liquid Composition", Lower=1E-6);
+        
+VARIABLES
+
+        Geometry                as VesselVolume (Brief="Vessel Geometry", Symbol=" ");
+
+in      InletVapour     as stream                       (Brief="Vapour inlet stream", PosX=0.13, PosY=0, Symbol="_{in}^{Vapour}");
+out     OutletLiquid    as liquid_stream        (Brief="Liquid outlet stream", PosX=0.35, PosY=1, Symbol="_{out}^{Liquid}");
+        Vapour                  as vapour_stream        (Brief="Vapour outlet stream", Hidden=true, Symbol="_{out}^{Vapour}");
+out     Product                 as stream                       (Brief="Vapour or Liquid product stream", PosX=0.54, PosY=0, Symbol="_{out}^{Vapour}");
+in      InletQ                  as power                        (Brief="Heat supplied", Protected = true, PosX=1, PosY=0.08, Symbol="Q_{in}");
+
+        RefluxRatio             as positive     (Brief = "Reflux Ratio", Default=10, Lower = 0.05);
+
+        out     TI as control_signal    (Brief="Temperature  Indicator of Condenser", Protected = true, PosX=0.33, PosY=0);
+        out     LI as control_signal    (Brief="Level  Indicator of Condenser", Protected = true, PosX=0.43, PosY=0);
+        out     PI as control_signal    (Brief="Pressure  Indicator of Condenser", Protected = true, PosX=0.25, PosY=0);
+
+        M(NComp)        as mol                  (Brief="Molar Holdup in the tray", Protected = true);
+        ML                      as mol                  (Brief="Molar liquid holdup", Protected = true);
+        MV                      as mol                  (Brief="Molar vapour holdup", Protected = true);
+        E                       as energy               (Brief="Total Energy Holdup on tray", Protected = true);
+        vL                      as volume_mol   (Brief="Liquid Molar Volume", Protected = true);
+        vV                      as volume_mol   (Brief="Vapour Molar volume", Protected = true);
+        rho                     as dens_mass    (Brief ="Inlet Vapour Mass Density",Hidden=true, Symbol ="\rho");
+        Pdrop           as press_delta  (Brief = "Pressure Drop", DisplayUnit = 'kPa', Symbol ="\Delta P", Protected=true);
+
+SET
+        Mw   = PP.MolecularWeight();
+        low_flow = 1E-6 * 'kmol/h';
+        zero_flow = 0 * 'kmol/h';
+        
+INITIAL
+
+"Initial level Percent"
+        LI = Levelpercent_Initial;
+
+"Initial Temperature"
+        OutletLiquid.T  = Initial_Temperature;
+
+"Initial Composition"
+        OutletLiquid.z(1:NComp-1) = Initial_Composition(1:NComp-1)/sum(Initial_Composition);
+
+EQUATIONS
+
+        
+        Vapour.F = zero_flow;
+        "Reflux ratio"
+        RefluxRatio*Product.F = OutletLiquid.F;
+
+switch CondenserType
+
+case "partial":
+        Product.v = Vapour.v;
+        Product.h = Vapour.h;
+        Product.z = Vapour.z;
+        
+case "total":
+        Product.v = OutletLiquid.v;
+        Product.h = OutletLiquid.h;
+        Product.z = OutletLiquid.z;
+end
+
+
+switch VapourFlow
+
+case "on":
+        InletVapour.F*vV = Kfactor *sqrt(Pdrop/rho)*'m^2';
+
+        when InletVapour.F < low_flow switchto "off";
+
+case "off":
+        InletVapour.F = zero_flow;
+
+        when InletVapour.P > OutletLiquid.P switchto "on";
+
+end
+
+"Component Molar Balance"
+        diff(M) = InletVapour.F*InletVapour.z - OutletLiquid.F*OutletLiquid.z- Product.F*Product.z;
+
+"Energy Balance"
+        diff(E) = InletVapour.F*InletVapour.h - OutletLiquid.F*OutletLiquid.h- Product.F*Product.h + InletQ;
+
+"Molar Holdup"
+        M = ML*OutletLiquid.z + MV*Vapour.z; 
+        
+"Energy Holdup"
+        E = ML*OutletLiquid.h + MV*Vapour.h - Vapour.P*Geometry.Vtotal;
+        
+"Mol fraction normalisation"
+        sum(OutletLiquid.z)=1.0;
+
+"Mol fraction Constraint"
+        sum(OutletLiquid.z)=sum(Vapour.z);
+
+"Liquid Volume"
+        vL = PP.LiquidVolume(OutletLiquid.T, OutletLiquid.P, OutletLiquid.z);
+        
+"Vapour Volume"
+        vV = PP.VapourVolume(Vapour.T, Vapour.P, Vapour.z);
+
+"Inlet Vapour Density"
+        rho = PP.VapourDensity(InletVapour.T, InletVapour.P, InletVapour.z);
+        
+"Chemical Equilibrium"
+        PP.LiquidFugacityCoefficient(OutletLiquid.T, OutletLiquid.P, OutletLiquid.z)*OutletLiquid.z = 
+                PP.VapourFugacityCoefficient(Vapour.T, Vapour.P, Vapour.z)*Vapour.z;
+
+"Thermal Equilibrium"
+        OutletLiquid.T = Vapour.T;
+        OutletLiquid.T = Product.T;
+
+"Mechanical Equilibrium"
+        Vapour.P = OutletLiquid.P;
+        Vapour.P = Product.P;
+
+"Pressure Drop"
+        OutletLiquid.P  = InletVapour.P - Pdrop;
+
+"Geometry Constraint"
+        Geometry.Vtotal = ML*vL + MV*vV;
+
+"Liquid Level"
+        ML * vL = Geometry.Vfilled;
+
+"Temperature indicator"
+        TI * 'K' = OutletLiquid.T;
+
+"Pressure indicator"
+        PI * 'atm' = OutletLiquid.P;
+
+"Level indicator"
+        LI*Geometry.Vtotal= Geometry.Vfilled;
+        
+end
+
+
 Model condenserSubcooled