source: trunk/sample/miscellaneous/Sample_Properties.mso

#*-------------------------------------------------------------------
* EMSO Model Library (EML) Copyright (C) 2004 - 2007 ALSOC.
*
* This LIBRARY is free software; you can distribute it and/or modify
* it under the therms of the ALSOC FREE LICENSE as available at
* http://www.enq.ufrgs.br/alsoc.
*
* EMSO Copyright (C) 2004 - 2007 ALSOC, original code
* from http://www.rps.eng.br Copyright (C) 2002-2004.
* All rights reserved.
*
* EMSO is distributed under the therms of the ALSOC LICENSE as
* available at http://www.enq.ufrgs.br/alsoc.
*
*--------------------------------------------------------------------
* Sample file for physical properties
*--------------------------------------------------------------------
* 
* This sample file needs VRTherm DEMO (www.vrtech.com.br) to run.
*
*----------------------------------------------------------------------
* Author: Gerson B. Bicca
* $Id: Sample_Properties.mso 89 2006-12-11 15:26:11Z paula $
*--------------------------------------------------------------------*#

using "streams";

Model Prop
        
VARIABLES

Mu                      as viscosity    (Brief="Stream Viscosity");
Cp                      as cp_mol               (Brief="Stream Molar Heat Capacity");
K                       as conductivity (Brief="Stream Thermal Conductivity");
rho                     as dens_mass    (Brief="Stream Density");       
Fracao      as fraction     (Brief="Stream Fraction");

end

Model propriedades
        
PARAMETERS
outer   NComp as Integer(Brief = "Number of chemical components", Lower = 1); 
outer   PP    as Plugin (Brief = "External Physical Properties",Type="PP");
        
VARIABLES
M(NComp)        as molweight    (Brief="Component Mol Weight");
Stream          as streamPH;
PropLiquido as Prop;
PropVapor   as Prop;

EQUATIONS
"Molecular Weight"
        M   =   PP.MolecularWeight();
        
"Liquid Heat Capacity"
        PropLiquido.Cp  =       PP.LiquidCp(Stream.T,Stream.P,Stream.z);
        
"Vapour Heat Capacity"
        PropVapor.Cp  =   PP.VapourCp(Stream.T,Stream.P,Stream.z);

"Liquid Mass Density"
        PropLiquido.rho =       PP.LiquidDensity(Stream.T,Stream.P,Stream.z);
        
"Vapour Mass Density"
        PropVapor.rho =   PP.VapourDensity(Stream.T,Stream.P,Stream.z);

"Liquid Viscosity"
        PropLiquido.Mu =        PP.LiquidViscosity(Stream.T,Stream.P,Stream.z); 
        
"Vapour Viscosity"      
        PropVapor.Mu =    PP.VapourViscosity(Stream.T,Stream.P,Stream.z);

"Liquid Conductivity"
        PropLiquido.K =         PP.LiquidThermalConductivity(Stream.T,Stream.P,Stream.z); 
        
"Vapour Conductivity"   
        PropVapor.K =     PP.VapourThermalConductivity(Stream.T,Stream.P,Stream.z);
        
"Liquid Fraction"
        PropLiquido.Fracao = 1-PP.VapourFraction(Stream.T,Stream.P,Stream.z);
        
"Vapour Fraction"
        PropVapor.Fracao = PP.VapourFraction(Stream.T,Stream.P,Stream.z);
end


FlowSheet SampleStreams
        
PARAMETERS

PP      as Plugin (Type ="PP", LiquidModel = "PR",VapourModel  = "PR",
                                Components      = ["methanol"]);
        NComp           as Integer;

SET

NComp                   = PP.NumberOfComponents;

DEVICES

Thermo as propriedades;

SPECIFY

        Thermo.Stream.F = 10  * 'kmol/h';
        Thermo.Stream.T = 300 * 'K';
        Thermo.Stream.P = 100 * 'kPa';
        Thermo.Stream.z =  [1];

OPTIONS

        Dynamic = false;
        
end