source: trunk/sample/reactors/fogler/chap4/molarflow_pfr.mso @ 961

#*-------------------------------------------------------------------
* EMSO Model Library (EML) Copyright (C) 2004 - 2007 ALSOC.
*
* This LIBRARY is free software; you can distribute it and/or modify
* it under the therms of the ALSOC FREE LICENSE as available at
* http://www.enq.ufrgs.br/alsoc.
*
* EMSO Copyright (C) 2004 - 2007 ALSOC, original code
* from http://www.rps.eng.br Copyright (C) 2002-2004.
* All rights reserved.
*
* EMSO is distributed under the therms of the ALSOC LICENSE as
* available at http://www.enq.ufrgs.br/alsoc.
*
*---------------------------------------------------------------------
* Working with molar flow in a PFR
*----------------------------------------------------------------------
* Solved problem from Fogler (1999)
* Problem number: 4-9
* Page: 160 (Brazilian version, 2002)
*----------------------------------------------------------------------
*
*   Description:
*               Sample to calculate of the molar flows as function of the 
*       volume in a PFR with the reaction:
*                       A <-> 2B
*       
*   Assumptions:
*               * change time in volume
*               * elementary reaction
*       * steady-state
*       * isotermic and isobaric system
*       * gaseous phase
*
*       Specify:
*               * the inlet stream
*               * the kinetic parameters
*
*----------------------------------------------------------------------
* Author: Christiano D. W. Guerra and Rodolfo Rodrigues
* $Id: molarflow_pfr.mso 574 2008-07-25 14:18:50Z rafael $
*--------------------------------------------------------------------*#

using "types";


FlowSheet MF_PFR
        PARAMETERS
        NComp   as Integer;
        ka              as Real                 (Brief="Specific rate of reaction", Unit='1/min');
        Kc              as conc_mol     (Brief="Equilibrium constant");
        
        VARIABLES
    F(NComp)as flow_mol         (Brief="Molar flow", DisplayUnit='mol/min');
        C(NComp)as conc_mol     (Brief="Molar concentration", DisplayUnit='mol/l');
        r(NComp)as reaction_mol (Brief="Reaction rate", DisplayUnit='mol/min/l');
        Fo(NComp) as flow_mol   (Brief="Input molar flow of A", DisplayUnit='mol/min');
    Ft          as flow_mol     (Brief="Total molar flow", DisplayUnit='mol/min');
        Cto     as conc_mol     (Brief="Initial concentration", DisplayUnit='mol/l');
        V               as volume               (Brief="Reactor volume", DisplayUnit='l');
        
        EQUATIONS
        "Change time in V"
        V = time*'l/s';

        "Molar balance"
        diff(F(1))= r(1)*'l/s';
        
        "Reaction rate of A"
        (-r(1)) = ka*(C(1) - C(2)^2/Kc);
        
        "Reaction rate of B"
        r(2) = 2*(-r(1));

        "Molar flow of B"
        F(2) = 2*(Fo(1) - F(1));
        
        "Total molar flow"
        Ft = sum(F);
        
        "Molar concentration"
        C = Cto*F/Ft;
        
        SET
        NComp = 2; # components A and B
        ka = 2.7*'1/min';
        Kc = 1.2*'mol/l';
        
    SPECIFY
        Cto = 0.1*'mol/l';
        
        Fo = [10, 0]*'mol/min';
        
        INITIAL
        "Molar flow of A"
        F(1) = 10*'mol/min';
        
        OPTIONS
        TimeStep = 1;
        TimeEnd = 100;
end