Changeset 569 for branches/gui/eml/streams.mso

Timestamp:

Jul 24, 2008, 5:16:27 PM (14 years ago)

Author:

gerson bicca

Message:

added info stream model/icon

File:

• branches/gui/eml/streams.mso (modified) (1 diff)

branches/gui/eml/streams.mso

@@ -415 +415 @@
         out OutletQ             as power(Brief = "Outlet energy stream", PosX=1, PosY=0.46, Symbol="_{out}");
 end
+
+Model info_stream
+        ATTRIBUTES
+        Pallete = true;
+        Icon = "icon/Info_Stream";
+        Brief = "Material stream information";
+        Info = "
+        This model should be used for middle streams when additional
+        information about the stream is desired.
+
+        Some of the additional informations calculated by this models are:
+         * Mass density
+         * Mass flow
+         * Mass compostions
+         * Specific volume
+         * Vapour fraction
+         * Volumetric flow
+         * Liquid and Vapour compositions
+         * Viscosity
+         * Heat Capacity
+         * Thermal Conductivity
+         * Temperature in Celsius Degrees
+        ";
+
+PARAMETERS
+        outer PP                        as Plugin                       (Brief = "External Physical Properties", Type="PP");
+        outer NComp     as Integer                      (Brief = "Number of chemical components", Lower = 1); 
+                  M(NComp)      as molweight    (Brief = "Component Mol Weight");
+        
+SET
+
+        M   = PP.MolecularWeight();
+        
+VARIABLES
+
+        in      Inlet           as stream               (Brief = "Inlet Stream", PosX=0, PosY=0.5308, Protected=true , Symbol="_{in}");
+        out     Outlet          as stream               (Brief = "Outlet Stream", PosX=1, PosY=0.5308, Protected=true , Symbol="_{out}");
+        
+        v                                               as fraction                     (Brief = "Vapourization fraction",Hidden=true);
+        x(NComp)                        as fraction                     (Brief = "Liquid Molar Fraction",Hidden=true);
+        y(NComp)                        as fraction                     (Brief = "Vapour Molar Fraction",Hidden=true);
+        
+        Fw                                      as flow_mass            (Brief = "Stream Mass Flow",Protected=true);
+        Fvol                            as flow_vol             (Brief = "Volumetric Flow",Protected=true);
+        T_Cdeg                          as temperature          (Brief = "Temperature in °C", Lower=-200,Protected=true);
+
+        Mu                                      as viscosity            (Brief="Stream Viscosity",Lower=0.0001, Symbol = "\mu",Protected=true);
+        Cp                                      as cp_mol                       (Brief="Stream Molar Heat Capacity", Upper=1e10,Protected=true);        
+        K                                               as conductivity         (Brief="Stream Thermal Conductivity", Default=1.0, Lower=1e-5, Upper=500,Protected=true);
+        Mw                                      as molweight            (Brief = "Average Mol Weight",Protected=true);
+        vm                                      as volume_mol   (Brief = "Molar Volume",Protected=true);        
+        rho                                     as dens_mass            (Brief = "Stream Mass Density",Protected=true);
+        rhom                                    as dens_mol             (Brief = "Stream Molar Density",Protected=true);
+        s                                               as entr_mol             (Brief = "Stream Entropy",Protected=true);
+        zmass(NComp)    as fraction                     (Brief = "Mass Fraction",Protected=true);
+        
+EQUATIONS
+
+"Flash Calculation"
+        [v, x, y] = PP.FlashPH(Inlet.P, Inlet.h, Inlet.z);
+        
+"Average Molecular Weight"
+        Mw = sum(M*Inlet.z);
+
+"Mass Density"
+        rho * ((1-v)/PP.LiquidDensity(Inlet.T,Inlet.P,x) + v/PP.VapourDensity(Inlet.T,Inlet.P,y)) = 1;
+        
+"Mass or Molar Density"
+        rhom * Mw = rho;
+
+"Flow Mass"
+        Fw      =  Mw*Inlet.F;
+
+"Molar Volume"
+        vm = (1-v)*PP.LiquidVolume(Inlet.T, Inlet.P, x) + v*PP.VapourVolume(Inlet.T,Inlet.P,y);
+        
+"Volumetric Flow"
+        Fvol = Inlet.F*vm ;
+        
+"Mass Fraction"
+        zmass = M*Inlet.z / Mw;
+
+"Stream Heat Capacity"
+        Cp      =       (1-v)*PP.LiquidCp(Inlet.T, Inlet.P, x) + v*PP.VapourCp(Inlet.T,Inlet.P,y);
+
+"Stream Viscosity"
+        Mu      =       (1-v)*PP.LiquidViscosity(Inlet.T, Inlet.P, x) + v*PP.VapourViscosity(Inlet.T,Inlet.P,y);
+
+"Stream ThermalConductivity"
+        K       =       (1-v)*PP.LiquidThermalConductivity(Inlet.T, Inlet.P, x) + v*PP.VapourThermalConductivity(Inlet.T,Inlet.P,y);
+
+"Stream Overall Entropy"
+        s = (1-v)*PP.LiquidEntropy(Inlet.T, Inlet.P, x) + v*PP.VapourEntropy(Inlet.T, Inlet.P, y);
+        
+"Temperature in °C"
+        T_Cdeg = Inlet.T - 273.15 * 'K';
+
+"Outlet Flow"
+        Outlet.F = Inlet.F;
+
+"Outlet Temperature"
+        Outlet.T = Inlet.T;
+
+"Outlet Pressure"
+        Outlet.P = Inlet.P;
+
+"Outlet Vapour Fraction"
+        Outlet.v = Inlet.v;
+
+"Outlet Enthalpy"
+        Outlet.h = Inlet.h;
+
+"Outlet Composition"
+        Outlet.z= Inlet.z;
+
+end