Changeset 321 for trunk

Timestamp:

Jul 20, 2007, 11:30:53 AM (16 years ago)

Author:

Argimiro Resende Secchi

Message:

Fix Pallete of streams.mso and add flashPH as another model of flash for devices.

Location:

trunk

Files:

• eml/stage_separators/flash.mso (modified) (1 diff)
• eml/streams.mso (modified) (5 diffs)
• sample/miscellaneous/sample_flashPH.mso (deleted)
• sample/stage_separators/sample_flashPH.mso (added)

trunk/eml/stage_separators/flash.mso

@@ -164 +164 @@
         OutletV.P = OutletL.P;
 end
+
+#*----------------------------------------------------------------------
+* Model of a steady-state PH flash.
+*---------------------------------------------------------------------*# 
+Model FlashPHSteady
+        ATTRIBUTES
+        Pallete         = true;
+        Icon            = "icon/Flash"; 
+        Brief           = "Model of a static PH flash.";
+        Info            = "
+        This model is for using the flashPH
+        routine available on VRTherm.
+
+        Assumptions:
+         * perfect mixing of both phases;
+
+        Specify: 
+         * the feed stream;
+         * the heat duty;
+         * the outlet pressure.
+        ";      
+
+        PARAMETERS
+outer PP as Plugin(Brief = "External Physical Properties", Type="PP");
+outer NComp as Integer;
+
+        VARIABLES
+in      Inlet as stream (Brief="Feed Stream");
+out     OutletL as liquid_stream (Brief="Liquid outlet stream");
+out     OutletV as vapour_stream (Brief="Vapour outlet stream");
+in      InletQ as energy_stream (Brief="Rate of heat supply"); 
+        vfrac as fraction(Brief="Real vaporization fraction");
+        h as enth_mol(Brief="Mixture enthalpy");
+
+        EQUATIONS
+
+        "Chemical equilibrium"
+        [vfrac,OutletL.z,OutletV.z]=PP.FlashPH(OutletL.P,h,Inlet.z);
+
+        "Global Molar Balance"
+        Inlet.F = OutletV.F + OutletL.F;
+        OutletV.F = Inlet.F * vfrac;
+
+        "Energy Balance"
+        Inlet.F*(h - Inlet.h) = InletQ.Q;
+        Inlet.F*h = Inlet.F*(1-vfrac)*OutletL.h + Inlet.F*vfrac*OutletV.h;
+
+        "Thermal Equilibrium"
+        OutletV.T = OutletL.T;
+        
+        "Mechanical Equilibrium"
+        OutletV.P = OutletL.P;
+end
+
+#*----------------------------------------------------------------------
+* Another model of a steady-state PH flash.
+* It is recommended to use [v,x,y]=PP.FlashPH(P,h,z) instead of.
+*---------------------------------------------------------------------*# 
+Model FlashPHSteadyA
+        ATTRIBUTES
+        Pallete         = true;
+        Icon            = "icon/Flash"; 
+        Brief           = "Another model of a static PH flash.";
+        Info            = "
+        This model shows how to model a pressure enthalpy flash
+        directly with the EMSO modeling language.
+
+        This model is for demonstration purposes only, the flashPH
+        routine available on VRTherm is much more robust.
+
+        Assumptions:
+         * perfect mixing of both phases;
+
+        Specify: 
+         * the feed stream;
+         * the heat duty;
+         * the outlet pressure.
+        ";      
+        
+        PARAMETERS
+outer PP as Plugin(Brief = "External Physical Properties", Type="PP");
+outer NComp as Integer;
+        B as Real(Default=1000, Brief="Regularization Factor");
+
+        VARIABLES
+in      Inlet as stream (Brief="Feed Stream");
+out     OutletL as liquid_stream (Brief="Liquid outlet stream");
+out     OutletV as vapour_stream (Brief="Vapour outlet stream");
+in      InletQ as energy_stream (Brief="Rate of heat supply"); 
+        vfrac as fraction(Brief="Real vaporization fraction");
+        vsat as Real(Lower=-0.1, Upper=1.1, Brief="Vaporization fraction if saturated");
+        Tsat as temperature(Lower=173, Upper=1473, Brief="Temperature if saturated");
+        xsat(NComp) as Real(Lower=0, Upper=1, Brief="Liquid composition if saturated");
+        ysat(NComp) as Real(Lower=0, Upper=1, Brief="Vapour composition if saturated");
+        
+        zero_one as fraction(Brief="Regularization Variable");
+        one_zero as fraction(Brief="Regularization Variable");
+
+        EQUATIONS
+        "Chemical equilibrium"
+        PP.LiquidFugacityCoefficient(Tsat, OutletL.P, xsat)*xsat = 
+                PP.VapourFugacityCoefficient(Tsat, OutletV.P, ysat)*ysat;
+
+        "Global Molar Balance"
+        Inlet.F = OutletV.F + OutletL.F;
+        OutletV.F = Inlet.F * vfrac;
+
+        "Component Molar Balance"
+        Inlet.F*Inlet.z = OutletL.F*xsat + OutletV.F*ysat;
+        sum(xsat) = sum(ysat);
+
+        "Energy Balance if saturated"
+        Inlet.F*Inlet.h  + InletQ.Q =
+                Inlet.F*(1-vsat)*PP.LiquidEnthalpy(Tsat, OutletL.P, xsat) +
+                Inlet.F*vsat*PP.VapourEnthalpy(Tsat, OutletV.P, ysat);
+
+        "Real Energy Balance"
+        Inlet.F*Inlet.h  + InletQ.Q =
+                Inlet.F*(1-vfrac)*OutletL.h + Inlet.F*vfrac*OutletV.h;
+
+        "Thermal Equilibrium"
+        OutletV.T = OutletL.T;
+        
+        "Mechanical Equilibrium"
+        OutletV.P = OutletL.P;
+        
+        # regularization functions
+        zero_one = (1 + tanh(B * vsat))/2;
+        one_zero = (1 - tanh(B * (vsat - 1)))/2;
+        
+        vfrac = zero_one * one_zero * vsat + 1 - one_zero;
+        OutletL.z = zero_one*one_zero*xsat + (1-zero_one*one_zero)*Inlet.z;
+        OutletV.z = zero_one*one_zero*ysat + (1-zero_one*one_zero)*Inlet.z;
+end

trunk/eml/streams.mso

@@ -114 +114 @@
 Model source
         ATTRIBUTES
+        Pallete = true;
         Icon = "icon/Source";
         Brief = "Material stream source";
@@ -205 +206 @@
 Model simple_source
         ATTRIBUTES
+        Pallete = true;
         Icon = "icon/Source";
         Brief = "Simple material stream source";
@@ -244 +246 @@
 Model sink
         ATTRIBUTES
+        Pallete = true;
         Icon = "icon/Sink";
         Brief = "Material stream sink";
@@ -319 +322 @@
 Model simple_sink
         ATTRIBUTES
+        Pallete = true;
         Icon = "icon/Sink";
         Brief = "Simple material stream sink";
@@ -345 +349 @@
 Model energy_source
         ATTRIBUTES
+        Pallete = true;
         Icon = "icon/energy_source";
         Brief = "Enegry stream source";