Changeset 38 for mso/eml/stage_separators

Timestamp:

Oct 23, 2006, 5:26:39 PM (16 years ago)

Author:

Paula Bettio Staudt

Message:

Included reactive distillation column

Location:

mso/eml/stage_separators

Files:

• column.mso (modified) (1 diff)
• condenser.mso (modified) (1 diff)
• reboiler.mso (modified) (1 diff)
• tray.mso (modified) (1 diff)

mso/eml/stage_separators/column.mso

@@ -909 +909 @@
         spbottom.Outlet2 to reb.InletL;
 end
+
+# Reactive Distillation!!
+Model ReactiveDistillation
+        PARAMETERS
+ext PP as CalcObject;
+ext NComp as Integer;
+        NTrays as Integer(Brief="Number of trays", Default=2);
+        
+        VARIABLES
+        trays(NTrays) as trayReact;
+        cond as condenserReact;
+        reb as reboilerReact;
+        sp as splitter;
+        p as pump;
+        
+        EQUATIONS
+        if ( reb.OutletV.P > 1 * "atm" ) then
+                "Pressure Drop through the tray"
+                reb.OutletV.F = trays(1).Ah/reb.vV * sqrt((reb.OutletV.P - 1*"atm") / (0.15*reb.rhoV) );
+        else
+                "Prato selado"
+                reb.OutletV.F = 0.0 * "mol/s";
+        end
+        
+        CONNECTIONS
+        #vapor
+        reb.OutletV to trays([NTrays]).InletV;
+        trays([2:NTrays]).OutletV to trays([1:NTrays-1]).InletV;
+        trays(1).OutletV to cond.InletV;
+
+        #liquid
+        cond.OutletL to sp.Inlet;       
+        sp.Outlet2 to p.Inlet;
+        p.Outlet to trays(1).InletL;
+        trays([1:NTrays-1]).OutletL to trays([2:NTrays]).InletL;
+        trays(NTrays).OutletL to reb.InletL;
+end

mso/eml/stage_separators/condenser.mso

@@ -122 +122 @@
         OutletL.v = 0.0;
 end
+
+#*-------------------------------------------------------------------
+* Condenser with reaction in liquid phase
+*--------------------------------------------------------------------*#
+Model condenserReact
+        PARAMETERS
+ext PP as CalcObject;
+ext NComp as Integer;
+        V as volume (Brief="Condenser total volume");
+        Across as area (Brief="Cross Section Area of reboiler");
+
+        stoic(NComp) as Real(Brief="Stoichiometric matrix");
+        Hr as energy_mol;
+        Pstartup as pressure;
+
+        VARIABLES
+in      InletV as stream;                       #(Brief="Vapour inlet stream");
+out     OutletL as stream_therm;        #(Brief="Liquid outlet stream");
+out     OutletV as stream_therm;        #(Brief="Vapour outlet stream");
+
+        M(NComp) as mol (Brief="Molar Holdup in the tray");
+        ML as mol (Brief="Molar liquid holdup");
+        MV as mol (Brief="Molar vapour holdup");
+        E as energy (Brief="Total Energy Holdup on tray");
+        vL as volume_mol (Brief="Liquid Molar Volume");
+        vV as volume_mol (Brief="Vapour Molar volume");
+        Level as length (Brief="Level of liquid phase");
+        Q as heat_rate (Brief="Heat supplied");
+        Vol as volume;
+        r as reaction_mol (Brief = "Reaction rate", Unit = "mol/l/s");
+        C(NComp) as conc_mol (Brief = "Molar concentration", Lower = -1);
+
+        EQUATIONS
+        "Molar Concentration"
+        OutletL.z = vL * C;
+        
+        "Component Molar Balance"
+        diff(M) = InletV.F*InletV.z - OutletL.F*OutletL.z
+                                - OutletV.F*OutletV.z + stoic*r*ML*vL;
+
+        "Energy Balance"
+        diff(E) = InletV.F*InletV.h - OutletL.F*OutletL.h
+                                - OutletV.F*OutletV.h + Q + Hr * r * ML*vL;
+
+        "Molar Holdup"
+        M = ML*OutletL.z + MV*OutletV.z; 
+        
+        "Energy Holdup"
+        E = ML*OutletL.h + MV*OutletV.h - OutletV.P*V;
+        
+        "Mol fraction normalisation"
+        sum(OutletL.z)=1.0;
+
+        "Liquid Volume"
+        vL = PP.LiquidVolume(OutletL.T, OutletL.P, OutletL.z);
+        "Vapour Volume"
+        vV = PP.VapourVolume(OutletV.T, OutletV.P, OutletV.z);
+
+        "Thermal Equilibrium"
+        OutletL.T = OutletV.T;
+
+        "Mechanical Equilibrium"
+        OutletV.P = OutletL.P;
+
+        "Geometry Constraint"
+        V = ML*vL + MV*vV;
+
+        Vol = ML*vL;
+        
+        "Level of liquid phase"
+        Level = ML*vL/Across;
+        
+        "Vapourisation Fraction"
+        OutletL.v = 0.0;
+        OutletV.v = 1.0;
+        
+        "Chemical Equilibrium"
+        PP.LiquidFugacityCoefficient(OutletL.T, OutletL.P, OutletL.z)*OutletL.z = 
+        PP.VapourFugacityCoefficient(OutletV.T, OutletV.P, OutletV.z)*OutletV.z;
+
+        sum(OutletL.z)=sum(OutletV.z);
+
+end

mso/eml/stage_separators/reboiler.mso

@@ -141 +141 @@
 end
 
+#*-------------------------------------------------------------------
+* Model of a dynamic reboiler with reaction
+*-------------------------------------------------------------------*#
+Model reboilerReact
+        PARAMETERS
+ext PP as CalcObject;
+ext NComp as Integer;
+        Across as area (Brief="Cross Section Area of reboiler");
+        V as volume (Brief="Total volume of reboiler");
+
+        stoic(NComp) as Real(Brief="Stoichiometric matrix");
+        Hr as energy_mol;
+        Pstartup as pressure;
+
+        VARIABLES
+in      Inlet as stream;                        #(Brief="Feed Stream");
+in      InletL as stream;                       #(Brief="Liquid inlet stream");
+out     OutletL as stream_therm;        #(Brief="Liquid outlet stream");
+out     OutletV as stream_therm;        #(Brief="Vapour outlet stream");
+
+        Q as heat_rate (Brief="Heat supplied");
+        M(NComp) as mol (Brief="Molar Holdup in the tray");
+        ML as mol (Brief="Molar liquid holdup");
+        MV as mol (Brief="Molar vapour holdup");
+        E as energy (Brief="Total Energy Holdup on tray");
+        vL as volume_mol (Brief="Liquid Molar Volume");
+        vV as volume_mol (Brief="Vapour Molar volume");
+        Level as length (Brief="Level of liquid phase");
+        Vol as volume;
+        startup as Real;
+        rhoV as dens_mass;
+        r as reaction_mol (Brief = "Reaction resulting ethyl acetate", Unit = "mol/l/s");
+        C(NComp) as conc_mol (Brief = "Molar concentration", Lower = -1);
+
+        EQUATIONS
+        "Molar Concentration"
+        OutletL.z = vL * C;
+        
+        "Component Molar Balance"
+        diff(M)= Inlet.F*Inlet.z + InletL.F*InletL.z
+                - OutletL.F*OutletL.z - OutletV.F*OutletV.z + stoic*r*ML*vL;
+        
+        "Energy Balance"
+        diff(E) = Inlet.F*Inlet.h + InletL.F*InletL.h
+                - OutletL.F*OutletL.h - OutletV.F*OutletV.h + Q + Hr * r * vL*ML;
+        
+        "Molar Holdup"
+        M = ML*OutletL.z + MV*OutletV.z; 
+        
+        "Energy Holdup"
+        E = ML*OutletL.h + MV*OutletV.h - OutletL.P*V;
+        
+        "Mol fraction normalisation"
+        sum(OutletL.z)=1.0;
+        
+        "Liquid Volume"
+        vL = PP.LiquidVolume(OutletL.T, OutletL.P, OutletL.z);
+        "Vapour Volume"
+        vV = PP.VapourVolume(OutletV.T, OutletV.P, OutletV.z);  
+        "Vapour Density"
+        rhoV = PP.VapourDensity(OutletV.T, OutletV.P, OutletV.z);
+        
+        "Level of liquid phase"
+        Level = ML*vL/Across;
+
+        Vol = ML*vL;
+        
+        "vaporization fraction "
+        OutletV.v = 1.0;
+        OutletL.v = 0.0;
+        
+        "Mechanical Equilibrium"
+        OutletL.P = OutletV.P;
+        
+        "Thermal Equilibrium"
+        OutletL.T = OutletV.T;  
+        
+        "Geometry Constraint"
+        V = ML*vL + MV*vV;              
+
+        "Chemical Equilibrium"
+        PP.LiquidFugacityCoefficient(OutletL.T, OutletL.P, OutletL.z)*OutletL.z = 
+        PP.VapourFugacityCoefficient(OutletV.T, OutletV.P, OutletV.z)*OutletV.z;
+
+        sum(OutletL.z)=sum(OutletV.z);
+        
+end

mso/eml/stage_separators/tray.mso

@@ -142 +142 @@
 end
 
+#*-------------------------------------------------------------------
+* Model of a tray with reaction
+*-------------------------------------------------------------------*#
+Model trayReact
+
+        PARAMETERS
+ext PP as CalcObject;
+ext NComp as Integer;
+        V as volume(Brief="Total Volume of the tray");
+        Q as power (Brief="Rate of heat supply"); 
+        Ap as area (Brief="Plate area = Atray - Adowncomer");
+        
+        Ah as area (Brief="Total holes area");
+        lw as length (Brief="Weir length");
+        g as acceleration (Default=9.81);
+        hw as length (Brief="Weir height");
+        beta as fraction (Brief="Aeration fraction");
+        alfa as fraction (Brief="Dry pressure drop coefficient");
+
+        stoic(NComp) as Real(Brief="Stoichiometric matrix");
+        Hr as energy_mol;
+        Pstartup as pressure;
+        
+        VARIABLES
+in      Inlet as stream;
+in      InletL as stream;
+in      InletV as stream;
+out     OutletL as stream_therm;
+out     OutletV as stream_therm;
+
+        yideal(NComp) as fraction;
+        Emv as Real (Brief = "Murphree efficiency");
+
+        M(NComp) as mol (Brief="Molar Holdup in the tray");
+        ML as mol (Brief="Molar liquid holdup");
+        MV as mol (Brief="Molar vapour holdup");
+        E as energy (Brief="Total Energy Holdup on tray");
+        vL as volume_mol (Brief="Liquid Molar Volume");
+        vV as volume_mol (Brief="Vapour Molar volume");
+        Level as length (Brief="Height of clear liquid on plate");
+        Vol as volume;
+        
+        rhoL as dens_mass;
+        rhoV as dens_mass;
+        r as reaction_mol (Brief = "Reaction rate", Unit = "mol/l/s");
+        C(NComp) as conc_mol (Brief = "Molar concentration", Lower = -1); #, Unit = "mol/l");
+        
+        EQUATIONS
+        "Molar Concentration"
+        OutletL.z = vL * C;
+        
+        "Component Molar Balance"
+        diff(M)=Inlet.F*Inlet.z + InletL.F*InletL.z + InletV.F*InletV.z
+                - OutletL.F*OutletL.z - OutletV.F*OutletV.z + stoic*r*ML*vL;
+        
+        "Energy Balance"
+        diff(E) = ( Inlet.F*Inlet.h + InletL.F*InletL.h + InletV.F*InletV.h
+                - OutletL.F*OutletL.h - OutletV.F*OutletV.h + Q ) + Hr * r * vL*ML;
+        
+        "Molar Holdup"
+        M = ML*OutletL.z + MV*OutletV.z;
+        
+        "Energy Holdup"
+        E = ML*OutletL.h + MV*OutletV.h - OutletL.P*V;
+        
+        "Mol fraction normalisation"
+        sum(OutletL.z)= 1.0;
+        
+        "Liquid Volume"
+        vL = PP.LiquidVolume(OutletL.T, OutletL.P, OutletL.z);
+        "Vapour Volume"
+        vV = PP.VapourVolume(OutletV.T, OutletV.P, OutletV.z);
+
+        "Thermal Equilibrium"
+        OutletV.T = OutletL.T;
+        
+        "Mechanical Equilibrium"
+        OutletV.P = OutletL.P;
+        
+        "vaporization fraction "
+        OutletV.v = 1.0;
+        OutletL.v = 0.0;
+        
+        "Level of clear liquid over the weir"
+        Level = ML*vL/Ap;
+
+        Vol = ML*vL;
+        
+        "Liquid Density"
+        rhoL = PP.LiquidDensity(OutletL.T, OutletL.P, OutletL.z);
+        "Vapour Density"
+        rhoV = PP.VapourDensity(InletV.T, InletV.P, InletV.z);
+
+        if (Level > (beta * hw)) then
+                "Francis Equation"
+                OutletL.F = (1.84*"m^0.5/s"*lw*((Level-(beta*hw))/(beta))^1.5/vL);
+        else
+                "Low level"
+                OutletL.F = 0 * "mol/h";
+        end
+
+                
+        "Pressure Drop through the tray"
+        OutletV.F = (1 + tanh(1 * (OutletV.P - Pstartup)/"Pa"))/2 * 
+                Ah/vV * sqrt(2*(OutletV.P - InletL.P + 1e-8 * "atm") / (alfa*rhoV) );
+        
+
+        "Chemical Equilibrium"
+        PP.LiquidFugacityCoefficient(OutletL.T, OutletL.P, OutletL.z)*OutletL.z = 
+                PP.VapourFugacityCoefficient(OutletV.T, OutletV.P, OutletV.z)*yideal;
+        
+        OutletV.z = Emv * (yideal - InletV.z) + InletV.z;
+        
+        sum(OutletL.z)= sum(OutletV.z);
+        
+        "Geometry Constraint"
+        V = ML* vL + MV*vV;
+end