Changeset 498 for trunk/eml/stage_separators

Timestamp:

Apr 11, 2008, 3:21:24 PM (15 years ago)

Author:

Paula Bettio Staudt

Message:

First official version of packed stage and packed column with samples

Location:

trunk/eml/stage_separators

Files:

• column.mso (modified) (1 diff)
• tray.mso (modified) (1 diff)

trunk/eml/stage_separators/column.mso

@@ -1261 +1261 @@
         
 end
+
+#*----------------------------------------------------------------------
+* Model of a  packed column section with:
+*       - NStages = theoretical number of equilibrium stages.
+* 
+*---------------------------------------------------------------------*# 
+Model Packed_Section_Column
+        ATTRIBUTES
+        Pallete         = true;
+        Icon            = "icon/SectionColumn"; 
+        Brief           = "Model of a packed column section.";
+        Info            =
+"== Model of a packed column section containing ==
+* NStages theoretical stages.
+        
+== Specify ==
+* the feed stream of each tray (Inlet);
+* the InletL stream of the top tray;
+* the InletV stream of the bottom tray;
+* the pressure drop (deltaP) of each tray.
+        
+== Initial Conditions ==
+* the stages temperature (OutletL.T);
+* the stages liquid holdup;
+* (NoComps - 1) OutletL (OR OutletV) compositions for each tray.
+";
+        
+        PARAMETERS
+        outer PP as Plugin(Brief = "External Physical Properties", Type="PP");
+        outer NComp as Integer;
+        NStages as Integer(Brief="Number of trays", Default=2);
+        topdown as Integer(Brief="Trays counting (1=top-down, -1=bottom-up)", Default=1);
+        top as Integer(Brief="Number of top tray");
+        bot as Integer(Brief="Number of bottom tray");
+        H as length (Brief="Height of packing");
+
+        VARIABLES
+        stage(NStages) as packedStage;
+        
+        SET
+        top = (NStages-1)*(1-topdown)/2+1;
+        bot = NStages/top;
+        stage.hs = H/NStages;   
+        stage.V = stage.hs * stage.d^2*3.14159/4;
+        
+        CONNECTIONS
+        stage([top+topdown:topdown:bot]).OutletV to stage([top:topdown:bot-topdown]).InletV;
+        stage([top:topdown:bot-topdown]).OutletL to stage([top+topdown:topdown:bot]).InletL;
+end
+
+#*----------------------------------------------------------------------
+* Model of a  packed distillation column containing:
+*       - a section with NStages theoretical stages;
+*       - a kettle reboiler;
+*       - dymamic condenser;
+*       - a splitter which separate reflux and distillate;
+*       - a pump in reflux stream;
+*---------------------------------------------------------------------*# 
+Model PackedDistillation_kettle_cond as Packed_Section_Column
+        PARAMETERS
+        VapourFlow as Switcher(Valid = ["on", "off"], Default = "on");
+        
+        VARIABLES
+        cond as condenser;
+        reb as reboiler;
+        sptop as splitter;
+        pump1 as pump;
+        
+        CONNECTIONS
+        #vapor
+        reb.OutletV to stage(bot).InletV;
+        stage(top).OutletV to cond.InletV;
+        
+        #liquid
+        cond.OutletL to sptop.Inlet;    
+        sptop.Outlet2 to pump1.Inlet;
+        pump1.Outlet to stage(top).InletL;
+        stage(bot).OutletL to reb.InletL;
+        
+        EQUATIONS
+        switch VapourFlow
+                case "on":
+                stage(bot).InletV.F*stage(bot).vV = sqrt((reb.OutletV.P - stage(bot).OutletV.P)/
+                                        (stage(bot).rhoV*stage(bot).Qsil*20))*(stage(bot).d^2*3.14159/4*stage(bot).e - stage(bot).Al);
+                when stage(bot).InletV.F < 1e-6 * 'kmol/h' switchto "off";
+                
+                case "off":
+                stage(bot).InletV.F = 0 * 'mol/s';
+                when reb.OutletV.P > stage(bot).OutletV.P + 1e-1 * 'atm' switchto "on";
+        end
+
+end

trunk/eml/stage_separators/tray.mso

@@ -323 +323 @@
         V = ML* vL + MV*vV;
 end
+
+#*-------------------------------------
+* Model of a packed column stage
+-------------------------------------*#
+Model packedStage
+        ATTRIBUTES
+        Pallete         = false;
+        Icon            = "icon/Tray"; 
+        Brief           = "Complete model of a packed column stage.";
+        Info            =
+"== Specify ==
+* the Feed stream
+* the Liquid inlet stream
+* the Vapour inlet stream
+* the stage pressure drop (deltaP)
+        
+== Initial ==
+* the plate temperature (OutletL.T)
+* the liquid molar holdup ML
+* (NoComps - 1) OutletL compositions
+";      
+        
+        PARAMETERS
+outer PP as Plugin(Brief = "External Physical Properties", Type="PP");
+outer NComp as Integer;
+        PPwater as Plugin(Brief="Physical Properties",
+                Type="PP",
+                Components = [ "water" ],
+                LiquidModel = "PR",
+                VapourModel = "PR"
+        );
+
+        V as volume(Brief="Total Volume of the tray");
+        Q as heat_rate (Brief="Rate of heat supply"); 
+        d as length (Brief="Column diameter");  
+
+        a as Real (Brief="surface area per packing volume", Unit='m^2/m^3');
+        g as acceleration;
+        e as Real (Brief="Void fraction of packing, m^3/m^3");
+        Cpo as Real (Brief="Constant for resitance equation"); # Billet and Schultes, 1999.
+        Mw(NComp)       as molweight    (Brief = "Component Mol Weight");
+        hs as length (Brief="Height of the packing stage");
+        Qsil as positive (Brief="Resistance coefficient on the liquid load", Default=1);
+
+        VARIABLES
+in      Inlet as stream (Brief="Feed stream", PosX=0, PosY=0.4932, Symbol="_{in}");
+in      InletL as stream (Brief="Inlet liquid stream", PosX=0.5195, PosY=0, Symbol="_{inL}");
+in      InletV as stream (Brief="Inlet vapour stream", PosX=0.4994, PosY=1, Symbol="_{inV}");
+out     OutletL as liquid_stream (Brief="Outlet liquid stream", PosX=0.8277, PosY=1, Symbol="_{outL}");
+out     OutletV as vapour_stream (Brief="Outlet vapour stream", PosX=0.8043, PosY=0, Symbol="_{outV}");
+
+        M(NComp) as mol (Brief="Molar Holdup in the tray", Default=0.01, Lower=0, Upper=100);
+        ML as mol (Brief="Molar liquid holdup", Default=0.01, Lower=0, Upper=100);
+        MV as mol (Brief="Molar vapour holdup", Default=0.01, Lower=0, Upper=100);
+        E as energy (Brief="Total Energy Holdup on tray", Default=-500);
+        vL as volume_mol (Brief="Liquid Molar Volume");
+        vV as volume_mol (Brief="Vapour Molar volume");
+        
+        miL as viscosity (Brief="Liquid dynamic viscosity", DisplayUnit='kg/m/s');
+        miV as viscosity (Brief="Vapor dynamic viscosity", DisplayUnit='kg/m/s');
+        rhoL as dens_mass;
+        rhoV as dens_mass;
+        
+        deltaP as pressure;
+        
+        uL as velocity (Brief="volume flow rate of liquid, m^3/m^2/s", Lower=-10, Upper=100);
+        uV as velocity (Brief="volume flow rate of vapor, m^3/m^2/s", Lower=-10, Upper=100);
+        dp as length (Brief="Particle diameter", Default=1e-3, Lower=0, Upper=10);
+        invK as positive (Brief="Wall factor", Default=1, Upper=10);
+        Rev as Real (Brief="Reynolds number of the vapor stream", Default=4000);
+        Al as area (Brief="Area occupied by the liquid", Default=0.001, Upper=1);
+        hl as positive (Brief="Column holdup", Unit='m^3/m^3', Default=0.01,Upper=10);
+
+        SET
+        Mw = PP.MolecularWeight();
+
+        EQUATIONS
+        "Component Molar Balance"
+        diff(M)=Inlet.F*Inlet.z + InletL.F*InletL.z + InletV.F*InletV.z
+                - OutletL.F*OutletL.z - OutletV.F*OutletV.z;
+
+        "Energy Balance"
+        diff(E) = ( Inlet.F*Inlet.h + InletL.F*InletL.h + InletV.F*InletV.h
+                - OutletL.F*OutletL.h - OutletV.F*OutletV.h + Q );
+        
+        "Molar Holdup"
+        M = ML*OutletL.z + MV*OutletV.z;
+        
+        "Energy Holdup"
+        E = ML*OutletL.h + MV*OutletV.h - OutletL.P*V;
+        
+        "Mol fraction normalisation"
+        sum(OutletL.z)= 1.0;
+        
+        "Liquid Volume"
+        vL = PP.LiquidVolume(OutletL.T, OutletL.P, OutletL.z);
+        "Vapour Volume"
+        vV = PP.VapourVolume(OutletV.T, OutletV.P, OutletV.z);
+        
+        "Chemical Equilibrium"
+        PP.LiquidFugacityCoefficient(OutletL.T, OutletL.P, OutletL.z)*OutletL.z = 
+                PP.VapourFugacityCoefficient(OutletV.T, OutletV.P, OutletV.z)*OutletV.z;
+        
+        "Thermal Equilibrium"
+        OutletV.T = OutletL.T;
+        
+        "Mechanical Equilibrium"
+        OutletL.P = OutletV.P;
+        
+        "Geometry Constraint"
+        V*e = ML*vL + MV*vV;
+        
+        "Liquid Density"
+        rhoL = PP.LiquidDensity(OutletL.T, OutletL.P, OutletL.z);
+        "Vapour Density"
+        rhoV = PP.VapourDensity(InletV.T, InletV.P, InletV.z);
+        "Liquid viscosity"
+        miL = PP.LiquidViscosity(OutletL.T, OutletL.P, OutletL.z);
+        "Vapour viscosity"
+        miV = PP.VapourViscosity(InletV.T, InletV.P, InletV.z);
+
+        "Area occupied by the liquid"
+        Al = ML*vL/hs;
+
+        "Volume flow rate of liquid, m^3/m^2/s"
+        uL * Al = OutletL.F * vL;
+        "Volume flow rate of vapor, m^3/m^2/s"
+        uV * ((d^2*3.14159/4)*e - Al) = OutletV.F * vV;
+        
+        "Liquid holdup"
+        hl = ML*vL/V/e;
+        
+        "Particle diameter"
+        dp = 6 * (1-e)/a;
+        
+        "Wall Factor"
+        invK = (1 + (2*dp/(3*d*(1-e))));
+        
+        "Reynolds number of the vapor stream"
+        Rev*invK = dp*uV*rhoV / (miV*(1-e));
+        
+        deltaP = InletV.P - OutletV.P;
+        
+        "Pressure drop and Vapor flow"
+        deltaP/hs  = Qsil*a*uV^2*rhoV*invK / (2*(e-hl)^3);
+
+        "Liquid holdup"
+        hl = (12*miL*a^2*uL/rhoL/g)^1/3;
+end