source: branches/new_gui/my_folders/fogler/chap4/membrane_reactor.mso @ 919

#*-------------------------------------------------------------------
* EMSO Model Library (EML) Copyright (C) 2004 - 2007 ALSOC.
*
* This LIBRARY is free software; you can distribute it and/or modify
* it under the therms of the ALSOC FREE LICENSE as available at
* http://www.enq.ufrgs.br/alsoc.
*
* EMSO Copyright (C) 2004 - 2007 ALSOC, original code
* from http://www.rps.eng.br Copyright (C) 2002-2004.
* All rights reserved.
*
* EMSO is distributed under the therms of the ALSOC LICENSE as
* available at http://www.enq.ufrgs.br/alsoc.
*
*---------------------------------------------------------------------
* Membrane reactor
*----------------------------------------------------------------------
* Solved problem from Fogler (1999)
* Problem number: 4-10
* Page: 164 (Brazilian version, 2002)
*----------------------------------------------------------------------
*
*   Description:
*               Sample to calculate of the molar flows as function of the 
*       volume in a membrane reactor with a generic reaction of 
*       dehydrogenation:
*                       A <-> B + C
*               The membrane is permeable to the B but it is not permeable to
*       the A and the C.
*       
*   Assumptions:
*               * change time in volume
*       * steady-state
*       * isotermic and isobaric system
*       * gaseous phase
*
*       Specify:
*               * the inlet stream
*               * the kinetic parameters
*
*----------------------------------------------------------------------
* Author: Christiano D. W. Guerra and Rodolfo Rodrigues
* $Id: membrane_reactor.mso 574 2008-07-25 14:18:50Z rafael $
*--------------------------------------------------------------------*#

using "types";


FlowSheet reactor
        PARAMETERS
        NComp   as Integer              (Brief="Number of chemical components", Lower=1);
        stoic(NComp)as Real             (Brief="Stoichiometric number");
        Kc      as conc_mol             (Brief="Equilibrium constant", DisplayUnit='mol/l');
        kc      as Real                 (Brief="Mass transfer coefficient", Unit='1/min');
        R               as Real                 (Brief="Universal gas constant", Unit='atm*l/mol/K', Default=0.082);
        
        VARIABLES
        F(NComp)as flow_mol             (Brief="Molar flow", DisplayUnit='mol/min');
        C(NComp)as conc_mol             (Brief="Molar concentration", DisplayUnit='mol/l', Lower=0);
        r(NComp)as reaction_mol (Brief="Rate of reaction", DisplayUnit='mol/l/min');
        Cto             as conc_mol             (Brief="Total inlet concentration", DisplayUnit='mol/l');
        k               as Real                 (Brief="Specific rate of reaction", Unit='1/min');
        V               as volume               (Brief="Volume", DisplayUnit='l');
        
        T               as temperature  (Brief="Temperatura");
        P               as pressure             (Brief="Pressure");

        EQUATIONS
        "Change time in V"
        V = time*'l/s';
        
        "Molar balance for A"
        diff(F(1))*'s/l' = r(1);
        "Molar balance for B"
        diff(F(2))*'s/l' = r(2) - kc*C(2);
        "Molar balance for C"
        diff(F(3))*'s/l' = r(3);
        
        "Rate of reaction"
        r = stoic*k*(C(1) - C(2)*C(3)/Kc);

        "Molar concentration"
        C*sum(F) = Cto*F;
        
        "Total molar concentration"
        Cto = P/(R*T);
        
        SET
        NComp = 3; # A: propane, B: propylene and C: hydrogen
        stoic = [-1.0, 1.0, 1.0]; # A <-> B + C
        
        kc = 0.20*'1/min';
        Kc = 0.05*'mol/l';
        
        SPECIFY
        P = 8.2*'atm';  # Isobaric system
        T = 500*'K';    # Isotermic system
        
        k = 0.7*'1/min';

        INITIAL
        "Molar flow"
        F = [10, 0.0, 0.0]*'mol/min';

        OPTIONS
        TimeStep = 10;
        TimeEnd = 500;
        TimeUnit = 's';
end