source: mso/sample/reactors/fogler/chap4/molarflow_pfr.mso @ 63

Last change on this file since 63 was 63, checked in by Rodolfo Rodrigues, 16 years ago

Added more samples

File size: 2.3 KB
Line 
1#*---------------------------------------------------------------------
2* Working with molar flow in a PFR
3*----------------------------------------------------------------------
4* Solved problem from Fogler (1999)
5* Problem number: 4-9
6* Page: 160 (Brazilian version, 2002)
7*----------------------------------------------------------------------
8*
9*   Description:
10*               Sample to calculate of the molar flows as function of the
11*       volume in a PFR with the reaction:
12*                       A <-> 2B
13*       
14*   Assumptions:
15*               * change time in volume
16*               * elementary reaction
17*       * steady-state
18*       * isotermic and isobaric system
19*       * gaseous phase
20*
21*       Specify:
22*               * the inlet stream
23*               * the kinetic parameters
24*
25*----------------------------------------------------------------------
26* Author: Christiano D. W. Guerra and Rodolfo Rodrigues
27* GIMSCOP/UFRGS - Group of Integration, Modeling, Simulation, Control,
28*                                       and Optimization of Processes
29* $Id$
30*--------------------------------------------------------------------*#
31
32using "types";
33
34
35FlowSheet MF_PFR
36        PARAMETERS
37        NComp   as Integer;
38        ka              as Real                 (Brief="Specific rate of reaction", Unit="1/min");
39        Kc              as conc_mol     (Brief="Equilibrium constant");
40       
41        VARIABLES
42    F(NComp)as flow_mol         (Brief="Molar flow", Unit="mol/min");
43        C(NComp)as conc_mol     (Brief="Molar concentration", Unit="mol/l");
44        r(NComp)as reaction_mol (Brief="Reaction rate", Unit="mol/min/l");
45        Fo(NComp) as flow_mol   (Brief="Input molar flow of A", Unit="mol/min");
46    Ft          as flow_mol     (Brief="Total molar flow", Unit="mol/min");
47        Cto     as conc_mol     (Brief="Initial concentration", Unit="mol/l");
48        V               as volume               (Brief="Reactor volume", Unit="l");
49       
50        EQUATIONS
51        "Change time in V"
52        V = time*"l/s";
53
54        "Molar balance"
55        diff(F(1))= r(1)*"l/s";
56       
57        "Reaction rate of A"
58        (-r(1)) = ka*(C(1) - C(2)^2/Kc);
59       
60        "Reaction rate of B"
61        r(2) = 2*(-r(1));
62
63        "Molar flow of B"
64        F(2) = 2*(Fo(1) - F(1));
65       
66        "Total molar flow"
67        Ft = sum(F);
68       
69        "Molar concentration"
70        C = Cto*F/Ft;
71       
72        SET
73        NComp = 2; # components A and B
74        ka = 2.7*"1/min";
75        Kc = 1.2*"mol/l";
76       
77    SPECIFY
78        "Input total molar concentration"
79        Cto = 0.1*"mol/l";
80       
81        "Input molar flow"
82        Fo = [10, 0]*"mol/min";
83       
84        INITIAL
85        "Molar flow of A"
86        F(1) = 10*"mol/min";
87       
88        OPTIONS
89        time=[0:1:100];
90        DAESolver = "dassl";
91end
Note: See TracBrowser for help on using the repository browser.