Changeset 503 for branches/rate

Timestamp:

Apr 15, 2008, 5:48:57 PM (15 years ago)

Author:

Gabriela Sporleder Straatmann

Message:

Starting rate model for tray.mso

File:

• branches/rate/eml/stage_separators/tray.mso (modified) (1 diff)

branches/rate/eml/stage_separators/tray.mso

@@ -472 +472 @@
         hl = (12*miL*a^2*uL/rhoL/g)^1/3;
 end
+
+Model trayRate
+        ATTRIBUTES
+        Pallete         = false;
+        Icon            = "icon/Tray"; 
+        Brief           = "Basic equations of a tray column model.";
+        Info            =
+"This model contains only the main equations of a column tray equilibrium model without
+the hidraulic equations.
+        
+== Assumptions ==
+* both phases (liquid and vapour) exists all the time;
+* thermodymanic equilibrium with Murphree plate efficiency;
+* no entrainment of liquid or vapour phase;
+* no weeping;
+* the dymanics in the downcomer are neglected.
+";
+        
+        PARAMETERS
+outer PP as Plugin(Brief = "External Physical Properties", Type="PP");
+outer NComp as Integer;
+        V as volume(Brief="Total Volume of the tray");
+        Q as heat_rate (Brief="Rate of heat supply"); 
+        Ap as area (Brief="Plate area = Atray - Adowncomer");
+        
+        VARIABLES
+in      Inlet as stream (Brief="Feed stream", PosX=0, PosY=0.4932, Symbol="_{in}");
+in      InletL as stream (Brief="Inlet liquid stream", PosX=0.5195, PosY=0, Symbol="_{inL}");
+in      InletV as stream (Brief="Inlet vapour stream", PosX=0.4994, PosY=1, Symbol="_{inV}");
+out     OutletL as liquid_stream (Brief="Outlet liquid stream", PosX=0.8277, PosY=1, Symbol="_{outL}");
+out     OutletV as vapour_stream (Brief="Outlet vapour stream", PosX=0.8043, PosY=0, Symbol="_{outV}");
+
+        M(NComp) as mol (Brief="Molar Holdup in the tray");
+        ML as mol (Brief="Molar liquid holdup");
+        MV as mol (Brief="Molar vapour holdup");
+        E as energy (Brief="Total Energy Holdup on tray");
+        vL as volume_mol (Brief="Liquid Molar Volume");
+        vV as volume_mol (Brief="Vapour Molar volume");
+        Level as length (Brief="Height of clear liquid on plate");
+        yideal(NComp) as fraction;
+        Emv as Real (Brief = "Murphree efficiency");
+        
+        EQUATIONS
+        "Component Molar Balance"
+        diff(M)=Inlet.F*Inlet.z + InletL.F*InletL.z + InletV.F*InletV.z
+                - OutletL.F*OutletL.z - OutletV.F*OutletV.z;
+        
+        "Energy Balance"
+        diff(E) = ( Inlet.F*Inlet.h + InletL.F*InletL.h + InletV.F*InletV.h
+                - OutletL.F*OutletL.h - OutletV.F*OutletV.h + Q );
+        
+        "Molar Holdup"
+        M = ML*OutletL.z + MV*OutletV.z;
+        
+        "Energy Holdup"
+        E = ML*OutletL.h + MV*OutletV.h - OutletL.P*V;
+        
+        "Mol fraction normalisation"
+        sum(OutletL.z)= 1.0;
+        sum(OutletL.z)= sum(OutletV.z);
+        
+        "Liquid Volume"
+        vL = PP.LiquidVolume(OutletL.T, OutletL.P, OutletL.z);
+        "Vapour Volume"
+        vV = PP.VapourVolume(OutletV.T, OutletV.P, OutletV.z);
+        
+        "Chemical Equilibrium"
+        PP.LiquidFugacityCoefficient(OutletL.T, OutletL.P, OutletL.z)*OutletL.z = 
+                PP.VapourFugacityCoefficient(OutletV.T, OutletV.P, yideal)*yideal;
+
+        "Murphree Efficiency"
+        OutletV.z = Emv * (yideal - InletV.z) + InletV.z;
+        
+        "Thermal Equilibrium"
+        OutletV.T = OutletL.T;
+        
+        "Mechanical Equilibrium"
+        OutletV.P = OutletL.P;
+        
+        "Geometry Constraint"
+        V = ML* vL + MV*vV;
+        
+        "Level of clear liquid over the weir"
+        Level = ML*vL/Ap;
+end
+