Changeset 755 for branches/gui/eml

Timestamp:

Jun 2, 2009, 4:45:51 PM (14 years ago)

Author:

gerson bicca

Message:

added a dynamic model of a condenser with splitter to be used in column models (not finished)

File:

• branches/gui/eml/stage_separators/condenser.mso (modified) (1 diff)

branches/gui/eml/stage_separators/condenser.mso

@@ -269 +269 @@
 
 end
+
+Model condenser_column
+        ATTRIBUTES
+        Pallete         = true;
+        Icon            = "icon/Condenser_column"; 
+        Brief           = "Model of a  dynamic condenser with splitter.";
+        Info            =
+"== Assumptions ==
+* perfect mixing of both phases;
+* thermodynamics equilibrium.
+        
+== Specify ==
+* the inlet stream;
+* the outlet flows: OutletVapour.F and OutletLiquid.F;
+* the heat supply.
+        
+== Initial Conditions ==
+* the condenser temperature (OutletLiquid.T);
+* the condenser liquid level (Level);
+* (NoComps - 1) OutletLiquid (OR OutletVapour) compositions.
+";      
+        
+PARAMETERS
+        outer PP                        as Plugin       (Brief = "External Physical Properties", Type="PP");
+        outer NComp     as Integer;
+
+        V                       as volume       (Brief="Condenser total volume");
+        Across  as area                         (Brief="Cross Section Area of reboiler");
+        
+        Initial_Level                           as length                       (Brief="Initial Level of liquid phase");
+        Initial_Temperature                     as temperature          (Brief="Initial Temperature of Condenser");
+        Initial_Composition(NComp)      as fraction             (Brief="Initial Liquid Composition");
+        
+VARIABLES
+in              InletVapour             as stream                               (Brief="Vapour inlet stream", PosX=0, PosY=0.5, Symbol="_{inV}");
+out     OutletLiquid    as liquid_stream                (Brief="Liquid outlet stream", PosX=0.5, PosY=1, Symbol="_{outL}");
+out     OutletVapour    as vapour_stream        (Brief="Vapour outlet stream", PosX=0.5, PosY=0, Symbol="_{outV}");
+in              InletQ          as power                                (Brief="Cold supplied", PosX=1, PosY=0.6, Symbol="_{in}");
+
+        M(NComp)        as mol                          (Brief="Molar Holdup in the tray");
+        ML                              as mol                          (Brief="Molar liquid holdup");
+        MV                              as mol                          (Brief="Molar vapour holdup");
+        E                                       as energy                       (Brief="Total Energy Holdup on tray");
+        vL                              as volume_mol   (Brief="Liquid Molar Volume");
+        vV                              as volume_mol   (Brief="Vapour Molar volume");
+        Level                   as length                       (Brief="Level of liquid phase");
+
+INITIAL
+
+        Level                                   = Initial_Level;
+        OutletLiquid.T                          = Initial_Temperature;
+        OutletLiquid.z(1:NComp-1)       = Initial_Composition(1:NComp-1)/sum(Initial_Composition);
+        
+EQUATIONS
+"Component Molar Balance"
+        diff(M) = InletVapour.F*InletVapour.z - OutletLiquid.F*OutletLiquid.z- OutletVapour.F*OutletVapour.z;
+
+"Energy Balance"
+        diff(E) = InletVapour.F*InletVapour.h - OutletLiquid.F*OutletLiquid.h- OutletVapour.F*OutletVapour.h + InletQ;
+
+"Molar Holdup"
+        M = ML*OutletLiquid.z + MV*OutletVapour.z; 
+        
+"Energy Holdup"
+        E = ML*OutletLiquid.h + MV*OutletVapour.h - OutletVapour.P*V;
+        
+"Mol fraction normalisation"
+        sum(OutletLiquid.z)=1.0;
+        sum(OutletLiquid.z)=sum(OutletVapour.z);
+
+"Liquid Volume"
+        vL = PP.LiquidVolume(OutletLiquid.T, OutletLiquid.P, OutletLiquid.z);
+        
+"Vapour Volume"
+        vV = PP.VapourVolume(OutletVapour.T, OutletVapour.P, OutletVapour.z);
+
+"Chemical Equilibrium"
+        PP.LiquidFugacityCoefficient(OutletLiquid.T, OutletLiquid.P, OutletLiquid.z)*OutletLiquid.z = 
+                PP.VapourFugacityCoefficient(OutletVapour.T, OutletVapour.P, OutletVapour.z)*OutletVapour.z;
+
+"Thermal Equilibrium"
+        OutletLiquid.T = OutletVapour.T;
+
+"Mechanical Equilibrium"
+        OutletVapour.P = OutletLiquid.P;
+
+"Geometry Constraint"
+        V = ML*vL + MV*vV;
+
+"Level of liquid phase"
+        Level = ML*vL/Across;
+
+end