Changeset 800 for branches/gui

Timestamp:

Jul 18, 2009, 11:18:23 PM (14 years ago)

Author:

gerson bicca

Message:

added SumpTank? model (to be used with a column section)

Location:

branches/gui/eml/stage_separators

Files:

• icon/SumpTank.png (added)
• icon/SumpTank.svg (added)
• tank.mso (modified) (1 diff)

branches/gui/eml/stage_separators/tank.mso

@@ -578 +578 @@
 end
 
+Model SumpTank
+
+ATTRIBUTES
+        Pallete         = true;
+        Icon            = "icon/SumpTank"; 
+        Brief           = "Model of a Column Sump Tank.";
+        Info            =
+"== ASSUMPTIONS ==
+* liquid phase only;
+
+== SET ==
+*Head
+**elliptical: 2:1 elliptical head (25% of vessel diameter);
+**hemispherical: hemispherical head (50% of vessel diameter);
+**flat: flat head (0% of vessel diameter);
+*Diameter: Vessel diameter;
+*Lenght: Side length of the cylinder shell;
+        
+== SPECIFY ==
+* the Inlet stream;
+* the OutletLiquid.F;
+
+== OPTIONAL ==
+* the SumpTank model has one control port
+** LI Level Indicator;
+
+== INITIAL CONDITIONS ==
+* Initial_Temperature :  the Tank temperature (OutletLiquid.T);
+* Initial_Level : the Tank liquid level (Level);
+* Initial_Composition : (NoComps) OutletLiquid compositions.
+";
+        
+PARAMETERS
+outer PP                as Plugin       (Brief = "External Physical Properties", Type="PP");
+outer NComp     as Integer      (Brief = "Number of components", Lower = 1); 
+
+        pi                      as positive             (Brief="Pi value", Default=3.141593,Hidden=true, Symbol="\pi");
+        Head                    as Switcher     (Valid=["elliptical","hemispherical","flat"],Default="flat");
+        Diameter                as length               (Brief="Vessel diameter", Symbol="D_{i}");
+        Lenght                  as length               (Brief="Side length of the cylinder shell", Symbol="L_{vessel}");
+        
+        Vhead_elliptical                as volume               (Brief="Elliptical Head Total Volume",Hidden=true, Symbol="V_{head}^{elliptical}");
+        Vhead_hemispherical     as volume               (Brief="Hemispherical Head Total Volume",Hidden=true, Symbol="V_{head}^{hemispherical}");
+        Vcylinder                               as volume               (Brief="Cylinder Total Volume",Hidden=true, Symbol="V_{cylinder}");
+        radius                                  as length               (Brief="Vessel radius",Hidden=true, Symbol="R_{cylinder}");
+        
+        Levelpercent_Initial                    as positive     (Brief="Initial liquid height in Percent", Default = 0.70);
+        Temperature_Initial                             as temperature  (Brief="Initial Liquid Temperature", Default = 330);
+        Composition_Initial(NComp)              as fraction             (Brief="Initial Composition", Default = 0.10);
+
+SET
+
+        Vhead_elliptical        = (pi*Diameter^3)/24;
+        Vhead_hemispherical = (pi*Diameter^3)/12;
+        Vcylinder = 0.25*(pi*Diameter^2)*Lenght;
+        radius = 0.5*Diameter;
+
+VARIABLES
+
+in      Inlet                   as stream                       (Brief="Feed Stream", PosX=0.5, PosY=0, Symbol="_{in}");
+out     OutletLiquid    as liquid_stream        (Brief="Liquid outlet stream", PosX=0.5, PosY=1, Symbol="_{out}^{Liquid}");
+
+        Vtotal                  as volume                       (Brief="Vessel total volume",Protected=true, Symbol="V_{total}");
+        Vfilled                 as volume                       (Brief="Vessel volume content",Protected=true, Symbol="V_{filled}");
+
+        TotalHoldup(NComp)              as mol  (Brief="Molar Holdup in the Vessel", Protected=true);
+        
+        E                       as energy               (Brief="Total Energy Holdup in the Vessel", Protected=true);
+        vL                      as volume_mol   (Brief="Liquid Molar Volume", Protected=true);
+        Level           as length               (Brief="liquid height", Protected=true);
+        Across          as area                 (Brief="Vessel cylinder shell Cross section area", Hidden=true, Symbol="A_{cross}");
+
+out     LI as control_signal    (Brief="Level Indicator", PosX=1, PosY=0.4, Protected=true);
+
+INITIAL
+
+"Initial level Percent"
+        LI = Levelpercent_Initial;
+        
+"Initial Outlet Liquid Temperature"
+        OutletLiquid.T = Temperature_Initial;
+        
+"Initial Outlet Liquid Composition Normalized"
+        OutletLiquid.z(1:NComp - 1) = Composition_Initial(1:NComp - 1)/sum(Composition_Initial);
+
+EQUATIONS
+
+"Vessel Cross Section Area"
+        Across = 0.25*(pi*Diameter^2);
+
+switch Head
+
+case "elliptical":
+
+"Vessel Total Volume"
+        Vtotal = Vhead_elliptical +     Vcylinder;
+
+if Level < 0.25*Diameter then
+
+"Vessel Filled Volume"
+        Vfilled = 0.25*pi*(((Diameter*Level)/(0.25*Diameter))^2)*(0.25*Diameter-Level/3);
+
+else
+
+"Vessel Filled Volume"
+        Vfilled = 0.25*pi*(Diameter^2)*(Level - 0.25*Diameter/3);
+
+end
+
+case "hemispherical":
+
+"Vessel Total Volume"
+        Vtotal = Vhead_hemispherical + Vcylinder;
+
+if Level < 0.5*Diameter then
+
+"Vessel Filled Volume"
+        Vfilled = 0.25*pi*(Level^2)*(2*Diameter-4*Level/3);
+
+else
+
+"Vessel Filled Volume"
+        Vfilled = 0.25*pi*((2/3)*((0.5*Diameter)^3) - (0.25*(Diameter)^3) + Level*Diameter^2);
+
+end
+
+case "flat":
+
+"Vessel Total Volume"
+        Vtotal = Vcylinder;
+
+"Vessel Filled Volume"
+        Vfilled = Across*Level;
+
+end
+
+"Component Molar Balance"
+        diff(TotalHoldup)=Inlet.F*Inlet.z - OutletLiquid.F*OutletLiquid.z;
+        
+"Energy Balance"
+        diff(E) = Inlet.F*Inlet.h - OutletLiquid.F*OutletLiquid.h;
+
+"Energy Holdup"
+        E = sum(TotalHoldup)*OutletLiquid.h;
+
+"Mechanical Equilibrium"
+        Inlet.P = OutletLiquid.P;
+
+"Liquid Volume"
+        vL = PP.LiquidVolume(OutletLiquid.T, OutletLiquid.P, OutletLiquid.z);
+
+"Molar Holdup"
+        TotalHoldup = OutletLiquid.z*sum(TotalHoldup); 
+        
+"Liquid Level"
+        Vfilled = sum(TotalHoldup) * vL;
+        
+"Level indicator"
+        LI*Vtotal= Vfilled;
+
+end
+
 Model tank_feed
         ATTRIBUTES
-        Pallete         = true;
+        Pallete         = false;
         Icon            = "icon/Tank"; 
         Brief           = "Model of a tank with feed stream.";