source: trunk/sample/estimation/sample_estimation.mso @ 996

#****************************************************************
# Simple static parameter estimation.
#
#
# Example 4.2 from "Applied Parameter Estimation for
#                                       Chemical Engineers", Englezos & Kalogerakis
#
# Author: Rafael de Pelegrini Soares
#****************************************************************#

FlowSheet SampleEstimationModel
        VARIABLES
        y as Real;
        x as Real;

        PARAMETERS
        k1 as Real(Default=1.5);
        k2 as Real(Default=1.5);
        k3 as Real(Default=1.5);

        SPECIFY
        x = 1;
        
        EQUATIONS
        y = k1 + k2 * exp(k3*x);
        
        OPTIONS
        Dynamic = false;
end


#
# Expected solution is:
# k = [ 523.305 -156.947 -0.199665 ]
#
Estimation SampleEstimation as SampleEstimationModel

        ESTIMATE
        # PAR   START  LOWER  UPPER  UNIT
        k1      100    0      1000;
        k2      -200   -300   0;
        k3      -1     -10    0;

        EXPERIMENTS
        # FILE                       WEIGTH
        "sample_estimation.dat"      1;

        OPTIONS
        NumJac = false;
        Statistics (
        Parameter = true
        );
        
        NLPSolver(
                File = "ipopt_emso"
                #File = "nmsearch"
                #File = "complex", MaxIterations=1000
        );
        Dynamic = false;
end