source: trunk/eml/reactors/tank_basic.mso @ 417

#*---------------------------------------------------------------------
* EMSO Model Library (EML) Copyright (C) 2004 - 2007 ALSOC.
*
* This LIBRARY is free software; you can distribute it and/or modify
* it under the therms of the ALSOC FREE LICENSE as available at
* http://www.enq.ufrgs.br/alsoc.
*
* EMSO Copyright (C) 2004 - 2007 ALSOC, original code
* from http://www.rps.eng.br Copyright (C) 2002-2004.
* All rights reserved.
*
* EMSO is distributed under the therms of the ALSOC LICENSE as
* available at http://www.enq.ufrgs.br/alsoc.
*
*----------------------------------------------------------------------
* Model of a tank basic
*----------------------------------------------------------------------
*
*
*
*----------------------------------------------------------------------
* Author: Rodolfo Rodrigues
* $Id$
*--------------------------------------------------------------------*#

using "streams";


Model tank_basic
        PARAMETERS
outer PP                as Plugin (Brief="External physical properties", Type="PP");
outer   NComp   as Integer (Brief="Number of components", Default=1);
        
        VARIABLES
in      Inlet   as stream;              # Inlet stream
out     Outletm as stream;              # Intermediary outlet stream

        M(NComp)as mol          (Brief="Component molar holdup");
        Mt              as mol          (Brief="Total component molar holdup");
        V               as volume       (Brief="Volume of reactional mixture");
        E               as energy       (Brief="Internal energy");
        Q               as heat_rate(Brief="Reactor duty", Default=0);
        
        Across  as area         (Brief="Tank cross section area");
        Level   as length       (Brief="Tank level");
        
        EQUATIONS
        "Component molar balance"
        diff(M) = Inlet.F*Inlet.z - Outletm.F*Outletm.z;
        
        "Component molar"
        M = Mt*Outletm.z;
        
        "Mole fraction normalisation"
        sum(Outletm.z) = 1.0;
        
        "Energy balance"
        diff(E) = Inlet.F*Inlet.h - Outletm.F*Outletm.h + Q;
        
        "Geometry"
        V = Across*Level;
end


#*---------------------------------------------------------------------
*       only liquid phase
*--------------------------------------------------------------------*#

Model tank_liq as tank_basic
        EQUATIONS
        "Vapourisation fraction"
        Outletm.v = 0.0;

        "Liquid Enthalpy"
        Outletm.h = PP.LiquidEnthalpy(Outletm.T,Outletm.P,Outletm.z);
        
        "Volume constraint"
        V = Mt*PP.LiquidVolume(Outletm.T,Outletm.P,Outletm.z);
        
        "Total internal energy"
        E = Mt*Outletm.h - Outletm.P*V;
end


#*---------------------------------------------------------------------
*       only vapour phase
*--------------------------------------------------------------------*#

Model tank_vap as tank_basic
        EQUATIONS
        "Vapourisation fraction"
        Outletm.v = 1.0;

        "Vapour Enthalpy"
        Outletm.h = PP.VapourEnthalpy(Outletm.T,Outletm.P,Outletm.z);

        "Volume constraint"
        V = Mt*PP.VapourVolume(Outletm.T,Outletm.P,Outletm.z);

        "Total internal energy"
        E = Mt*Outletm.h;
end


#*---------------------------------------------------------------------
*       liquid and vapour phases
*--------------------------------------------------------------------*#

Model tank_liqvap
        PARAMETERS
outer PP                as Plugin(Brief="External physical properties", Type="PP");
outer NComp     as Integer      (Brief="Number of components", Default=1);

        VARIABLES
in      Inlet    as stream;                     # Inlet stream
out     OutletmL as liquid_stream;      # Intermediary liquid outlet stream
out     OutletV  as vapour_stream;      # Outlet vapour stream

        M(NComp)as mol                  (Brief="Component molar holdup");
        ML              as mol                  (Brief="Molar liquid holdup");
        MV              as mol                  (Brief="Molar vapour holdup");
        V               as volume               (Brief="Volume of reactional mixture");
        E               as energy               (Brief="Internal energy");
        Q               as heat_rate    (Brief="Reactor duty", Default=0);
        vL              as volume_mol   (Brief="Liquid Molar Volume");
        
        Across  as area                 (Brief="Tank cross section area");
        Level   as length               (Brief="Tank level");
        
        EQUATIONS
        "Component molar balance"
        diff(M) = Inlet.F*Inlet.z - (OutletmL.F*OutletmL.z + OutletV.F*OutletV.z);

        "Molar holdup"
        M = ML*OutletmL.z + MV*OutletV.z;
        
        
        "Mole fraction normalisation"
        sum(OutletmL.z) = 1.0;
        
        "Mole fraction normalisation"
        sum(OutletmL.z) = sum(OutletV.z);
        
        
        "Vapourisation fraction"
        OutletV.v = 1.0;
        
        "Vapourisation fraction"
        OutletmL.v = 0.0;
        
        
        "Energy balance"
        diff(E) = Inlet.F*Inlet.h - (OutletmL.F*OutletmL.h + OutletV.F*OutletV.h) + Q;
        
        "Total internal energy"
        E = ML*OutletmL.h + MV*OutletV.h; #- OutletmL.P*V; P_tank*V_tank
        
        "Geometry constraint"
        V = ML*vL + MV*PP.VapourVolume(OutletV.T,OutletV.P,OutletV.z);
        
        
        "Chemical Equilibrium"
        PP.LiquidFugacityCoefficient(OutletmL.T,OutletmL.P,OutletmL.z)*OutletmL.z = 
                PP.VapourFugacityCoefficient(OutletV.T,OutletV.P,OutletV.z)*OutletV.z;
        
        "Mechanical Equilibrium"
        OutletmL.P = OutletV.P;
        
        "Thermal Equilibrium"
        OutletmL.T = OutletV.T;
        
        "Liquid Volume"
        vL = PP.LiquidVolume(OutletmL.T,OutletmL.P,OutletmL.z);
        
        "Tank Level"
        ML*vL = Across*Level;
end