Changeset 522 for trunk

Timestamp:

May 21, 2008, 8:21:12 PM (14 years ago)

Author:

Argimiro Resende Secchi

Message:

merging tray versions.

Location:

trunk

Files:

• eml/stage_separators/tray.mso (modified) (1 diff)
• sample/stage_separators/sample_tray.mso (modified) (1 diff)
• sample/stage_separators/trayRate_Test.rlt (added)

trunk/eml/stage_separators/tray.mso

@@ -532 +532 @@
         hl = (12*miL*a^2*uL/rhoL/g)^1/3;
 end
+
+#*-------------------------------------
+* Nonequilibrium Model
+-------------------------------------*#
+Model interface
+        
+        ATTRIBUTES
+        Pallete         = false;
+        Icon            = "icon/Tray"; 
+        Brief           = "Descrition of variables of the equilibrium interface.";
+        Info            =
+"This model contains only the variables of the equilibrium interface.";
+
+        PARAMETERS
+outer PP as Plugin(Brief = "External Physical Properties", Type="PP");
+outer NComp as Integer;
+outer NC1 as Integer;
+        
+        VARIABLES
+        NL(NComp) as flow_mol_delta     (Brief = "Stream Molar Rate on Liquid Phase");
+        NV(NComp) as flow_mol_delta     (Brief = "Stream Molar Rate on Vapour Phase");
+        T as temperature                (Brief = "Stream Temperature");
+        P as pressure                   (Brief = "Stream Pressure");
+        x(NComp) as fraction    (Brief = "Stream Molar Fraction on Liquid Phase");
+        y(NComp) as fraction    (Brief = "Stream Molar Fraction on Vapour Phase");
+        a as area                           (Brief = "Interface Area");
+        htL as heat_trans_coeff (Brief = "Heat Transference Coefficient on Liquid Phase");
+        htV as heat_trans_coeff (Brief = "Heat Transference Coefficient on Vapour Phase");      
+        E_liq as heat_rate      (Brief = "Liquid Energy Rate at interface");
+    E_vap as heat_rate      (Brief = "Vapour Energy Rate at interface");        
+        hL as enth_mol          (Brief = "Liquid Molar Enthalpy");
+        hV as enth_mol          (Brief = "Vapour Molar Enthalpy");
+        kL(NC1,NC1) as velocity (Brief = "Mass Transfer Coefficients");
+        kV(NC1,NC1) as velocity (Brief = "Mass Transfer Coefficients");
+        
+        EQUATIONS
+        "Liquid Enthalpy"
+        hL = PP.LiquidEnthalpy(T, P, x);
+        
+        "Vapour Enthalpy"
+        hV = PP.VapourEnthalpy(T, P, y);
+
+end
+
+Model trayRateBasic
+        ATTRIBUTES
+        Pallete         = false;
+        Icon            = "icon/Tray"; 
+        Brief           = "Basic equations of a tray rate column model.";
+        Info            =
+"This model contains only the main equations of a column tray nonequilibrium model without
+the hidraulic equations.
+        
+== Assumptions ==
+* both phases (liquid and vapour) exists all the time;
+* no entrainment of liquid or vapour phase;
+* no weeping;
+* the dymanics in the downcomer are neglected.
+";
+        
+        PARAMETERS
+outer PP as Plugin(Brief = "External Physical Properties", Type="PP");
+outer NComp as Integer;
+    NC1 as Integer;
+        V as volume(Brief="Total Volume of the tray");
+        Q as heat_rate (Brief="Rate of heat supply"); 
+        Ap as area (Brief="Plate area = Atray - Adowncomer");
+        
+        VARIABLES
+in      Inlet as stream (Brief="Feed stream", PosX=0, PosY=0.4932, Symbol="_{in}");
+in      InletFV as stream (Brief="Feed stream", PosX=0, PosY=0.4932, Symbol="_{in}");
+in      InletL as stream (Brief="Inlet liquid stream", PosX=0.5195, PosY=0, Symbol="_{inL}");
+in      InletV as stream (Brief="Inlet vapour stream", PosX=0.4994, PosY=1, Symbol="_{inV}");
+out     OutletL as liquid_stream (Brief="Outlet liquid stream", PosX=0.8277, PosY=1, Symbol="_{outL}");
+out     OutletV as vapour_stream (Brief="Outlet vapour stream", PosX=0.8043, PosY=0, Symbol="_{outV}");
+
+        M_liq(NComp) as mol (Brief="Liquid Molar Holdup in the tray");
+        M_vap(NComp) as mol (Brief="Vapour Molar Holdup in the tray");
+        ML as mol (Brief="Molar liquid holdup");
+        MV as mol (Brief="Molar vapour holdup");
+        E_liq as energy (Brief="Total Liquid Energy Holdup on tray");
+        E_vap as energy (Brief="Total Vapour Energy Holdup on tray");
+        vL as volume_mol (Brief="Liquid Molar Volume");
+        vV as volume_mol (Brief="Vapour Molar volume");
+        Level as length (Brief="Height of clear liquid on plate");
+        interf as interface;    
+
+        SET   
+        NC1=NComp-1;
+
+        EQUATIONS
+        "Component Molar Balance"
+        diff(M_liq)=Inlet.F*Inlet.z + InletL.F*InletL.z 
+        - OutletL.F*OutletL.z + interf.NL;
+        
+        diff(M_vap)=InletFV.F*InletFV.z + InletV.F*InletV.z 
+        - OutletV.F*OutletV.z - interf.NV;
+        
+        "Energy Balance"
+        diff(E_liq) = Inlet.F*Inlet.h + InletL.F*InletL.h
+                - OutletL.F*OutletL.h  + Q + interf.E_liq;
+        
+        diff(E_vap) = InletFV.F*InletFV.h + InletV.F*InletV.h
+                - OutletV.F*OutletV.h  - interf.E_vap;
+        
+        "Molar Holdup"
+        M_liq = ML*OutletL.z;
+        
+        M_vap = MV*OutletV.z;
+        
+        "Energy Holdup"
+        E_liq = ML*(OutletL.h - OutletL.P*vL);
+        
+        E_vap = MV*(OutletV.h - OutletV.P*vV);
+        
+        "Energy Rate through the interface"
+        interf.E_liq = interf.htL*interf.a*(interf.T-OutletL.T)+sum(interf.NL)*interf.hL;       
+        
+        interf.E_vap = interf.htV*interf.a*(OutletV.T-interf.T)+sum(interf.NV)*interf.hV;
+        
+        "Mass Conservation"
+        interf.NL = interf.NV;
+        
+        "Energy Conservation"
+        interf.E_liq = interf.E_vap;
+        
+        "Mol fraction normalisation"
+        sum(OutletL.z)= 1.0;
+        sum(OutletL.z)= sum(OutletV.z);
+        sum(interf.x)=1.0;
+        sum(interf.x)=sum(interf.y);
+        
+        "Liquid Volume"
+        vL = PP.LiquidVolume(OutletL.T, OutletL.P, OutletL.z);
+        "Vapour Volume"
+        vV = PP.VapourVolume(OutletV.T, OutletV.P, OutletV.z);
+        
+        "Chemical Equilibrium"
+        PP.LiquidFugacityCoefficient(interf.T, interf.P, interf.x)*interf.x = 
+                PP.VapourFugacityCoefficient(interf.T, interf.P, interf.y)*interf.y;
+
+        "Geometry Constraint"
+        V = ML*vL + MV*vV;
+        
+        "Level of clear liquid over the weir"
+        Level = ML*vL/Ap;
+
+        "Total Mass Transfer Rates"
+        interf.NL(1:NC1)=interf.a*sumt(interf.kL*(interf.x(1:NC1)-OutletL.z(1:NC1)))/vL+
+                OutletL.z(1:NC1)*sum(interf.NL);
+
+#       interf.NL(1:NC1)=0.01*'kmol/s';
+        
+        interf.NV(1:NC1)=interf.a*sumt(interf.kV*(OutletV.z(1:NC1)-interf.y(1:NC1)))/vV+
+                OutletV.z(1:NC1)*sum(interf.NV);
+
+        "Mechanical Equilibrium"
+        OutletV.P = OutletL.P;
+        interf.P=OutletL.P;
+end
+
+Model trayRate as trayRateBasic
+        ATTRIBUTES
+        Pallete         = false;
+        Icon            = "icon/Tray"; 
+        Brief           = "Complete rate model of a column tray.";
+        Info            =
+"== Specify ==
+* the Feed stream
+* the Liquid inlet stream
+* the Vapour inlet stream
+* the Vapour outlet flow (OutletV.F)
+        
+== Initial ==
+* the plate temperature of both phases (OutletL.T and OutletV.T)
+* the liquid height (Level) OR the liquid flow holdup (ML)
+* the vapor holdup (MV)
+* (NoComps - 1) OutletL compositions
+";
+
+        PARAMETERS
+        Ah as area (Brief="Total holes area");
+        lw as length (Brief="Weir length");
+        g as acceleration (Default=9.81);
+        hw as length (Brief="Weir height");
+        beta as fraction (Brief="Aeration fraction");
+        alfa as fraction (Brief="Dry pressure drop coefficient");
+        
+        VapourFlow as Switcher(Valid = ["on", "off"], Default = "on");
+        LiquidFlow as Switcher(Valid = ["on", "off"], Default = "on");
+        
+        VARIABLES
+        rhoL as dens_mass;
+        rhoV as dens_mass;
+
+        EQUATIONS
+        "Liquid Density"
+        rhoL = PP.LiquidDensity(OutletL.T, OutletL.P, OutletL.z);
+        "Vapour Density"
+        rhoV = PP.VapourDensity(InletV.T, InletV.P, InletV.z);
+
+        switch LiquidFlow
+                case "on":
+                "Francis Equation"
+#               OutletL.F*vL = 1.84*'m^0.5/s'*lw*((Level-(beta*hw))/(beta))^1.5;
+                OutletL.F*vL = 1.84*'1/s'*lw*((Level-(beta*hw))/(beta))^2;
+                when Level < (beta * hw) switchto "off";
+                
+                case "off":
+                "Low level"
+                OutletL.F = 0 * 'mol/h';
+                when Level > (beta * hw) + 1e-6*'m' switchto "on";
+        end
+
+        switch VapourFlow
+                case "on":
+                InletV.F*vV = sqrt((InletV.P - OutletV.P)/(rhoV*alfa))*Ah;
+                when InletV.F < 1e-6 * 'kmol/h' switchto "off";
+                
+                case "off":
+                InletV.F = 0 * 'mol/s';
+                when InletV.P > OutletV.P + Level*g*rhoL + 1e-1 * 'atm' switchto "on";
+        end     
+end

trunk/sample/stage_separators/sample_tray.mso

@@ -220 +220 @@
         TimeEnd = 100;
 end
+
+FlowSheet trayRate_Test
+        PARAMETERS
+        PP      as Plugin(Brief="Physical Properties",
+                Type="PP",
+                Components = [ "n-pentane", "benzene"],
+                LiquidModel = "PR",
+                VapourModel = "PR"
+        );
+        NComp   as Integer;
+
+        SET
+        NComp = PP.NumberOfComponents;
+        
+        DEVICES
+        t1 as trayRate;
+        feed as source;
+        feedV as source;
+        inL as liquid_stream;
+        inV as vapour_stream;
+        
+        CONNECTIONS
+        feed.Outlet to t1.Inlet;
+        feedV.Outlet to t1.InletFV;
+        inL to t1.InletL;
+        inV to t1.InletV;
+        
+        SPECIFY
+        feed.Outlet.F = 116 * 'kmol/h';
+        feed.Outlet.T = 280 * 'K';
+        feed.Outlet.P = 150 * 'kPa';
+        feed.Outlet.z = [0.5, 0.5];
+
+        feedV.Outlet.F = 0 * 'kmol/h';
+        feedV.Outlet.T = 280 * 'K';
+        feedV.Outlet.P = 150 * 'atm';
+        feedV.Outlet.z = [0.5, 0.5];
+
+        inL.P = 150 * 'kPa';
+        inL.T = 290 * 'K';
+        inL.F = 90 * 'kmol/h';
+        inL.z = [0.1641, 0.8359];
+
+        inV.P = 150 * 'kPa';
+        inV.T = 500 * 'K';
+        inV.z = [0.0584, 0.9416];
+#       inV.F = 62 * 'kmol/h';
+
+        t1.OutletV.F = 120 * 'kmol/h';
+#       t1.OutletL.F = 120 * 'kmol/h';
+        t1.interf.a = 40 * 'm^2';
+        t1.interf.htL = 10.01 * 'kW/m^2/K';
+        t1.interf.htV = 0.025 * 'kW/m^2/K';
+        t1.interf.kL = 0.00933 * 'm/s';
+        t1.interf.kV = 0.000236 * 'm/s';
+
+        SET
+        t1.V = 4 * 'ft^3';
+        t1.Ah = 0.394 * 'ft^2';
+        t1.lw = 20.94 * 'in';
+        t1.hw = 0.125 * 'ft';
+        t1.beta = 0.6;
+        t1.alfa = 4;
+        t1.Ap = 3.94 * 'ft^2';
+        t1.Q = 0 * 'kW';
+
+        INITIAL
+        t1.OutletL.T = 295 *'K';
+        t1.OutletV.T = 290 *'K';
+        t1.Level = 0.9 * t1.hw;
+        t1.OutletL.z(1) = 0.5;
+        t1.OutletV.z(1) = 0.6;
+        t1.MV = 1.0*'mol' ;
+
+        OPTIONS
+        TimeStep = 0.1;
+        TimeEnd = 10;
+        TimeUnit = 's';
+        GuessFile = "trayRate_Test.rlt";
+end