source: branches/gui/tutorial/ThreeTank3.mso @ 808

#*---------------------------------------------------------------------
* This file is property of the author and cannot be used, copyed
* or modified without permission.
*
* Copyright (C) 2002-2004  the author
*----------------------------------------------------------------------
* Author: Rafael de Pelegrini Soares
* $Id: ThreeTank3.mso 765 2009-06-16 13:15:20Z rafael $
*----------------------------------------------------------------------
*
* Arquivo de exemplo do EMSO
*
* Sistema de uma série de tanques.
*
*-------------------------------------------------------------------*#

Model tank_simplified
        PARAMETERS
        k as Real (Brief="Valve Constant", Unit = 'm^2.5/h', Default=4);
        A as Real (Brief="Tank area", Default=2, Unit = 'm^2');

        VARIABLES
        Level as Real(Brief="Tank level", Unit='m');
in      Fin  as Real(Brief="Input flow", Unit='m^3/h');
out     Fout as Real(Brief="Output flow", Unit='m^3/h');

        EQUATIONS
        "Mass balance"
        diff(A*Level) = Fin - Fout;

        "Valve equation"
        Fout = k*sqrt(Level);           
end


FlowSheet ThreeTank
        VARIABLES
        Feed    as Real(Unit='m^3/h');

        DEVICES
        Tank1   as tank_simplified;
        Tank2   as tank_simplified;
        Tank3   as tank_simplified;

        CONNECTIONS
        Feed        to  Tank1.Fin;
        Tank1.Fout      to      Tank2.Fin;
        Tank2.Fout      to      Tank3.Fin;

        SPECIFY
        Feed = 10 * 'm^3/h';
        
        INITIAL
        Tank1.Level = 1 * 'm';
        Tank2.Level = 2 * 'm';
        Tank3.Level = 1 * 'm';
        
        SET
        Tank2.k = 8 * 'm^2.5/h';
        Tank2.A = 4 * 'm^2';
        
        OPTIONS
        TimeStep = 0.1;
        TimeEnd = 2;
        TimeUnit = 'h';
end