source: branches/newlanguage/sample/reactors/fogler/chap4/spheric_reactor.mso @ 115

#*-------------------------------------------------------------------
* EMSO Model Library (EML) Copyright (C) 2004 - 2007 ALSOC.
*
* This LIBRARY is free software; you can distribute it and/or modify
* it under the therms of the ALSOC FREE LICENSE as available at
* http://www.enq.ufrgs.br/alsoc.
*
* EMSO Copyright (C) 2004 - 2007 ALSOC, original code
* from http://www.rps.eng.br Copyright (C) 2002-2004.
* All rights reserved.
*
* EMSO is distributed under the therms of the ALSOC LICENSE as
* available at http://www.enq.ufrgs.br/alsoc.
*
*---------------------------------------------------------------------
* Spheric reactor
*----------------------------------------------------------------------
* Solved problem from Fogler (1999)
* Problem number: 4-8
* Page: 151 (Brazilian version, 2002)
*----------------------------------------------------------------------
*
*   Description:
*               Sample to calculate of the molar conversion and pressure drop
*       as function of the length in a spheric reactor with a reaction of
*       dehydrogenation (reforming reaction):
*                       paraffin -> oleffin + H2
*       of first-order with respect to paraffin.
*       
*   Assumptions:
*               * change time in length
*       * steady-state
*       * isotermic system
*       * gaseous phase
*
*       Specify:
*               * the inlet stream
*               * the kinetic parameters
*               * the parameters of reactor
*               * the parameters of catalyst packed bed
*
*----------------------------------------------------------------------
* Author: Christiano D. Wetzel Guerra and Rodolfo Rodrigues
* GIMSCOP/UFRGS - Group of Integration, Modeling, Simulation, Control,
*                                       and Optimization of Processes
* $Id: spheric_reactor.mso 82 2006-12-08 20:11:44Z paula $
*--------------------------------------------------------------------*#

using "types";


FlowSheet spheric_reactor
        PARAMETERS
        rho_0 as dens_mass      (Brief="Initial density");
        Dp    as length         (Brief="Particle diameter");
        k_lin as Real           (Brief="Specific rate of reaction", Unit="m^3/kg/s");
        visc  as viscosity      (Brief="Flow viscosity");
        L     as length         (Brief="Fixed bed half length");
        rho_c as dens_mass      (Brief="Catalyser density");
        phi   as fraction       (Brief="Fixed bed porosity");
        pi        as Real               (Brief="Number pi", Default=3.14159);
        R     as length         (Brief="Radius reactor");
        
        VARIABLES
        X     as fraction       (Brief="Molar conversion");
        y     as Real           (Brief="Dimensionless pressure drop (P/P0)", Lower=0);
        P     as pressure       (Brief="Output pressure", Unit="kPa");
        z         as length             (Brief="Length of reactor");
        beta0 as Real           (Brief="Parameter beta0 of Ergun equation", Unit="Pa/m");
        Ac    as area           (Brief="Tranversal section area", Lower=0);
        Ca0   as conc_mol       (Brief="Input molar concentration of A");
        Fa0   as flow_mol       (Brief="Input molar flow of A");
        P0    as pressure       (Brief="Initial pressure", Unit="kPa");
        m         as flow_mass  (Brief="Mass flow");
        
        EQUATIONS
        "Change time in z"
        z = time*"m/s";
        
        "Transversal section area"
        Ac = pi*(R^2 - (z - L)^2);
        
        "Parameter beta0 of Ergun equation"
        beta0 = m*(1 - phi)/(rho_0*Ac*Dp*(phi^3))*(150*(1 - phi)*visc/Dp - 1.75*m/Ac);
        
        
        "Molar conversion"
        diff(X) = k_lin*(Ca0*(1 - X)/(1 + X)*y)*rho_c*(1 - phi)*Ac/Fa0*"m/s";
        
        "Pressure drop"
        diff(y) = -beta0/P0/y*(1 + X)*"m/s";
        
        "Dimensionless pressure drop"
        y = P/P0;
        
        SET
        rho_0 = 32*"kg/m^3";
        Dp        = 0.002*"m";
        k_lin = 2e-5*"m^3/kg/s";
        visc  = 1.5e-5*"kg/m/s";
        L         = 2.7*"m";
        rho_c = 2600*"kg/m^3";
        phi   = 0.4;
        R         = 3*"m";
        
        SPECIFY
        "Input molar concentration of A"
        Ca0 = 320*"mol/m^3";
        "Input molar flow of A"
        Fa0 = 440*"mol/s";
        "Initial pressure"
        P0      = 2000*"kPa";
        "Input mass flow"
        m       = 44*"kg/s";

        INITIAL
        "Molar conversion"
        X = 0;  
        "Dimensionless pressure drop"
        y = 1;

        OPTIONS
        time =[0:0.1:5.4];
end