source: branches/gui/sample/miscellaneous/sample_high_index_optimal.mso @ 695

#*-------------------------------------------------------------------
* EMSO Model Library (EML) Copyright (C) 2004 - 2007 ALSOC.
*
* This LIBRARY is free software; you can distribute it and/or modify
* it under the therms of the ALSOC FREE LICENSE as available at
* http://www.enq.ufrgs.br/alsoc.
*
* EMSO Copyright (C) 2004 - 2007 ALSOC, original code
* from http://www.rps.eng.br Copyright (C) 2002-2004.
* All rights reserved.
*
* EMSO is distributed under the therms of the ALSOC LICENSE as
* available at http://www.enq.ufrgs.br/alsoc.
*
*--------------------------------------------------------------------
* Sample file for for a high-index optimal control problem.
*--------------------------------------------------------------------
* Author: Rafael de Pelegrini Soares
* $Id$
*--------------------------------------------------------------------*# 
using "types";

Model FlashRaoult
        ATTRIBUTES
        Info = "
        This is a very simple (wrong) model with dynamics only on the energy.
        
        It should be used for ilustration purposes only.";
        
        PARAMETERS
        NComp as Integer;
        
        # Antoine constants
        A(NComp) as Real;
        B(NComp) as Real;
        C(NComp) as Real;
        
        Cv as Real(Unit = 'J/mol/K');
        DHvap as energy_mol;

        VARIABLES
        F as flow_mol;
        L as flow_mol;
        V as flow_mol;
        z(NComp) as fraction;
        x(NComp) as fraction;
        y(NComp) as fraction;
        n(NComp) as mol;
        nt       as mol;
        
        T as temperature;
        P as pressure;
        Psat(NComp) as pressure;
        
        Q as power;
        E as energy;
        
        EQUATIONS       
        "Component Molar Balance"
        diff(n) = F*z - (L*x + V*y);
        
        nt = sum(n);
        x = n/nt;
        
        "Energy Balance"
        diff(E) = Q - V*DHvap;
        
        "Internal energy"
        E = nt*Cv*T;
        
        "Raoult's Law"
        P*y = Psat*x;
        
        "Antoine for Vapour Pressure"
        ln(Psat/'kPa') = A - B/(T/'K'- 273.15 + C);
        
        "Molar Fraction sum"
        sum(y) = 1;
end


FlowSheet FlashRaoultTest
        DEVICES
        fl as FlashRaoult;
        
        SET
        fl.NComp = 3;
        # Antoine constants (Acetone, Acetonitrile, Nitromethane)
        fl.A = [14.31, 14.89, 14.75];
        fl.B = [2756,  3413,  3331];
        fl.C = [228,   250,   227];
        
        fl.Cv = 30 * 'J/mol/K';
        fl.DHvap = 30 * 'kJ/mol';
        
        EQUATIONS
        if time < 1 * 'min' then
                fl.z = [0.45, 0.35, 0.2];
        else
                fl.z = [0.55, 0.25, 0.2];
        end


        SPECIFY
        # Feed conditions
        fl.F = 1 * 'kmol/h';
        
        fl.V = 0.1 * 'kmol/h';
        fl.L = 0.2 * 'kmol/h';
        
        # Operating conditions
        #fl.T = (80+273.15) * 'K';
        fl.Q = 0 * 'W';
        #fl.P = 1.2 * 'atm';
        
        INITIAL
        fl.T = (80+273.15) * 'K';
        fl.x = [0.55, 0.25];
        
        OPTIONS
        TimeEnd = 2;
        TimeStep = 0.01;
        TimeUnit = 'min';
        Dynamic = true;
end