source: branches/packed/eml/heat_exchangers/DoublePipe.mso @ 448

Last change on this file since 448 was 420, checked in by gerson bicca, 16 years ago

REMOVED SOME VARIABLES

  • Property svn:keywords set to Id
File size: 46.4 KB
Line 
1#*-------------------------------------------------------------------
2* EMSO Model Library (EML) Copyright (C) 2004 - 2007 ALSOC.
3*
4* This LIBRARY is free software; you can distribute it and/or modify
5* it under the therms of the ALSOC FREE LICENSE as available at
6* http://www.enq.ufrgs.br/alsoc.
7*
8* EMSO Copyright (C) 2004 - 2007 ALSOC, original code
9* from http://www.rps.eng.br Copyright (C) 2002-2004.
10* All rights reserved.
11*
12* EMSO is distributed under the therms of the ALSOC LICENSE as
13* available at http://www.enq.ufrgs.br/alsoc.
14*--------------------------------------------------------------------
15* Author: Gerson Balbueno Bicca
16* $Id: DoublePipe.mso 420 2007-11-26 22:43:17Z bicca $
17*------------------------------------------------------------------*#
18
19using "HEX_Engine";
20
21
22Model DoublePipe_Basic
23
24ATTRIBUTES
25        Pallete         = false;
26        Brief           = "Basic Equations for rigorous double pipe heat exchanger model.";
27        Info            =
28        "to be documented.";
29
30PARAMETERS
31
32outer PP            as Plugin           (Brief="External Physical Properties", Type="PP");
33outer NComp     as Integer      (Brief="Number of Components");
34       
35        M(NComp)        as molweight    (Brief="Component Mol Weight");
36       
37        HotSide                         as Switcher             (Brief="Flag for Fluid Alocation ",Valid=["outer","inner"],Default="outer");
38        innerFlowRegime         as Switcher     (Brief="Inner Flow Regime ",Valid=["laminar","transition","turbulent"],Default="laminar");
39        outerFlowRegime         as Switcher     (Brief="Outer Flow Regime ",Valid=["laminar","transition","turbulent"],Default="laminar");
40
41        InnerLaminarCorrelation         as Switcher     (Brief="Heat Transfer Correlation in Laminar Flow for the Inner Side",Valid=["Hausen","Schlunder"],Default="Hausen");
42        InnerTransitionCorrelation  as Switcher         (Brief="Heat Transfer Correlation in Transition Flow for the Inner Side",Valid=["Gnielinski","Hausen"],Default="Gnielinski");
43        InnerTurbulentCorrelation   as Switcher (Brief="Heat Transfer Correlation in Turbulent Flow for the Inner Side",Valid=["Petukhov","SiederTate"],Default="Petukhov");
44
45        OuterLaminarCorrelation         as Switcher             (Brief="Heat Transfer Correlation in Laminar Flow for the Outer Side",Valid=["Hausen","Schlunder"],Default="Hausen");
46        OuterTransitionCorrelation  as Switcher         (Brief="Heat Transfer Correlation in Transition Flow for the OuterSide",Valid=["Gnielinski","Hausen"],Default="Gnielinski");
47        OuterTurbulentCorrelation   as Switcher         (Brief="Heat Transfer Correlation in Turbulent Flow for the Outer Side",Valid=["Petukhov","SiederTate"],Default="Petukhov");
48
49        Pi                              as constant             (Brief="Pi Number",Default=3.14159265, Symbol = "\pi");
50        DoInner         as length                       (Brief="Outside Diameter of Inner Pipe",Lower=1e-6);
51        DiInner as length                       (Brief="Inside Diameter of Inner Pipe",Lower=1e-10);
52        DiOuter as length                       (Brief="Inside Diameter of Outer pipe",Lower=1e-10);
53        Lpipe           as length                       (Brief="Effective Tube Length of one segment of Pipe",Lower=0.1, Symbol = "L_{pipe}");
54        Kwall           as conductivity         (Brief="Tube Wall Material Thermal Conductivity",Default=1.0, Symbol = "K_{wall}");
55        Rfi                     as positive                     (Brief="Inside Fouling Resistance",Unit='m^2*K/kW',Default=1e-6,Lower=0);
56        Rfo                     as positive                     (Brief="Outside Fouling Resistance",Unit='m^2*K/kW',Default=1e-6,Lower=0);
57
58VARIABLES
59
60in  InletInner          as stream               (Brief="Inlet Inner Stream", PosX=0, PosY=0.5225, Symbol="_{inInner}");
61in  InletOuter          as stream               (Brief="Inlet Outer Stream", PosX=0.2805, PosY=0, Symbol="_{inOuter}");
62out OutletInner         as streamPH     (Brief="Outlet Inner Stream", PosX=1, PosY=0.5225, Symbol="_{outInner}");
63out OutletOuter         as streamPH     (Brief="Outlet Outer Stream", PosX=0.7264, PosY=1, Symbol="_{outOuter}");
64
65        Details         as Details_Main         (Brief="Some Details in the Heat Exchanger", Symbol=" ");
66        Inner                   as Main_DoublePipe      (Brief="Inner Side of the Heat Exchanger", Symbol="_{Inner}");
67        Outer                   as Main_DoublePipe      (Brief="Outer Side of the Heat Exchanger", Symbol="_{Outer}");
68
69SET
70
71#"Component Molecular Weight"
72        M  = PP.MolecularWeight();
73       
74#"Pi Number"
75        Pi      = 3.14159265;
76       
77#"Inner Pipe Cross Sectional Area for Flow"
78        Inner.HeatTransfer.As=Pi*DiInner*DiInner/4;
79       
80#"Outer Pipe Cross Sectional Area for Flow"
81        Outer.HeatTransfer.As=Pi*(DiOuter*DiOuter - DoInner*DoInner)/4;
82       
83#"Inner Pipe Hydraulic Diameter for Heat Transfer"
84        Inner.HeatTransfer.Dh=DiInner;
85       
86#"Outer Pipe Hydraulic Diameter for Heat Transfer"
87        Outer.HeatTransfer.Dh=(DiOuter*DiOuter-DoInner*DoInner)/DoInner;
88
89#"Inner Pipe Hydraulic Diameter for Pressure Drop"
90        Inner.PressureDrop.Dh=DiInner;
91       
92#"Outer Pipe Hydraulic Diameter for Pressure Drop"
93        Outer.PressureDrop.Dh=DiOuter-DoInner;
94
95EQUATIONS
96
97"Outer  Stream Average Temperature"
98        Outer.Properties.Average.T = 0.5*InletOuter.T + 0.5*OutletOuter.T;
99
100"Inner Stream Average Temperature"
101        Inner.Properties.Average.T = 0.5*InletInner.T + 0.5*OutletInner.T;
102       
103"Outer Stream Average Pressure"
104        Outer.Properties.Average.P = 0.5*InletOuter.P+0.5*OutletOuter.P;
105       
106"Inner Stream Average Pressure"
107        Inner.Properties.Average.P = 0.5*InletInner.P+0.5*OutletInner.P;
108
109"Inner Stream Wall Temperature"
110        Inner.Properties.Wall.Twall =   0.5*Outer.Properties.Average.T + 0.5*Inner.Properties.Average.T;
111
112"Outer Stream Wall Temperature"
113        Outer.Properties.Wall.Twall =   0.5*Outer.Properties.Average.T + 0.5*Inner.Properties.Average.T;
114
115"Outer Stream Average Molecular Weight"
116        Outer.Properties.Average.Mw = sum(M*InletOuter.z);
117
118"Inner Stream Average Molecular Weight"
119        Inner.Properties.Average.Mw = sum(M*InletInner.z);
120
121if InletInner.v equal 0
122       
123        then   
124
125"Average Heat Capacity Inner Stream"
126        Inner.Properties.Average.Cp             =       PP.LiquidCp(Inner.Properties.Average.T,Inner.Properties.Average.P,InletInner.z);
127
128"Average Mass Density Inner Stream"
129        Inner.Properties.Average.rho    =       PP.LiquidDensity(Inner.Properties.Average.T,Inner.Properties.Average.P,InletInner.z);
130
131"Inlet Mass Density Inner Stream"
132        Inner.Properties.Inlet.rho              =       PP.LiquidDensity(InletInner.T,InletInner.P,InletInner.z);
133
134"Outlet Mass Density Inner Stream"
135        Inner.Properties.Outlet.rho     =       PP.LiquidDensity(OutletInner.T,OutletInner.P,OutletInner.z);
136
137"Average Viscosity Inner Stream"
138        Inner.Properties.Average.Mu     =       PP.LiquidViscosity(Inner.Properties.Average.T,Inner.Properties.Average.P,InletInner.z);
139
140"Average        Conductivity Inner Stream"
141        Inner.Properties.Average.K              =       PP.LiquidThermalConductivity(Inner.Properties.Average.T,Inner.Properties.Average.P,InletInner.z);
142
143"Viscosity Inner Stream at wall temperature"
144        Inner.Properties.Wall.Mu                =       PP.LiquidViscosity(Inner.Properties.Wall.Twall,Inner.Properties.Average.P,InletInner.z);
145
146        else
147
148"Average Heat Capacity InnerStream"
149        Inner.Properties.Average.Cp     =       PP.VapourCp(Inner.Properties.Average.T,Inner.Properties.Average.P,InletInner.z);
150
151"Average Mass Density Inner Stream"
152        Inner.Properties.Average.rho    =       PP.VapourDensity(Inner.Properties.Average.T,Inner.Properties.Average.P,InletInner.z);
153
154"Inlet Mass Density Inner Stream"
155        Inner.Properties.Inlet.rho              =       PP.VapourDensity(InletInner.T,InletInner.P,InletInner.z);
156       
157"Outlet Mass Density Inner Stream"
158        Inner.Properties.Outlet.rho     =       PP.VapourDensity(OutletInner.T,OutletInner.P,OutletInner.z);
159
160"Average Viscosity Inner Stream"
161        Inner.Properties.Average.Mu     =       PP.VapourViscosity(Inner.Properties.Average.T,Inner.Properties.Average.P,InletInner.z);
162
163"Average Conductivity Inner Stream"
164        Inner.Properties.Average.K              =       PP.VapourThermalConductivity(Inner.Properties.Average.T,Inner.Properties.Average.P,InletInner.z);
165
166"Viscosity Inner Stream at wall temperature"
167        Inner.Properties.Wall.Mu                =       PP.VapourViscosity(Inner.Properties.Wall.Twall,Inner.Properties.Average.P,InletInner.z);
168
169end
170
171if InletOuter.v equal 0
172
173        then
174
175"Average Heat Capacity Outer Stream"
176        Outer.Properties.Average.Cp     =               PP.LiquidCp(Outer.Properties.Average.T,Outer.Properties.Average.P,InletOuter.z);
177
178"Average Mass Density Outer Stream"
179        Outer.Properties.Average.rho =          PP.LiquidDensity(Outer.Properties.Average.T,Outer.Properties.Average.P,InletOuter.z);
180
181"Inlet Mass Density Outer Stream"
182        Outer.Properties.Inlet.rho              =               PP.LiquidDensity(InletOuter.T,InletOuter.P,InletOuter.z);
183
184"Outlet Mass Density Outer Stream"
185        Outer.Properties.Outlet.rho     =               PP.LiquidDensity(OutletOuter.T,OutletOuter.P,OutletOuter.z);
186
187"Average Viscosity Outer Stream"
188        Outer.Properties.Average.Mu     =               PP.LiquidViscosity(Outer.Properties.Average.T,Outer.Properties.Average.P,InletOuter.z);
189
190"Average Conductivity Outer Stream"
191        Outer.Properties.Average.K      =               PP.LiquidThermalConductivity(Outer.Properties.Average.T,Outer.Properties.Average.P,InletOuter.z);       
192
193"Viscosity Outer Stream at wall temperature"
194        Outer.Properties.Wall.Mu                =               PP.LiquidViscosity(Outer.Properties.Wall.Twall,Outer.Properties.Average.P,InletOuter.z);       
195
196
197        else
198
199"Average Heat Capacity Outer Stream"
200        Outer.Properties.Average.Cp     =               PP.VapourCp(Outer.Properties.Average.T,Outer.Properties.Average.P,InletOuter.z);
201
202"Average Mass Density Outer Stream"
203        Outer.Properties.Average.rho =          PP.VapourDensity(Outer.Properties.Average.T,Outer.Properties.Average.P,InletOuter.z);
204
205"Inlet Mass Density Outer Stream"
206        Outer.Properties.Inlet.rho              =               PP.VapourDensity(InletOuter.T,InletOuter.P,InletOuter.z);
207       
208"Outlet Mass Density Outer Stream"
209        Outer.Properties.Outlet.rho     =               PP.VapourDensity(OutletOuter.T,OutletOuter.P,OutletOuter.z);
210
211"Average Viscosity Outer Stream"
212        Outer.Properties.Average.Mu     =               PP.VapourViscosity(Outer.Properties.Average.T,Outer.Properties.Average.P,InletOuter.z);
213
214"Average Conductivity Outer Stream"
215        Outer.Properties.Average.K      =               PP.VapourThermalConductivity(Outer.Properties.Average.T,Outer.Properties.Average.P,InletOuter.z);       
216
217"Viscosity Outer Stream at wall temperature"
218        Outer.Properties.Wall.Mu                =               PP.VapourViscosity(Outer.Properties.Wall.Twall,Outer.Properties.Average.P,InletOuter.z);
219
220end
221
222switch HotSide
223       
224        case "outer":
225
226"Energy Balance Outer Stream"
227        Details.Q = InletOuter.F*(InletOuter.h-OutletOuter.h);
228
229"Energy Balance Inner Stream"
230        Details.Q = InletInner.F*(OutletInner.h-InletInner.h);
231
232        when InletInner.T > InletOuter.T switchto "inner";
233
234case "inner":
235
236"Energy Balance Hot Stream"
237        Details.Q = InletInner.F*(InletInner.h-OutletInner.h);
238
239"Energy Balance Cold Stream"
240        Details.Q = InletOuter.F*(OutletOuter.h - InletOuter.h);
241
242        when InletInner.T < InletOuter.T switchto "outer";
243
244end
245
246"Flow Mass Inlet Inner Stream"
247        Inner.Properties.Inlet.Fw       =  sum(M*InletInner.z)*InletInner.F;
248
249"Flow Mass Outlet Inner Stream"
250        Inner.Properties.Outlet.Fw      =  sum(M*OutletInner.z)*OutletInner.F;
251
252"Flow Mass Inlet Outer Stream"
253        Outer.Properties.Inlet.Fw               =  sum(M*InletOuter.z)*InletOuter.F;
254
255"Flow Mass Outlet Outer Stream"
256        Outer.Properties.Outlet.Fw      =  sum(M*OutletOuter.z)*OutletOuter.F;
257
258"Molar Balance Outer Stream"
259        OutletOuter.F = InletOuter.F;
260       
261"Molar Balance Inner Stream"
262        OutletInner.F = InletInner.F;
263
264"Outer Stream Molar Fraction Constraint"
265        OutletOuter.z=InletOuter.z;
266       
267"InnerStream Molar Fraction Constraint"
268        OutletInner.z=InletInner.z;
269
270"Exchange Surface Area for one segment of pipe"
271        Details.A=Pi*DoInner*Lpipe;
272
273switch innerFlowRegime
274       
275        case "laminar":
276       
277"Inner Side Friction Factor for Pressure Drop - laminar Flow"
278        Inner.PressureDrop.fi*Inner.PressureDrop.Re = 16;
279       
280        when Inner.PressureDrop.Re > 2300 switchto "transition";
281
282        case "transition":
283       
284"using Turbulent Flow - to be implemented"
285        (Inner.PressureDrop.fi-0.0035)*(Inner.PressureDrop.Re^0.42) = 0.264;
286
287        when Inner.PressureDrop.Re < 2300 switchto "laminar";
288        when Inner.PressureDrop.Re > 10000 switchto "turbulent";
289
290        case "turbulent":
291
292"Inner Side Friction Factor - Turbulent Flow"
293        (Inner.PressureDrop.fi-0.0035)*(Inner.PressureDrop.Re^0.42) = 0.264;
294
295        when Inner.PressureDrop.Re < 10000 switchto "transition";
296       
297end     
298
299switch outerFlowRegime
300       
301        case "laminar":
302       
303"Outer Side Friction Factor - laminar Flow"
304        Outer.PressureDrop.fi*Outer.PressureDrop.Re = 16;
305       
306        when Outer.PressureDrop.Re > 2300 switchto "transition";
307
308        case "transition":
309       
310"using Turbulent Flow - Transition Flow must be implemented"
311        (Outer.PressureDrop.fi-0.0035)*(Outer.PressureDrop.Re^0.42) = 0.264;
312
313        when Outer.PressureDrop.Re < 2300 switchto "laminar";
314        when Outer.PressureDrop.Re > 10000 switchto "turbulent";
315
316        case "turbulent":
317
318"Outer Side Friction Factor - Turbulent Flow"
319        (Outer.PressureDrop.fi-0.0035)*(Outer.PressureDrop.Re^0.42) = 0.264;
320
321        when Outer.PressureDrop.Re < 10000 switchto "transition";
322       
323end
324
325switch innerFlowRegime
326       
327        case "laminar":
328       
329"Inner Side Friction Factor for Heat Transfer - laminar Flow"
330        Inner.HeatTransfer.fi   = 1/(0.79*ln(Inner.HeatTransfer.Re)-1.64)^2;
331       
332switch InnerLaminarCorrelation
333       
334        case "Hausen":
335
336"Nusselt Number"
337        Inner.HeatTransfer.Nu = 3.665 + ((0.19*((DiInner/Lpipe)*Inner.HeatTransfer.Re*Inner.HeatTransfer.PR)^0.8)/(1+0.117*((DiInner/Lpipe)*Inner.HeatTransfer.Re*Inner.HeatTransfer.PR)^0.467));
338       
339        case "Schlunder":
340
341"Nusselt Number"
342        Inner.HeatTransfer.Nu = (49.027896+4.173281*Inner.HeatTransfer.Re*Inner.HeatTransfer.PR*(DiInner/Lpipe))^(1/3);
343
344end
345       
346        when Inner.HeatTransfer.Re > 2300 switchto "transition";
347       
348        case "transition":
349       
350"Inner Side Friction Factor for Heat Transfer - transition Flow"
351        Inner.HeatTransfer.fi   = 1/(0.79*ln(Inner.HeatTransfer.Re)-1.64)^2;
352       
353switch InnerTransitionCorrelation
354       
355        case "Gnielinski":
356       
357"Nusselt Number"
358        Inner.HeatTransfer.Nu*(1+(12.7*sqrt(0.125*Inner.HeatTransfer.fi)*((Inner.HeatTransfer.PR)^(2/3) -1))) = 0.125*Inner.HeatTransfer.fi*(Inner.HeatTransfer.Re-1000)*Inner.HeatTransfer.PR;
359
360        case "Hausen":
361
362"Nusselt Number"
363        Inner.HeatTransfer.Nu =0.116*(Inner.HeatTransfer.Re^(0.667)-125)*Inner.HeatTransfer.PR^(0.333)*(1+(DiInner/Lpipe)^0.667);
364       
365end
366
367        when Inner.HeatTransfer.Re < 2300 switchto "laminar";
368        when Inner.HeatTransfer.Re > 10000 switchto "turbulent";
369
370        case "turbulent":
371
372switch InnerTurbulentCorrelation
373       
374        case "Petukhov":
375       
376"Inner Side Friction Factor for Heat Transfer - turbulent Flow"
377        Inner.HeatTransfer.fi   = 1/(1.82*log(Inner.HeatTransfer.Re)-1.64)^2;
378
379"Nusselt Number"
380        Inner.HeatTransfer.Nu*(1.07+(12.7*sqrt(0.125*Inner.HeatTransfer.fi)*((Inner.HeatTransfer.PR)^(2/3) -1))) = 0.125*Inner.HeatTransfer.fi*Inner.HeatTransfer.Re*Inner.HeatTransfer.PR;
381       
382        case "SiederTate":
383
384"Nusselt Number"
385        Inner.HeatTransfer.Nu = 0.027*(Inner.HeatTransfer.PR)^(1/3)*(Inner.HeatTransfer.Re)^(4/5);
386
387"Inner Side Friction Factor for Heat Transfer - turbulent Flow"
388        Inner.HeatTransfer.fi   = 1/(1.82*log(Inner.HeatTransfer.Re)-1.64)^2;
389       
390end
391       
392        when Inner.HeatTransfer.Re < 10000 switchto "transition";
393       
394end
395
396switch outerFlowRegime
397       
398        case "laminar":
399       
400"Outer Side Friction Factor for Heat Transfer - laminar Flow"
401        Outer.HeatTransfer.fi   = 1/(0.79*ln(Outer.HeatTransfer.Re)-1.64)^2;
402       
403switch OuterLaminarCorrelation
404       
405        case "Hausen":
406
407"Nusselt Number"
408        Outer.HeatTransfer.Nu = 3.665 + ((0.19*((Outer.HeatTransfer.Dh/Lpipe)*Outer.HeatTransfer.Re*Outer.HeatTransfer.PR)^0.8)/(1+0.117*((Outer.HeatTransfer.Dh/Lpipe)*Outer.HeatTransfer.Re*Outer.HeatTransfer.PR)^0.467));
409       
410        case "Schlunder":
411
412"Nusselt Number"
413        Outer.HeatTransfer.Nu = (49.027896+4.173281*Outer.HeatTransfer.Re*Outer.HeatTransfer.PR*(Outer.HeatTransfer.Dh/Lpipe))^(1/3);
414
415end
416       
417        when Outer.HeatTransfer.Re > 2300 switchto "transition";
418       
419        case "transition":
420       
421switch OuterTransitionCorrelation
422       
423        case "Gnielinski":
424
425"Outer Side Friction Factor for Heat Transfer - transition Flow"
426        Outer.HeatTransfer.fi   = 1/(0.79*ln(Outer.HeatTransfer.Re)-1.64)^2;
427
428"Nusselt Number"
429        Outer.HeatTransfer.Nu*(1+(12.7*sqrt(0.125*Outer.HeatTransfer.fi)*((Outer.HeatTransfer.PR)^(2/3) -1))) = 0.125*Outer.HeatTransfer.fi*(Outer.HeatTransfer.Re-1000)*Outer.HeatTransfer.PR;
430
431        case "Hausen":
432
433"Nusselt Number"
434        Outer.HeatTransfer.Nu = 0.116*(Outer.HeatTransfer.Re^(0.667)-125)*Outer.HeatTransfer.PR^(0.333)*(1+(Outer.HeatTransfer.Dh/Lpipe)^0.667);
435
436
437"Outer Side Friction Factor for Heat Transfer - transition Flow"
438        Outer.HeatTransfer.fi   = 1/(0.79*ln(Outer.HeatTransfer.Re)-1.64)^2;
439       
440end
441       
442        when Outer.HeatTransfer.Re < 2300 switchto "laminar";
443        when Outer.HeatTransfer.Re > 10000 switchto "turbulent";
444       
445        case "turbulent":
446       
447switch OuterTurbulentCorrelation
448       
449        case "Petukhov":
450
451"Outer Side Friction Factor for Heat Transfer - turbulent Flow"
452        Outer.HeatTransfer.fi   = 1/(1.82*log(Outer.HeatTransfer.Re)-1.64)^2;
453       
454"Nusselt Number"
455        Outer.HeatTransfer.Nu*(1.07+(12.7*sqrt(0.125*Outer.HeatTransfer.fi)*((Outer.HeatTransfer.PR)^(2/3) -1))) = 0.125*Outer.HeatTransfer.fi*Outer.HeatTransfer.Re*Outer.HeatTransfer.PR;
456       
457        case "SiederTate":
458
459"Nusselt Number"
460        Outer.HeatTransfer.Nu = 0.027*(Outer.HeatTransfer.PR)^(1/3)*(Outer.HeatTransfer.Re)^(4/5);
461
462"Outer Side Friction Factor for Heat Transfer - turbulent Flow"
463        Outer.HeatTransfer.fi   = 1/(1.82*log(Outer.HeatTransfer.Re)-1.64)^2;
464       
465end
466
467        when Outer.HeatTransfer.Re < 10000 switchto "transition";
468
469end
470
471"Inner Pipe Film Coefficient"
472        Inner.HeatTransfer.hcoeff = (Inner.HeatTransfer.Nu*Inner.Properties.Average.K/DiInner)*Inner.HeatTransfer.Phi;
473
474"Outer Pipe Film Coefficient"
475        Outer.HeatTransfer.hcoeff= (Outer.HeatTransfer.Nu*Outer.Properties.Average.K/Outer.HeatTransfer.Dh)*Outer.HeatTransfer.Phi;
476
477"Total Pressure Drop Outer Stream"
478        Outer.PressureDrop.Pdrop  = Outer.PressureDrop.Pd_fric+Outer.PressureDrop.Pd_ret;
479
480"Total Pressure Drop Inner Stream"
481        Inner.PressureDrop.Pdrop  = Inner.PressureDrop.Pd_fric+Inner.PressureDrop.Pd_ret;
482       
483"Pressure Drop Outer Stream"
484        OutletOuter.P  = InletOuter.P - Outer.PressureDrop.Pdrop;
485
486"Pressure Drop Inner Stream"
487        OutletInner.P  = InletInner.P - Inner.PressureDrop.Pdrop;
488       
489"Outer Pipe Pressure Drop for friction"
490        Outer.PressureDrop.Pd_fric = (2*Outer.PressureDrop.fi*Lpipe*Outer.Properties.Average.rho*Outer.HeatTransfer.Vmean^2)/(Outer.PressureDrop.Dh*Outer.HeatTransfer.Phi);
491       
492"Inner Pipe Pressure Drop for friction"
493        Inner.PressureDrop.Pd_fric = (2*Inner.PressureDrop.fi*Lpipe*Inner.Properties.Average.rho*Inner.HeatTransfer.Vmean^2)/(DiInner*Inner.HeatTransfer.Phi);
494
495"Outer Pipe Pressure Drop due to return"
496        Outer.PressureDrop.Pd_ret = 0*'kPa';
497
498"Inner Pipe Pressure Drop due to return"
499        Inner.PressureDrop.Pd_ret = 0*'kPa';
500
501"Outer Pipe Phi correction"
502        Outer.HeatTransfer.Phi = (Outer.Properties.Average.Mu/Outer.Properties.Wall.Mu)^0.14;
503       
504"Inner Pipe Phi correction"
505        Inner.HeatTransfer.Phi  = (Inner.Properties.Average.Mu/Inner.Properties.Wall.Mu)^0.14;
506
507"Outer Pipe Prandtl Number"
508        Outer.HeatTransfer.PR = ((Outer.Properties.Average.Cp/Outer.Properties.Average.Mw)*Outer.Properties.Average.Mu)/Outer.Properties.Average.K;
509
510"Inner Pipe Prandtl Number"
511        Inner.HeatTransfer.PR = ((Inner.Properties.Average.Cp/Inner.Properties.Average.Mw)*Inner.Properties.Average.Mu)/Inner.Properties.Average.K;
512
513"Outer Pipe Reynolds Number for Heat Transfer"
514        Outer.HeatTransfer.Re = (Outer.Properties.Average.rho*Outer.HeatTransfer.Vmean*Outer.HeatTransfer.Dh)/Outer.Properties.Average.Mu;
515
516"Outer Pipe Reynolds Number for Pressure Drop"
517        Outer.PressureDrop.Re = (Outer.Properties.Average.rho*Outer.HeatTransfer.Vmean*Outer.PressureDrop.Dh)/Outer.Properties.Average.Mu;
518
519"Inner Pipe Reynolds Number for Heat Transfer"
520        Inner.HeatTransfer.Re = (Inner.Properties.Average.rho*Inner.HeatTransfer.Vmean*Inner.HeatTransfer.Dh)/Inner.Properties.Average.Mu;
521
522"Inner Pipe Reynolds Number for Pressure Drop"
523        Inner.PressureDrop.Re = Inner.HeatTransfer.Re;
524
525"Outer Pipe Velocity"
526        Outer.HeatTransfer.Vmean*(Outer.HeatTransfer.As*Outer.Properties.Average.rho)  = Outer.Properties.Inlet.Fw;
527
528"Inner Pipe Velocity"
529        Inner.HeatTransfer.Vmean*(Inner.HeatTransfer.As*Inner.Properties.Average.rho)  = Inner.Properties.Inlet.Fw;
530
531"Overall Heat Transfer Coefficient Clean"
532        Details.Uc*((DoInner/(Inner.HeatTransfer.hcoeff*DiInner) )+(DoInner*ln(DoInner/DiInner)/(2*Kwall))+(1/(Outer.HeatTransfer.hcoeff)))=1;
533
534"Overall Heat Transfer Coefficient Dirty"
535        Details.Ud*(Rfi*(DoInner/DiInner) +  Rfo + (DoInner/(Inner.HeatTransfer.hcoeff*DiInner) )+(DoInner*ln(DoInner/DiInner)/(2*Kwall))+(1/(Outer.HeatTransfer.hcoeff)))=1;
536
537end
538
539Model DoublePipe_NTU as DoublePipe_Basic
540
541ATTRIBUTES
542
543        Icon = "icon/DoublePipe";
544        Pallete = true;
545        Brief  = "Double Pipe Heat Exchanger - NTU Method";
546        Info  =
547        "to be documented.";
548
549PARAMETERS
550
551FlowDirection   as Switcher     (Brief="Flow Direction",Valid=["counter","cocurrent"],Default="cocurrent");
552       
553VARIABLES
554
555Method as NTU_Basic     (Brief="NTU Method of Calculation", Symbol=" ");
556
557EQUATIONS
558
559"Number of Units Transference"
560        Method.NTU*Method.Cmin = Details.Ud*Pi*DoInner*Lpipe;
561       
562"Minimum Heat Capacity"
563        Method.Cmin  = min([Method.Ch,Method.Cc]);
564
565"Maximum Heat Capacity"
566        Method.Cmax  = max([Method.Ch,Method.Cc]);
567
568"Thermal Capacity Ratio"
569        Method.Cr    = Method.Cmin/Method.Cmax;
570
571"Effectiveness Correction"
572        Method.Eft1 = 1;
573
574if Method.Cr equal 0
575       
576        then   
577"Effectiveness"
578        Method.Eft = 1-exp(-Method.NTU);
579       
580        else
581
582switch  FlowDirection
583
584        case "cocurrent":
585       
586"Effectiveness in Cocurrent Flow"
587        Method.Eft = (1-exp(-Method.NTU*(1+Method.Cr)))/(1+Method.Cr);
588
589        case "counter":
590
591if Method.Cr equal 1
592       
593        then
594       
595"Effectiveness in Counter Flow"
596        Method.Eft = Method.NTU/(1+Method.NTU);
597       
598        else
599       
600"Effectiveness in Counter Flow"
601        Method.Eft = (1-exp(-Method.NTU*(1-Method.Cr)))/(1-Method.Cr*exp(-Method.NTU*(1-Method.Cr)));
602       
603end
604
605end
606
607end
608
609switch HotSide
610       
611        case "outer":
612
613"Duty"
614        Details.Q       = Method.Eft*Method.Cmin*(InletOuter.T-InletInner.T);
615
616"Hot Stream Heat Capacity"
617        Method.Ch  = InletOuter.F*Outer.Properties.Average.Cp;
618       
619"Cold Stream Heat Capacity"
620        Method.Cc = InletInner.F*Inner.Properties.Average.Cp;
621
622        when InletInner.T > InletOuter.T switchto "inner";
623       
624        case "inner":
625
626"Duty"
627        Details.Q       = Method.Eft*Method.Cmin*(InletInner.T-InletOuter.T);
628
629"Cold Stream Heat Capacity"
630        Method.Cc = InletOuter.F*Outer.Properties.Average.Cp;
631       
632"Hot Stream Heat Capacity"
633        Method.Ch = InletInner.F*Inner.Properties.Average.Cp;
634       
635        when InletInner.T < InletOuter.T switchto "outer";
636       
637end
638
639end
640
641Model DoublePipe_LMTD as DoublePipe_Basic
642       
643ATTRIBUTES
644
645        Icon = "icon/DoublePipe";
646        Pallete = true;
647        Brief  = "Double Pipe Heat Exchanger - LMTD Method";
648        Info  =
649        "to be documented.";
650
651PARAMETERS
652
653FlowDirection   as Switcher     (Brief="Flow Direction",Valid=["counter","cocurrent"],Default="cocurrent");
654       
655VARIABLES
656
657Method as LMTD_Basic    (Brief="LMTD Method of Calculation", Symbol=" ");
658
659EQUATIONS
660
661"Exchange Surface Area"
662        Details.Q = Details.Ud*Pi*DoInner*Lpipe*Method.LMTD;
663       
664"LMTD Correction Factor - True counter ou cocurrent flow"
665        Method.Fc = 1;
666
667switch HotSide
668       
669        case "outer":
670       
671switch FlowDirection
672
673        case "cocurrent":
674       
675"Temperature Difference at Inlet - Cocurrent Flow"
676        Method.DT0 = InletOuter.T - InletInner.T;
677
678"Temperature Difference at Outlet - Cocurrent Flow"
679        Method.DTL = OutletOuter.T - OutletInner.T;
680
681        case "counter":
682       
683"Temperature Difference at Inlet - Counter Flow"
684        Method.DT0 = InletOuter.T - OutletInner.T;
685
686"Temperature Difference at Outlet - Counter Flow"
687        Method.DTL = OutletOuter.T - InletInner.T;
688       
689
690end
691
692        when InletInner.T > InletOuter.T switchto "inner";
693       
694        case "inner":
695
696switch FlowDirection
697
698        case "cocurrent":
699       
700"Temperature Difference at Inlet - Cocurrent Flow"
701        Method.DT0 = InletInner.T - InletOuter.T;
702
703"Temperature Difference at Outlet - Cocurrent Flow"
704        Method.DTL = OutletInner.T - OutletOuter.T;
705       
706        case "counter":
707       
708"Temperature Difference at Inlet - Counter Flow"
709        Method.DT0 = InletInner.T - OutletOuter.T;
710
711"Temperature Difference at Outlet - Counter Flow"
712        Method.DTL = OutletInner.T - InletOuter.T;
713       
714end
715
716        when InletInner.T < InletOuter.T switchto "outer";
717
718end
719
720end
721
722# Testing Hairpin Heat Exchanger (U tube)
723
724Model Hairpin_Basic
725
726ATTRIBUTES
727        Pallete         = false;
728        Brief           = "Basic Equations for hairpin heat exchanger model.";
729        Info            =
730        "to be documented.";
731
732PARAMETERS
733
734outer PP            as Plugin           (Brief="External Physical Properties", Type="PP");
735outer NComp     as Integer      (Brief="Number of Components");
736       
737        M(NComp)        as molweight    (Brief="Component Mol Weight");
738       
739        HotSide                         as Switcher             (Brief="Flag for Fluid Alocation ",Valid=["outer","inner"],Default="outer");
740        innerFlowRegime         as Switcher     (Brief="Inner Flow Regime ",Valid=["laminar","transition","turbulent"],Default="laminar");
741        outerFlowRegime         as Switcher     (Brief="Outer Flow Regime ",Valid=["laminar","transition","turbulent"],Default="laminar");
742
743        InnerLaminarCorrelation         as Switcher     (Brief="Heat Transfer Correlation in Laminar Flow for the Inner Side",Valid=["Hausen","Schlunder"],Default="Hausen");
744        InnerTransitionCorrelation  as Switcher         (Brief="Heat Transfer Correlation in Transition Flow for the Inner Side",Valid=["Gnielinski","Hausen"],Default="Gnielinski");
745        InnerTurbulentCorrelation   as Switcher (Brief="Heat Transfer Correlation in Turbulent Flow for the Inner Side",Valid=["Petukhov","SiederTate"],Default="Petukhov");
746
747        OuterLaminarCorrelation         as Switcher             (Brief="Heat Transfer Correlation in Laminar Flow for the Outer Side",Valid=["Hausen","Schlunder"],Default="Hausen");
748        OuterTransitionCorrelation  as Switcher         (Brief="Heat Transfer Correlation in Transition Flow for the OuterSide",Valid=["Gnielinski","Hausen"],Default="Gnielinski");
749        OuterTurbulentCorrelation   as Switcher         (Brief="Heat Transfer Correlation in Turbulent Flow for the Outer Side",Valid=["Petukhov","SiederTate"],Default="Petukhov");
750
751        Pi                              as constant             (Brief="Pi Number",Default=3.14159265, Symbol = "\pi");
752        DoInner         as length                       (Brief="Outside Diameter of Inner Pipe",Lower=1e-6);
753        DiInner as length                       (Brief="Inside Diameter of Inner Pipe",Lower=1e-10);
754        DiOuter as length                       (Brief="Inside Diameter of Outer pipe",Lower=1e-10);
755        Lpipe           as length                       (Brief="Effective Tube Length of one segment of Pipe",Lower=0.1, Symbol = "L_{pipe}");
756        Kwall           as conductivity         (Brief="Tube Wall Material Thermal Conductivity",Default=1.0, Symbol = "K_{wall}");
757        Rfi                     as positive                     (Brief="Inside Fouling Resistance",Unit='m^2*K/kW',Default=1e-6,Lower=0);
758        Rfo                     as positive                     (Brief="Outside Fouling Resistance",Unit='m^2*K/kW',Default=1e-6,Lower=0);
759
760VARIABLES
761
762in  InletInner          as stream               (Brief="Inlet Inner Stream", PosX=1, PosY=0.7, Symbol="_{inInner}");   
763in  InletOuter          as stream               (Brief="Inlet Outer Stream", PosX=0.8, PosY=0, Symbol="_{inOuter}");
764out OutletInner         as streamPH     (Brief="Outlet Inner Stream", PosX=1, PosY=0.3, Symbol="_{outInner}");
765out OutletOuter         as streamPH     (Brief="Outlet Outer Stream", PosX=0.8, PosY=1, Symbol="_{outOuter}");
766
767        Details         as Details_Main         (Brief="Some Details in the Heat Exchanger", Symbol=" ");
768        Inner                   as Main_DoublePipe      (Brief="Inner Side of the Heat Exchanger", Symbol="_{Inner}");
769        Outer                   as Main_DoublePipe      (Brief="Outer Side of the Heat Exchanger", Symbol="_{Outer}");
770
771SET
772
773#"Component Molecular Weight"
774        M  = PP.MolecularWeight();
775       
776#"Pi Number"
777        Pi      = 3.14159265;
778       
779#"Inner Pipe Cross Sectional Area for Flow"
780        Inner.HeatTransfer.As=Pi*DiInner*DiInner/4;
781       
782#"Outer Pipe Cross Sectional Area for Flow"
783        Outer.HeatTransfer.As=Pi*(DiOuter*DiOuter - DoInner*DoInner)/4;
784       
785#"Inner Pipe Hydraulic Diameter for Heat Transfer"
786        Inner.HeatTransfer.Dh=DiInner;
787       
788#"Outer Pipe Hydraulic Diameter for Heat Transfer"
789        Outer.HeatTransfer.Dh=(DiOuter*DiOuter-DoInner*DoInner)/DoInner;
790
791#"Inner Pipe Hydraulic Diameter for Pressure Drop"
792        Inner.PressureDrop.Dh=DiInner;
793       
794#"Outer Pipe Hydraulic Diameter for Pressure Drop"
795        Outer.PressureDrop.Dh=DiOuter-DoInner;
796
797EQUATIONS
798
799"Outer  Stream Average Temperature"
800        Outer.Properties.Average.T = 0.5*InletOuter.T + 0.5*OutletOuter.T;
801
802"Inner Stream Average Temperature"
803        Inner.Properties.Average.T = 0.5*InletInner.T + 0.5*OutletInner.T;
804       
805"Outer Stream Average Pressure"
806        Outer.Properties.Average.P = 0.5*InletOuter.P+0.5*OutletOuter.P;
807       
808"Inner Stream Average Pressure"
809        Inner.Properties.Average.P = 0.5*InletInner.P+0.5*OutletInner.P;
810
811"Inner Stream Wall Temperature"
812        Inner.Properties.Wall.Twall =   0.5*Outer.Properties.Average.T + 0.5*Inner.Properties.Average.T;
813
814"Outer Stream Wall Temperature"
815        Outer.Properties.Wall.Twall =   0.5*Outer.Properties.Average.T + 0.5*Inner.Properties.Average.T;
816
817"Outer Stream Average Molecular Weight"
818        Outer.Properties.Average.Mw = sum(M*InletOuter.z);
819
820"Inner Stream Average Molecular Weight"
821        Inner.Properties.Average.Mw = sum(M*InletInner.z);
822
823if InletInner.v equal 0
824       
825        then   
826
827"Average Heat Capacity Inner Stream"
828        Inner.Properties.Average.Cp             =       PP.LiquidCp(Inner.Properties.Average.T,Inner.Properties.Average.P,InletInner.z);
829
830"Average Mass Density Inner Stream"
831        Inner.Properties.Average.rho    =       PP.LiquidDensity(Inner.Properties.Average.T,Inner.Properties.Average.P,InletInner.z);
832
833"Inlet Mass Density Inner Stream"
834        Inner.Properties.Inlet.rho              =       PP.LiquidDensity(InletInner.T,InletInner.P,InletInner.z);
835
836"Outlet Mass Density Inner Stream"
837        Inner.Properties.Outlet.rho     =       PP.LiquidDensity(OutletInner.T,OutletInner.P,OutletInner.z);
838
839"Average Viscosity Inner Stream"
840        Inner.Properties.Average.Mu     =       PP.LiquidViscosity(Inner.Properties.Average.T,Inner.Properties.Average.P,InletInner.z);
841
842"Average        Conductivity Inner Stream"
843        Inner.Properties.Average.K              =       PP.LiquidThermalConductivity(Inner.Properties.Average.T,Inner.Properties.Average.P,InletInner.z);
844
845"Viscosity Inner Stream at wall temperature"
846        Inner.Properties.Wall.Mu                =       PP.LiquidViscosity(Inner.Properties.Wall.Twall,Inner.Properties.Average.P,InletInner.z);
847
848        else
849
850"Average Heat Capacity InnerStream"
851        Inner.Properties.Average.Cp     =       PP.VapourCp(Inner.Properties.Average.T,Inner.Properties.Average.P,InletInner.z);
852
853"Average Mass Density Inner Stream"
854        Inner.Properties.Average.rho    =       PP.VapourDensity(Inner.Properties.Average.T,Inner.Properties.Average.P,InletInner.z);
855
856"Inlet Mass Density Inner Stream"
857        Inner.Properties.Inlet.rho              =       PP.VapourDensity(InletInner.T,InletInner.P,InletInner.z);
858       
859"Outlet Mass Density Inner Stream"
860        Inner.Properties.Outlet.rho     =       PP.VapourDensity(OutletInner.T,OutletInner.P,OutletInner.z);
861
862"Average Viscosity Inner Stream"
863        Inner.Properties.Average.Mu     =       PP.VapourViscosity(Inner.Properties.Average.T,Inner.Properties.Average.P,InletInner.z);
864
865"Average Conductivity Inner Stream"
866        Inner.Properties.Average.K              =       PP.VapourThermalConductivity(Inner.Properties.Average.T,Inner.Properties.Average.P,InletInner.z);
867
868"Viscosity Inner Stream at wall temperature"
869        Inner.Properties.Wall.Mu                =       PP.VapourViscosity(Inner.Properties.Wall.Twall,Inner.Properties.Average.P,InletInner.z);
870
871end
872
873if InletOuter.v equal 0
874
875        then
876
877"Average Heat Capacity Outer Stream"
878        Outer.Properties.Average.Cp     =               PP.LiquidCp(Outer.Properties.Average.T,Outer.Properties.Average.P,InletOuter.z);
879
880"Average Mass Density Outer Stream"
881        Outer.Properties.Average.rho =          PP.LiquidDensity(Outer.Properties.Average.T,Outer.Properties.Average.P,InletOuter.z);
882
883"Inlet Mass Density Outer Stream"
884        Outer.Properties.Inlet.rho              =               PP.LiquidDensity(InletOuter.T,InletOuter.P,InletOuter.z);
885
886"Outlet Mass Density Outer Stream"
887        Outer.Properties.Outlet.rho     =               PP.LiquidDensity(OutletOuter.T,OutletOuter.P,OutletOuter.z);
888
889"Average Viscosity Outer Stream"
890        Outer.Properties.Average.Mu     =               PP.LiquidViscosity(Outer.Properties.Average.T,Outer.Properties.Average.P,InletOuter.z);
891
892"Average Conductivity Outer Stream"
893        Outer.Properties.Average.K      =               PP.LiquidThermalConductivity(Outer.Properties.Average.T,Outer.Properties.Average.P,InletOuter.z);       
894
895"Viscosity Outer Stream at wall temperature"
896        Outer.Properties.Wall.Mu                =               PP.LiquidViscosity(Outer.Properties.Wall.Twall,Outer.Properties.Average.P,InletOuter.z);       
897
898
899        else
900
901"Average Heat Capacity Outer Stream"
902        Outer.Properties.Average.Cp     =               PP.VapourCp(Outer.Properties.Average.T,Outer.Properties.Average.P,InletOuter.z);
903
904"Average Mass Density Outer Stream"
905        Outer.Properties.Average.rho =          PP.VapourDensity(Outer.Properties.Average.T,Outer.Properties.Average.P,InletOuter.z);
906
907"Inlet Mass Density Outer Stream"
908        Outer.Properties.Inlet.rho              =               PP.VapourDensity(InletOuter.T,InletOuter.P,InletOuter.z);
909       
910"Outlet Mass Density Outer Stream"
911        Outer.Properties.Outlet.rho     =               PP.VapourDensity(OutletOuter.T,OutletOuter.P,OutletOuter.z);
912
913"Average Viscosity Outer Stream"
914        Outer.Properties.Average.Mu     =               PP.VapourViscosity(Outer.Properties.Average.T,Outer.Properties.Average.P,InletOuter.z);
915
916"Average Conductivity Outer Stream"
917        Outer.Properties.Average.K      =               PP.VapourThermalConductivity(Outer.Properties.Average.T,Outer.Properties.Average.P,InletOuter.z);       
918
919"Viscosity Outer Stream at wall temperature"
920        Outer.Properties.Wall.Mu                =               PP.VapourViscosity(Outer.Properties.Wall.Twall,Outer.Properties.Average.P,InletOuter.z);
921
922end
923
924switch HotSide
925       
926        case "outer":
927
928"Energy Balance Outer Stream"
929        Details.Q = InletOuter.F*(InletOuter.h-OutletOuter.h);
930
931"Energy Balance Inner Stream"
932        Details.Q = InletInner.F*(OutletInner.h-InletInner.h);
933
934        when InletInner.T > InletOuter.T switchto "inner";
935
936case "inner":
937
938"Energy Balance Hot Stream"
939        Details.Q = InletInner.F*(InletInner.h-OutletInner.h);
940
941"Energy Balance Cold Stream"
942        Details.Q = InletOuter.F*(OutletOuter.h - InletOuter.h);
943
944        when InletInner.T < InletOuter.T switchto "outer";
945
946end
947
948"Flow Mass Inlet Inner Stream"
949        Inner.Properties.Inlet.Fw       =  sum(M*InletInner.z)*InletInner.F;
950
951"Flow Mass Outlet Inner Stream"
952        Inner.Properties.Outlet.Fw      =  sum(M*OutletInner.z)*OutletInner.F;
953
954"Flow Mass Inlet Outer Stream"
955        Outer.Properties.Inlet.Fw               =  sum(M*InletOuter.z)*InletOuter.F;
956
957"Flow Mass Outlet Outer Stream"
958        Outer.Properties.Outlet.Fw      =  sum(M*OutletOuter.z)*OutletOuter.F;
959
960"Molar Balance Outer Stream"
961        OutletOuter.F = InletOuter.F;
962       
963"Molar Balance Inner Stream"
964        OutletInner.F = InletInner.F;
965
966"Outer Stream Molar Fraction Constraint"
967        OutletOuter.z=InletOuter.z;
968       
969"InnerStream Molar Fraction Constraint"
970        OutletInner.z=InletInner.z;
971
972"Exchange Surface Area for one segment of pipe"
973        Details.A=Pi*DoInner*(2*Lpipe);
974
975switch innerFlowRegime
976       
977        case "laminar":
978       
979"Inner Side Friction Factor for Pressure Drop - laminar Flow"
980        Inner.PressureDrop.fi*Inner.PressureDrop.Re = 16;
981       
982        when Inner.PressureDrop.Re > 2300 switchto "transition";
983
984        case "transition":
985       
986"using Turbulent Flow - to be implemented"
987        (Inner.PressureDrop.fi-0.0035)*(Inner.PressureDrop.Re^0.42) = 0.264;
988
989        when Inner.PressureDrop.Re < 2300 switchto "laminar";
990        when Inner.PressureDrop.Re > 10000 switchto "turbulent";
991
992        case "turbulent":
993
994"Inner Side Friction Factor - Turbulent Flow"
995        (Inner.PressureDrop.fi-0.0035)*(Inner.PressureDrop.Re^0.42) = 0.264;
996
997        when Inner.PressureDrop.Re < 10000 switchto "transition";
998       
999end     
1000
1001switch outerFlowRegime
1002       
1003        case "laminar":
1004       
1005"Outer Side Friction Factor - laminar Flow"
1006        Outer.PressureDrop.fi*Outer.PressureDrop.Re = 16;
1007       
1008        when Outer.PressureDrop.Re > 2300 switchto "transition";
1009
1010        case "transition":
1011       
1012"using Turbulent Flow - Transition Flow must be implemented"
1013        (Outer.PressureDrop.fi-0.0035)*(Outer.PressureDrop.Re^0.42) = 0.264;
1014
1015        when Outer.PressureDrop.Re < 2300 switchto "laminar";
1016        when Outer.PressureDrop.Re > 10000 switchto "turbulent";
1017
1018        case "turbulent":
1019
1020"Outer Side Friction Factor - Turbulent Flow"
1021        (Outer.PressureDrop.fi-0.0035)*(Outer.PressureDrop.Re^0.42) = 0.264;
1022
1023        when Outer.PressureDrop.Re < 10000 switchto "transition";
1024       
1025end
1026
1027switch innerFlowRegime
1028       
1029        case "laminar":
1030       
1031"Inner Side Friction Factor for Heat Transfer - laminar Flow"
1032        Inner.HeatTransfer.fi   = 1/(0.79*ln(Inner.HeatTransfer.Re)-1.64)^2;
1033       
1034switch InnerLaminarCorrelation
1035       
1036        case "Hausen":
1037
1038"Nusselt Number"
1039        Inner.HeatTransfer.Nu = 3.665 + ((0.19*((DiInner/Lpipe)*Inner.HeatTransfer.Re*Inner.HeatTransfer.PR)^0.8)/(1+0.117*((DiInner/Lpipe)*Inner.HeatTransfer.Re*Inner.HeatTransfer.PR)^0.467));
1040       
1041        case "Schlunder":
1042
1043"Nusselt Number"
1044        Inner.HeatTransfer.Nu = (49.027896+4.173281*Inner.HeatTransfer.Re*Inner.HeatTransfer.PR*(DiInner/Lpipe))^(1/3);
1045
1046end
1047       
1048        when Inner.HeatTransfer.Re > 2300 switchto "transition";
1049       
1050        case "transition":
1051       
1052"Inner Side Friction Factor for Heat Transfer - transition Flow"
1053        Inner.HeatTransfer.fi   = 1/(0.79*ln(Inner.HeatTransfer.Re)-1.64)^2;
1054       
1055switch InnerTransitionCorrelation
1056       
1057        case "Gnielinski":
1058       
1059"Nusselt Number"
1060        Inner.HeatTransfer.Nu*(1+(12.7*sqrt(0.125*Inner.HeatTransfer.fi)*((Inner.HeatTransfer.PR)^(2/3) -1))) = 0.125*Inner.HeatTransfer.fi*(Inner.HeatTransfer.Re-1000)*Inner.HeatTransfer.PR;
1061
1062        case "Hausen":
1063
1064"Nusselt Number"
1065        Inner.HeatTransfer.Nu =0.116*(Inner.HeatTransfer.Re^(0.667)-125)*Inner.HeatTransfer.PR^(0.333)*(1+(DiInner/Lpipe)^0.667);
1066       
1067end
1068
1069        when Inner.HeatTransfer.Re < 2300 switchto "laminar";
1070        when Inner.HeatTransfer.Re > 10000 switchto "turbulent";
1071
1072        case "turbulent":
1073
1074switch InnerTurbulentCorrelation
1075       
1076        case "Petukhov":
1077       
1078"Inner Side Friction Factor for Heat Transfer - turbulent Flow"
1079        Inner.HeatTransfer.fi   = 1/(1.82*log(Inner.HeatTransfer.Re)-1.64)^2;
1080
1081"Nusselt Number"
1082        Inner.HeatTransfer.Nu*(1.07+(12.7*sqrt(0.125*Inner.HeatTransfer.fi)*((Inner.HeatTransfer.PR)^(2/3) -1))) = 0.125*Inner.HeatTransfer.fi*Inner.HeatTransfer.Re*Inner.HeatTransfer.PR;
1083       
1084        case "SiederTate":
1085
1086"Nusselt Number"
1087        Inner.HeatTransfer.Nu = 0.027*(Inner.HeatTransfer.PR)^(1/3)*(Inner.HeatTransfer.Re)^(4/5);
1088
1089"Inner Side Friction Factor for Heat Transfer - turbulent Flow"
1090        Inner.HeatTransfer.fi   = 1/(1.82*log(Inner.HeatTransfer.Re)-1.64)^2;
1091       
1092end
1093       
1094        when Inner.HeatTransfer.Re < 10000 switchto "transition";
1095       
1096end
1097
1098switch outerFlowRegime
1099       
1100        case "laminar":
1101       
1102"Outer Side Friction Factor for Heat Transfer - laminar Flow"
1103        Outer.HeatTransfer.fi   = 1/(0.79*ln(Outer.HeatTransfer.Re)-1.64)^2;
1104       
1105switch OuterLaminarCorrelation
1106       
1107        case "Hausen":
1108
1109"Nusselt Number"
1110        Outer.HeatTransfer.Nu = 3.665 + ((0.19*((Outer.HeatTransfer.Dh/Lpipe)*Outer.HeatTransfer.Re*Outer.HeatTransfer.PR)^0.8)/(1+0.117*((Outer.HeatTransfer.Dh/Lpipe)*Outer.HeatTransfer.Re*Outer.HeatTransfer.PR)^0.467));
1111       
1112        case "Schlunder":
1113
1114"Nusselt Number"
1115        Outer.HeatTransfer.Nu = (49.027896+4.173281*Outer.HeatTransfer.Re*Outer.HeatTransfer.PR*(Outer.HeatTransfer.Dh/Lpipe))^(1/3);
1116
1117end
1118       
1119        when Outer.HeatTransfer.Re > 2300 switchto "transition";
1120       
1121        case "transition":
1122       
1123switch OuterTransitionCorrelation
1124       
1125        case "Gnielinski":
1126
1127"Outer Side Friction Factor for Heat Transfer - transition Flow"
1128        Outer.HeatTransfer.fi   = 1/(0.79*ln(Outer.HeatTransfer.Re)-1.64)^2;
1129
1130"Nusselt Number"
1131        Outer.HeatTransfer.Nu*(1+(12.7*sqrt(0.125*Outer.HeatTransfer.fi)*((Outer.HeatTransfer.PR)^(2/3) -1))) = 0.125*Outer.HeatTransfer.fi*(Outer.HeatTransfer.Re-1000)*Outer.HeatTransfer.PR;
1132
1133        case "Hausen":
1134
1135"Nusselt Number"
1136        Outer.HeatTransfer.Nu = 0.116*(Outer.HeatTransfer.Re^(0.667)-125)*Outer.HeatTransfer.PR^(0.333)*(1+(Outer.HeatTransfer.Dh/Lpipe)^0.667);
1137
1138
1139"Outer Side Friction Factor for Heat Transfer - transition Flow"
1140        Outer.HeatTransfer.fi   = 1/(0.79*ln(Outer.HeatTransfer.Re)-1.64)^2;
1141       
1142end
1143       
1144        when Outer.HeatTransfer.Re < 2300 switchto "laminar";
1145        when Outer.HeatTransfer.Re > 10000 switchto "turbulent";
1146       
1147        case "turbulent":
1148       
1149switch OuterTurbulentCorrelation
1150       
1151        case "Petukhov":
1152
1153"Outer Side Friction Factor for Heat Transfer - turbulent Flow"
1154        Outer.HeatTransfer.fi   = 1/(1.82*log(Outer.HeatTransfer.Re)-1.64)^2;
1155       
1156"Nusselt Number"
1157        Outer.HeatTransfer.Nu*(1.07+(12.7*sqrt(0.125*Outer.HeatTransfer.fi)*((Outer.HeatTransfer.PR)^(2/3) -1))) = 0.125*Outer.HeatTransfer.fi*Outer.HeatTransfer.Re*Outer.HeatTransfer.PR;
1158       
1159        case "SiederTate":
1160
1161"Nusselt Number"
1162        Outer.HeatTransfer.Nu = 0.027*(Outer.HeatTransfer.PR)^(1/3)*(Outer.HeatTransfer.Re)^(4/5);
1163
1164"Outer Side Friction Factor for Heat Transfer - turbulent Flow"
1165        Outer.HeatTransfer.fi   = 1/(1.82*log(Outer.HeatTransfer.Re)-1.64)^2;
1166       
1167end
1168
1169        when Outer.HeatTransfer.Re < 10000 switchto "transition";
1170
1171end
1172
1173"Inner Pipe Film Coefficient"
1174        Inner.HeatTransfer.hcoeff = (Inner.HeatTransfer.Nu*Inner.Properties.Average.K/DiInner)*Inner.HeatTransfer.Phi;
1175
1176"Outer Pipe Film Coefficient"
1177        Outer.HeatTransfer.hcoeff= (Outer.HeatTransfer.Nu*Outer.Properties.Average.K/Outer.HeatTransfer.Dh)*Outer.HeatTransfer.Phi;
1178
1179"Total Pressure Drop Outer Stream"
1180        Outer.PressureDrop.Pdrop  = Outer.PressureDrop.Pd_fric+Outer.PressureDrop.Pd_ret;
1181
1182"Total Pressure Drop Inner Stream"
1183        Inner.PressureDrop.Pdrop  = Inner.PressureDrop.Pd_fric+Inner.PressureDrop.Pd_ret;
1184       
1185"Pressure Drop Outer Stream"
1186        OutletOuter.P  = InletOuter.P - Outer.PressureDrop.Pdrop;
1187
1188"Pressure Drop Inner Stream"
1189        OutletInner.P  = InletInner.P - Inner.PressureDrop.Pdrop;
1190       
1191"Outer Pipe Pressure Drop for friction"
1192        Outer.PressureDrop.Pd_fric = (2*Outer.PressureDrop.fi*(2*Lpipe)*Outer.Properties.Average.rho*Outer.HeatTransfer.Vmean^2)/(Outer.PressureDrop.Dh*Outer.HeatTransfer.Phi);
1193       
1194"Inner Pipe Pressure Drop for friction"
1195        Inner.PressureDrop.Pd_fric = (2*Inner.PressureDrop.fi*(2*Lpipe)*Inner.Properties.Average.rho*Inner.HeatTransfer.Vmean^2)/(DiInner*Inner.HeatTransfer.Phi);
1196
1197"Outer Pipe Pressure Drop due to return"
1198        Outer.PressureDrop.Pd_ret = 1.5*Outer.Properties.Average.rho*Outer.HeatTransfer.Vmean^2;
1199
1200"Inner Pipe Pressure Drop due to return"
1201        Inner.PressureDrop.Pd_ret = 1.5*Inner.Properties.Average.rho*Inner.HeatTransfer.Vmean^2;
1202
1203"Outer Pipe Phi correction"
1204        Outer.HeatTransfer.Phi = (Outer.Properties.Average.Mu/Outer.Properties.Wall.Mu)^0.14;
1205       
1206"Inner Pipe Phi correction"
1207        Inner.HeatTransfer.Phi  = (Inner.Properties.Average.Mu/Inner.Properties.Wall.Mu)^0.14;
1208
1209"Outer Pipe Prandtl Number"
1210        Outer.HeatTransfer.PR = ((Outer.Properties.Average.Cp/Outer.Properties.Average.Mw)*Outer.Properties.Average.Mu)/Outer.Properties.Average.K;
1211
1212"Inner Pipe Prandtl Number"
1213        Inner.HeatTransfer.PR = ((Inner.Properties.Average.Cp/Inner.Properties.Average.Mw)*Inner.Properties.Average.Mu)/Inner.Properties.Average.K;
1214
1215"Outer Pipe Reynolds Number for Heat Transfer"
1216        Outer.HeatTransfer.Re = (Outer.Properties.Average.rho*Outer.HeatTransfer.Vmean*Outer.HeatTransfer.Dh)/Outer.Properties.Average.Mu;
1217
1218"Outer Pipe Reynolds Number for Pressure Drop"
1219        Outer.PressureDrop.Re = (Outer.Properties.Average.rho*Outer.HeatTransfer.Vmean*Outer.PressureDrop.Dh)/Outer.Properties.Average.Mu;
1220
1221"Inner Pipe Reynolds Number for Heat Transfer"
1222        Inner.HeatTransfer.Re = (Inner.Properties.Average.rho*Inner.HeatTransfer.Vmean*Inner.HeatTransfer.Dh)/Inner.Properties.Average.Mu;
1223
1224"Inner Pipe Reynolds Number for Pressure Drop"
1225        Inner.PressureDrop.Re = Inner.HeatTransfer.Re;
1226
1227"Outer Pipe Velocity"
1228        Outer.HeatTransfer.Vmean*(Outer.HeatTransfer.As*Outer.Properties.Average.rho)  = Outer.Properties.Inlet.Fw;
1229
1230"Inner Pipe Velocity"
1231        Inner.HeatTransfer.Vmean*(Inner.HeatTransfer.As*Inner.Properties.Average.rho)  = Inner.Properties.Inlet.Fw;
1232
1233"Overall Heat Transfer Coefficient Clean"
1234        Details.Uc*((DoInner/(Inner.HeatTransfer.hcoeff*DiInner) )+(DoInner*ln(DoInner/DiInner)/(2*Kwall))+(1/(Outer.HeatTransfer.hcoeff)))=1;
1235
1236"Overall Heat Transfer Coefficient Dirty"
1237        Details.Ud*(Rfi*(DoInner/DiInner) +  Rfo + (DoInner/(Inner.HeatTransfer.hcoeff*DiInner) )+(DoInner*ln(DoInner/DiInner)/(2*Kwall))+(1/(Outer.HeatTransfer.hcoeff)))=1;
1238
1239end
1240
1241Model Hairpin_NTU as Hairpin_Basic
1242
1243ATTRIBUTES
1244
1245        Icon = "icon/hairpin";
1246        Pallete = true;
1247        Brief  = "Hairpin Heat Exchanger - NTU Method";
1248        Info  =
1249        "to be documented.";
1250
1251PARAMETERS
1252
1253FlowDirection   as Switcher     (Brief="Flow Direction",Valid=["counter","cocurrent"],Default="cocurrent");
1254       
1255VARIABLES
1256
1257Method as NTU_Basic     (Brief="NTU Method of Calculation", Symbol=" ");
1258
1259EQUATIONS
1260
1261"Number of Units Transference"
1262        Method.NTU*Method.Cmin = Details.Ud*Pi*DoInner*(2*Lpipe);
1263       
1264"Minimum Heat Capacity"
1265        Method.Cmin  = min([Method.Ch,Method.Cc]);
1266
1267"Maximum Heat Capacity"
1268        Method.Cmax  = max([Method.Ch,Method.Cc]);
1269
1270"Thermal Capacity Ratio"
1271        Method.Cr    = Method.Cmin/Method.Cmax;
1272
1273"Effectiveness Correction"
1274        Method.Eft1 = 1;
1275
1276if Method.Cr equal 0
1277       
1278        then   
1279"Effectiveness"
1280        Method.Eft = 1-exp(-Method.NTU);
1281       
1282        else
1283
1284switch  FlowDirection
1285
1286        case "cocurrent":
1287       
1288"Effectiveness in Cocurrent Flow"
1289        Method.Eft = (1-exp(-Method.NTU*(1+Method.Cr)))/(1+Method.Cr);
1290
1291        case "counter":
1292
1293if Method.Eft >= 1
1294       
1295        then
1296       
1297"Effectiveness in Counter Flow"
1298        Method.Eft = 1;
1299       
1300        else
1301       
1302"Effectiveness in Counter Flow"
1303        Method.NTU*(Method.Cr-1.00001) = ln(abs((Method.Eft-1.00001))) - ln(abs((Method.Cr*Method.Eft-1.00001)));
1304end
1305
1306end
1307
1308end
1309
1310switch HotSide
1311       
1312        case "outer":
1313
1314"Duty"
1315        Details.Q       = Method.Eft*Method.Cmin*(InletOuter.T-InletInner.T);
1316
1317"Hot Stream Heat Capacity"
1318        Method.Ch  = InletOuter.F*Outer.Properties.Average.Cp;
1319       
1320"Cold Stream Heat Capacity"
1321        Method.Cc = InletInner.F*Inner.Properties.Average.Cp;
1322
1323        when InletInner.T > InletOuter.T switchto "inner";
1324       
1325        case "inner":
1326
1327"Duty"
1328        Details.Q       = Method.Eft*Method.Cmin*(InletInner.T-InletOuter.T);
1329
1330"Cold Stream Heat Capacity"
1331        Method.Cc = InletOuter.F*Outer.Properties.Average.Cp;
1332       
1333"Hot Stream Heat Capacity"
1334        Method.Ch = InletInner.F*Inner.Properties.Average.Cp;
1335       
1336        when InletInner.T < InletOuter.T switchto "outer";
1337       
1338end
1339
1340end
1341
1342Model Hairpin_LMTD as Hairpin_Basic
1343       
1344ATTRIBUTES
1345
1346        Icon = "icon/hairpin";
1347        Pallete = true;
1348        Brief  = "Hairpin Heat Exchanger - LMTD Method";
1349        Info  =
1350        "to be documented.";
1351
1352PARAMETERS
1353
1354FlowDirection   as Switcher     (Brief="Flow Direction",Valid=["counter","cocurrent"],Default="cocurrent");
1355       
1356VARIABLES
1357
1358Method as LMTD_Basic    (Brief="LMTD Method of Calculation", Symbol=" ");
1359
1360EQUATIONS
1361
1362"Exchange Surface Area"
1363        Details.Q = Details.Ud*Pi*DoInner*(2*Lpipe)*Method.LMTD;
1364       
1365"LMTD Correction Factor - True counter ou cocurrent flow"
1366        Method.Fc = 1;
1367
1368switch HotSide
1369       
1370        case "outer":
1371       
1372switch FlowDirection
1373
1374        case "cocurrent":
1375       
1376"Temperature Difference at Inlet - Cocurrent Flow"
1377        Method.DT0 = InletOuter.T - InletInner.T;
1378
1379"Temperature Difference at Outlet - Cocurrent Flow"
1380        Method.DTL = OutletOuter.T - OutletInner.T;
1381
1382        case "counter":
1383       
1384"Temperature Difference at Inlet - Counter Flow"
1385        Method.DT0 = InletOuter.T - OutletInner.T;
1386
1387"Temperature Difference at Outlet - Counter Flow"
1388        Method.DTL = OutletOuter.T - InletInner.T;
1389       
1390
1391end
1392
1393        when InletInner.T > InletOuter.T switchto "inner";
1394       
1395        case "inner":
1396
1397switch FlowDirection
1398
1399        case "cocurrent":
1400       
1401"Temperature Difference at Inlet - Cocurrent Flow"
1402        Method.DT0 = InletInner.T - InletOuter.T;
1403
1404"Temperature Difference at Outlet - Cocurrent Flow"
1405        Method.DTL = OutletInner.T - OutletOuter.T;
1406       
1407        case "counter":
1408       
1409"Temperature Difference at Inlet - Counter Flow"
1410        Method.DT0 = InletInner.T - OutletOuter.T;
1411
1412"Temperature Difference at Outlet - Counter Flow"
1413        Method.DTL = OutletInner.T - InletOuter.T;
1414       
1415end
1416
1417        when InletInner.T < InletOuter.T switchto "outer";
1418
1419end
1420
1421end
Note: See TracBrowser for help on using the repository browser.