source: branches/gui/sample/reactors/fogler/chap4/semibatch_reactor.mso @ 961

#*-------------------------------------------------------------------
* EMSO Model Library (EML) Copyright (C) 2004 - 2007 ALSOC.
*
* This LIBRARY is free software; you can distribute it and/or modify
* it under the therms of the ALSOC FREE LICENSE as available at
* http://www.enq.ufrgs.br/alsoc.
*
* EMSO Copyright (C) 2004 - 2007 ALSOC, original code
* from http://www.rps.eng.br Copyright (C) 2002-2004.
* All rights reserved.
*
* EMSO is distributed under the therms of the ALSOC LICENSE as
* available at http://www.enq.ufrgs.br/alsoc.
*
*---------------------------------------------------------------------
* Semibatch isotermic reactor
*----------------------------------------------------------------------
* Solved problem from Fogler (1999)
* Problem number: 4-11
* Page: 171 (Brazilian version, 2002)
*----------------------------------------------------------------------
*
*   Description:
*               Sample to calculate of the molar concentrations and conversions
*       as function of the time in a semibatch (or semicontinuous) reactor
*       with a irreversible second-order reaction:
*                       CNBr + CH3NH2 -> CH3Br + NCNH2
*       
*   Assumptions:
*               * elementary reaction
*               * steady-state
*       * isotermic and isobaric system
*       * liquid phase
*
*       Specify:
*               * the inlet stream
*               * the kinetic parameters
*
*----------------------------------------------------------------------
* Author: Christiano D. W. Guerra and Rodolfo Rodrigues
* $Id: semibatch_reactor.mso 574 2008-07-25 14:18:50Z rafael $
*--------------------------------------------------------------------*#

using "types";


FlowSheet reactor
        PARAMETERS
        NComp           as Integer              (Brief="Number of chemical components", Lower=1);
        stoic(NComp)as Real                     (Brief="Stoichiometric number");
        Vo                      as volume               (Brief="Initial volume");
        vo                      as flow_vol     (Brief="Inlet volumetric flow");
        Cao             as conc_mol             (Brief="Initial concentration of A");
        
        VARIABLES
        C(NComp)        as conc_mol             (Brief="Concentration", DisplayUnit='mol/l', Lower=0);
        Co(NComp)       as conc_mol             (Brief="Inlet concentration", DisplayUnit='mol/l', Lower=0);
        
        r(NComp)        as reaction_mol (Brief="Rate of reaction", DisplayUnit='mol/l/s');
        k                       as Real                 (Brief="Specific rate of reaction", Unit='l/mol/s');
        V                       as volume               (Brief="Volume", DisplayUnit='l');
        X                       as fraction     (Brief="Molar conversion");
        
        EQUATIONS
        "Molar balance"
        diff(C) = r + (Co - C)*vo/V; # Co = Inlet condition
        
        "Volume"
        diff(V) = vo;
        
        "Rate of reaction"
        r = stoic*k*C(1)*C(2);
        
        "Molar conversion"
        X = 1 - (C(1)*V)/(Cao*Vo); # Cao = Initial condition

        SET
        NComp = 4;      # A: cyanogen bromide, B: methylamine, 
                                # C: methyl bromide and D: cyanamide
        stoic = [-1.0, -1.0, 1.0, 1.0]; # A + B -> C + D
        
        Vo = 5.00*'l';
        vo = 0.05*'l/s';
        Cao= 0.05*'mol/l'; # Initial condition
        
        SPECIFY
        k = 2.2*'l/mol/s';
        
        Co = [0.0, 0.025, 0.0, 0.0]*'mol/l';

        INITIAL
        "Molar concentration"
        C = [0.05, 0.0, 0.0, 0.0]*'mol/l';
        "Volume"
        V = Vo;

        OPTIONS
        TimeStep = 5;
        TimeEnd = 500;
end